catala/examples/allocations_familiales/securite_sociale_L.catala_fr

# Code de la sécurité sociale

## Partie législative

### Livre 5 : Prestations familiales et prestations assimilées

#### Titre 1 : Champ d'application - Généralités

##### Chapitre 1er : Liste des prestations

###### Article L511-1|LEGIARTI000038834530

Les prestations familiales comprennent :

1°) la prestation d'accueil du jeune enfant ;

2°) les allocations familiales ;

3°) le complément familial ;

4°) L'allocation de logement régie par les dispositions du livre VIII du code de la construction et de l'habitation ;

5°) l'allocation d'éducation de l'enfant handicapé ;

6°) l'allocation de soutien familial ;

7°) l'allocation de rentrée scolaire ;

8°) (Abrogé) ;

9°) l'allocation journalière de présence parentale.

```catala
# Voir l'énumération ÉlémentPrestationsFamiliale
```

##### Chapitre 2 : Champ d'application

###### Article L512-3|LEGIARTI000038834523

Sous réserve des règles particulières à chaque prestation,
ouvre droit aux prestations familiales :

1°) tout enfant jusqu'à la fin de l'obligation scolaire ;

```catala
champ d'application PrestationsFamiliales :
  étiquette cas_base règle droit_ouvert de enfant sous condition
    enfant.obligation_scolaire sous forme Avant ou
    enfant.obligation_scolaire sous forme Pendant
  conséquence rempli
```

2°) après la fin de l'obligation scolaire, et jusqu'à un âge limite,
tout enfant dont la rémunération éventuelle n'excède pas un plafond.

```catala
champ d'application PrestationsFamiliales :
  étiquette cas_base règle droit_ouvert de enfant sous condition
    enfant.obligation_scolaire sous forme Après et
    (enfant.rémuneration_mensuelle <=€ plafond_l512_3_2) et
    (enfant.âge < âge_l512_3_2)
  conséquence rempli

  # On définit les conditions hors âge d'abord car elles
  # sont référencées plus tard dans l'article L521-1
  règle conditions_hors_âge de enfant sous condition
    enfant.obligation_scolaire sous forme Avant ou
    enfant.obligation_scolaire sous forme Pendant ou
    enfant.obligation_scolaire sous forme Après et
    (enfant.rémuneration_mensuelle <=€ plafond_l512_3_2)
  conséquence rempli

champ d'application AllocationsFamiliales:
  définition enfants_à_charge_droit_ouvert_prestation_familiale égal à
    filtre pour enfant dans enfants_à_charge de
      prestations_familiales.droit_ouvert de enfant
```

Toutefois, pour l'attribution du complément familial et de l'allocation
de logement mentionnés aux 3° et 4° de l'article L. 511-1 , l'âge limite
peut être différent de celui mentionné au 2° du présent article.

```catala
# Sera géré avec une exception dans Catala. Le texte est équivalent
# à une méta-propriété du code à vérifier : i.e. pas d'exceptions pour
# cet âge azutre part que pour Complément Familial ou AllocationLogement.
```

#### Titre 2 : Prestations générales d'entretien

##### Chapitre 1er : Allocations familiales

###### Article L521-1|LEGIARTI000029963006

Les allocations familiales sont dues à partir du deuxième enfant à charge.

```catala
champ d'application AllocationsFamiliales :
  règle droit_ouvert_base sous condition
    nombre de enfants_à_charge_droit_ouvert_prestation_familiale >= 2
  conséquence rempli
```

Une allocation forfaitaire par enfant d'un montant fixé par décret est versée
pendant un an à la personne ou au ménage qui assume la charge d'un nombre
minimum d'enfants également fixé par décret lorsque l'un ou plusieurs des
enfants qui ouvraient droit aux allocations familiales atteignent l'âge
limite mentionné au 2° de l'article L. 512-3 . Cette allocation est versée
à la condition que le ou les enfants répondent aux conditions autres que
celles de l'âge pour l'ouverture du droit aux allocations familiales.

```catala
champ d'application AllocationsFamiliales :
  assertion fixé montant_versé par décret

  règle droit_ouvert_forfaitaire de enfant sous condition
    # nombre_enfants_alinéa_2_l521_3 sera défini dans l'article R521-3
    (nombre de enfants_à_charge >= nombre_enfants_alinéa_2_l521_3) et
    # Puisqu'un enfant ne garde un âge donné que pour une période d'un an,
    # cette condition assure que l'allocation ne peut être distribuée que pour
    # un an.
    (enfant.âge = prestations_familiales.âge_l512_3_2) et
    (enfant.a_déjà_ouvert_droit_aux_allocations_familiales) et
    (prestations_familiales.conditions_hors_âge de enfant)
  conséquence rempli
```

Le montant des allocations mentionnées aux deux premiers alinéas du présent
article, ainsi que celui des majorations mentionnées à l'article L. 521-3
varient en fonction des ressources du ménage ou de la personne qui a la charge
des enfants, selon un barème défini par décret.

```catala
champ d'application AllocationsFamiliales :
  assertion fixé montant_versé_base  par décret
  assertion varie montant_versé_base avec ressources_ménage
  assertion fixé montant_versé_majorations par décret
  assertion varie montant_versé_majorations avec ressources_ménage
```

Le montant des allocations familiales varie en fonction du nombre d'enfants
à charge.

```catala
champ d'application AllocationsFamiliales :
  assertion varie montant_versé_base.montant_versé avec
     nombre de enfants_à_charge_droit_ouvert_prestation_familiale
```

Les niveaux des plafonds de ressources, qui varient en fonction du nombre
d'enfants à charge, sont révisés conformément à l'évolution annuelle de
l'indice des prix à la consommation, hors tabac.

```catala
# Pour formaliser l'évolution des prix, il faudrait recopier ici
# tous les décrets d'application qui fixent la valeur des plafonds
# de ressources. Si cela reste possible à faire pour notre langage,
# nous avons choisi de ne pas inclure tout ce code dans ce document.
```

Un complément dégressif est versé lorsque les ressources du bénéficiaire
dépassent l'un des plafonds, dans la limite de montants définis par décret.
Les modalités de calcul de ces montants et celles du complément dégressif
sont définies par décret.

```catala
# Ditto, le volume du code à inclure pour formaliser cette assertion
# est assez important et nous avons choisi de ne pas l'inclure dans ce
# document.

champ d'application AllocationsFamiliales :
  assertion fixé montant_versé_complément par décret
```

###### Article L521-2|LEGIARTI000006743210

Les allocations sont versées à la personne qui assume, dans quelques conditions
que ce soit, la charge effective et permanente de l'enfant.

```catala
champ d'application AllocationsFamiliales :
  définition prise_en_compte de enfant sous condition
    enfant.prise_en_charge sous forme EffectiveEtPermanente
  conséquence égal à PriseEnCompte.Complète

  définition versement de enfant sous condition
    enfant.prise_en_charge sous forme EffectiveEtPermanente
  conséquence égal à VersementAllocations.Normal
```

En cas de résidence alternée de l'enfant au domicile de chacun des parents telle
que prévue à l'article 373-2-9 du code civil, mise en oeuvre de manière
effective, les parents désignent l'allocataire. Cependant, la charge de l'enfant
pour le calcul des allocations familiales est partagée par moitié entre les deux
parents soit sur demande conjointe des parents, soit si les parents sont en
désaccord sur la désignation de l'allocataire. Un décret en Conseil d'Etat fixe
les conditions d'application du présent alinéa.

```catala
champ d'application AllocationsFamiliales :
  # Premier cas : garde alternée, parents désignent un unique allocataire
  définition prise_en_compte de enfant sous condition
    enfant.prise_en_charge sous forme GardeAlternéeAllocataireUnique
  conséquence égal à PriseEnCompte.Complète

  définition versement de enfant sous condition
    enfant.prise_en_charge sous forme GardeAlternéeAllocataireUnique
  conséquence égal à VersementAllocations.Normal

  # Deuxième cas : garde alternée, parents partagent la charge pour
  # l'allocation
  définition prise_en_compte de enfant sous condition
    enfant.prise_en_charge sous forme GardeAlternéePartageAllocations
  conséquence égal à PriseEnCompte.Partagée

  définition versement de enfant sous condition
    enfant.prise_en_charge sous forme GardeAlternéePartageAllocations
  conséquence égal à VersementAllocations.Normal
```

Lorsque la personne qui assume la charge effective et permanente de l'enfant ne
remplit pas les conditions prévues au titre I du présent livre pour l'ouverture
du droit aux allocations familiales, ce droit s'ouvre du chef du père ou,
à défaut, du chef de la mère.

```catala
champ d'application AllocationsFamiliales :
  assertion
    personne_charge_effective_permanente_est_parent ou
    (
      (non personne_charge_effective_permanente_est_parent) et
      personne_charge_effective_permanente_remplit_titre_I
    )
```

Lorsqu'un enfant est confié au service d'aide sociale à l'enfance, les
allocations familiales continuent d'être évaluées en tenant compte à la fois
des enfants présents au foyer et du ou des enfants confiés au service de
l'aide sociale à l'enfance. La part des allocations familiales dues à la
famille pour cet enfant est versée à ce service. Toutefois, le juge peut
décider, d'office ou sur saisine du président du conseil général, à la
suite d'une mesure prise en application des articles 375-3 et 375-5 du code
civil ou des articles 15,16,16 bis et 28 de l' ordonnance n° 45-174 du 2
février 1945 relative à l'enfance délinquante, de maintenir le versement
des allocations à la famille, lorsque celle-ci participe à la prise en
charge morale ou matérielle de l'enfant ou en vue de faciliter le retour
de l'enfant dans son foyer.

```catala
champ d'application AllocationsFamiliales :
 définition prise_en_compte de enfant sous condition
    enfant.prise_en_charge sous forme
      ServicesSociauxAllocationVerséeAuxServicesSociaux
  conséquence égal à PriseEnCompte.Zéro

  définition versement de enfant sous condition
    enfant.prise_en_charge sous forme
      ServicesSociauxAllocationVerséeAuxServicesSociaux
  conséquence égal à VersementAllocations.AllocationVerséeAuxServicesSociaux

  définition prise_en_compte de enfant sous condition
    enfant.prise_en_charge sous forme
      ServicesSociauxAllocationVerséeÀLaFamille
  conséquence égal à PriseEnCompte.Complète


  définition versement de enfant sous condition
    enfant.prise_en_charge sous forme
      ServicesSociauxAllocationVerséeÀLaFamille
  conséquence égal à VersementAllocations.Normal
```

Un décret en Conseil d'Etat fixe les conditions d'application du présent
article, notamment dans les cas énumérés ci-dessous :

a) retrait total de l'autorité parentale des parents ou de l'un d'eux ;

b) indignité des parents ou de l'un d'eux ;

c) divorce, séparation de corps ou de fait des parents ;

d) enfants confiés à un service public, à une institution privée, à un particulier.

```catala
# Ce programme ne cherche pas à formaliser les détails pour lesquels un enfant
# est confié à un service social.
```

###### Article L521-3|LEGIARTI000006743289

Chacun des enfants à charge, à l'exception du plus âgé, ouvre droit à partir
d'un âge minimum à une majoration des allocations familiales.

```catala
champ d'application AllocationsFamiliales :
  règle droit_ouvert_majoration de enfant
  sous condition
    (non (est_enfant_le_plus_âgé de enfant)) et
    (enfant.âge >= âge_minimum_alinéa_1_l521_3 de enfant)
  conséquence rempli
```

Toutefois, les personnes ayant un nombre déterminé d'enfants à charge
bénéficient de ladite majoration pour chaque enfant à charge à partir
de l'âge mentionné au premier alinéa.

```catala
champ d'application AllocationsFamiliales :
  exception
  règle droit_ouvert_majoration de enfant
  sous condition
    (nombre de enfants_à_charge_droit_ouvert_prestation_familiale >=
      nombre_enfants_alinéa_2_l521_3) et
    (enfant.âge >= âge_minimum_alinéa_1_l521_3 de enfant)
  conséquence rempli
```

#### Titre 5 : Dispositions communes

##### Chapitre 1er : Etablissement du salaire de base

###### Article L551-1|LEGIARTI000031688371

Le montant des prestations familiales est déterminé d'après des bases
mensuelles de calcul revalorisées au 1er avril de chaque année par application
du coefficient mentionné à l'article L. 161-25 .

```catala
# Idem que L521-1, on ne formalise pas ici l'évolution de la BMPA
champ d'application PrestationsFamiliales :
  assertion fixé prestations_familiales.base_mensuelle par décret
```

### Livre 7 : Régimes divers - Dispositions diverses

#### Titre 5 : Dispositions particulières à la Guadeloupe, à la Guyane, à la Martinique, à La Réunion, à Saint-Barthélemy et à Saint-Martin

##### Chapitre 1er : Généralités

###### Article L751-1|LEGIARTI000031323778

Les dispositions du présent titre s'appliquent en Guadeloupe, en Guyane,
en Martinique, à La Réunion, à Saint-Barthélemy et à Saint-Martin à
l'ensemble des bénéficiaires de la législation générale de sécurité
sociale, y compris les membres des professions agricoles.

```catala
# Angle mort: ici nous n'avons pas formalisé la partie sur la législation
# générale de sécurité sociale et les membres des professions agricoles.

champ d'application PrestationsFamiliales :
  règle régime_outre_mer_l751_1 sous condition
    (résidence = Guadeloupe) ou
    (résidence = Guyane) ou
    (résidence = Martinique) ou
    (résidence = LaRéunion) ou
    (résidence = SaintBarthélemy) ou
    (résidence = SaintMartin)
  conséquence rempli
```

##### Chapitre 5 : Prestations familiales et prestations assimilées

###### Article L755-3|LEGIARTI000033728786

Les dispositions des articles L. 512-1 à L. 512-4 , L. 513-1 , L. 521-2 ,
L. 552-1 , L. 553-1 , L. 553-2 , L. 553-4 , L. 582-1 , L. 582-2 , L. 583-3
et L. 583-5 sont applicables aux collectivités mentionnées à l'article L. 751-1 .

La base de calcul des prestations familiales est la même que celle qui est
fixée en application de l'article L. 551-1 .

```catala
# Aucun changement dans le code, puisque les articles restent applicables
```

###### Article L755-11|LEGIARTI000031323803

Les conditions d'attribution des allocations familiales et de leurs majorations
fixées par les articles L. 521-1 et L. 521-3 sont applicables dans les
collectivités mentionnées à l'article L. 751-1.

```catala
# Aucun changement dans le code, puisque les articles restent applicables
```

Toutefois, les dispositions de l'article L. 755-12 restent en vigueur aussi
longtemps que le présent chapitre V est applicable.

###### Article L755-12|LEGIARTI000029962999

Les allocations familiales sont dues, pour tout enfant, à la personne qui a
effectivement la charge de celui-ci.

```catala
# TODO Liane: Angle mort, ici c'est marqué "effectivement la charge" mais dans l'article de
# L521-2 il faut charge effective ET permanente. Pourquoi cette différence ?
# Quelles conséquences pratiques ?
# Apparemment en 1987 il y avait encore des exceptions pour certains agents
# publics d'outre-mer

champ d'application AllocationsFamiliales:
  exception
  règle droit_ouvert_base sous condition
    prestations_familiales.régime_outre_mer_l751_1 et
    (nombre de enfants_à_charge_droit_ouvert_prestation_familiale >= 1)
  conséquence rempli
```
Toutefois, les quatre derniers alinéas de l'article L. 521-1 ne sont pas
applicables lorsque le ménage ou la personne a un seul enfant à charge.

```catala
# Ceci concerne l'ouverture du droit à l'allocation forfaitaire
# et au complément dégressif.

champ d'application AllocationsFamiliales :
  exception
  règle droit_ouvert_forfaitaire de enfant sous condition
     prestations_familiales.régime_outre_mer_l751_1 et
     (nombre de enfants_à_charge_droit_ouvert_prestation_familiale = 1)
  conséquence non rempli

  exception
  règle droit_ouvert_complément sous condition
    prestations_familiales.régime_outre_mer_l751_1 et
    (nombre de enfants_à_charge_droit_ouvert_prestation_familiale = 1)
  conséquence non rempli
```