mirror of
https://github.com/DNSCrypt/dnscrypt-proxy.git
synced 2024-09-20 01:18:56 +03:00
2c49804bd0
Git has been nagging me about these files that I haven't touched being changed. The solution was to run `git add --renormalize .`. Apparently this needs to be done after setting up `.gitattributes`. According to `git ls-files --eol windows/`, the .bat files were previously stored in the index with CRLF endings and will now be stored with LF endings (with .gitattributes dictating that checked out copies will use CRLF).
36 lines
958 B
Batchfile
Executable File
36 lines
958 B
Batchfile
Executable File
@set @_cmd=1 /*
|
|
@echo off
|
|
setlocal EnableExtensions
|
|
title DNSCrypt-Proxy
|
|
|
|
whoami /groups | findstr "S-1-16-12288" >nul && goto :admin
|
|
if "%~1"=="RunAsAdmin" goto :error
|
|
|
|
echo Requesting privileges elevation for managing the dnscrypt-proxy service . . .
|
|
cscript /nologo /e:javascript "%~f0" || goto :error
|
|
exit /b
|
|
|
|
:error
|
|
echo.
|
|
echo Error: Administrator privileges elevation failed,
|
|
echo please manually run this script as administrator.
|
|
echo.
|
|
goto :end
|
|
|
|
:admin
|
|
pushd "%~dp0"
|
|
dnscrypt-proxy.exe -service stop
|
|
dnscrypt-proxy.exe -service uninstall
|
|
popd
|
|
echo.
|
|
echo Thank you for using DNSCrypt-Proxy!
|
|
|
|
:end
|
|
set /p =Press [Enter] to exit . . .
|
|
exit /b */
|
|
|
|
// JScript, restart batch script as administrator
|
|
var objShell = WScript.CreateObject('Shell.Application');
|
|
var ComSpec = WScript.CreateObject('WScript.Shell').ExpandEnvironmentStrings('%ComSpec%');
|
|
objShell.ShellExecute(ComSpec, '/c ""' + WScript.ScriptFullName + '" RunAsAdmin"', '', 'runas', 1);
|