Mindustry/settings.gradle

include 'desktop', 'core', 'kryonet', 'server', 'ios', 'annotations', 'tools', 'tests'

Properties properties = new Properties()

if(new File(settingsDir, 'local.properties').exists()){
    properties.load(new File(settingsDir, 'local.properties').newDataInputStream())

    if(properties.containsKey("sdk.dir")){
        include 'android'
    }else{
        println("No android SDK dir found Not loading Android module.")
    }
}else{
    println("No local.properties found. Not loading Android module.")
}

if(System.properties["release"] == null || System.properties["release"] == "false"){
    if (new File(settingsDir, '../uCore').exists()) {
        include ':uCore'
        project(':uCore').projectDir = new File(settingsDir, '../uCore')
    }

    if (new File(settingsDir, '../GDXGifRecorder').exists()) {
        include ':GDXGifRecorder'
        project(':GDXGifRecorder').projectDir = new File(settingsDir, '../GDXGifRecorder')
    }
    if (new File(settingsDir, '../debug').exists()) {
        include ':debug'
        project(':debug').projectDir = new File(settingsDir, '../debug')
    }
}else{
    println("Not including local repositories.")
}