mirror of
https://github.com/Huluti/Curtail.git
synced 2024-09-11 14:16:12 +03:00
3f8064065f
- Add the `<developer><name>` tag - Mark the `<developer_name>` tag as deprecated - Use --no-net argument for appstreamcli to reduce traffic
56 lines
1.5 KiB
Meson
56 lines
1.5 KiB
Meson
pkgdatadir = join_paths(get_option('prefix'), get_option('datadir'), meson.project_name())
|
|
|
|
gnome = import('gnome')
|
|
|
|
gnome.compile_resources('curtail',
|
|
'curtail.gresource.xml',
|
|
gresource_bundle: true,
|
|
install: true,
|
|
install_dir: pkgdatadir,
|
|
)
|
|
|
|
desktop_file = i18n.merge_file(
|
|
input: 'com.github.huluti.Curtail.desktop.in',
|
|
output: 'com.github.huluti.Curtail.desktop',
|
|
type: 'desktop',
|
|
po_dir: '../po',
|
|
install: true,
|
|
install_dir: join_paths(get_option('datadir'), 'applications')
|
|
)
|
|
|
|
desktop_utils = find_program('desktop-file-validate', required: false)
|
|
if desktop_utils.found()
|
|
test('Validate desktop file', desktop_utils,
|
|
args: [desktop_file]
|
|
)
|
|
endif
|
|
|
|
appstream_file = i18n.merge_file(
|
|
input: 'com.github.huluti.Curtail.appdata.xml.in',
|
|
output: 'com.github.huluti.Curtail.appdata.xml',
|
|
po_dir: '../po',
|
|
install: true,
|
|
install_dir: join_paths(get_option('datadir'), 'metainfo')
|
|
)
|
|
|
|
appstreamcli = find_program('appstreamcli', required: false)
|
|
if appstreamcli.found()
|
|
test('Validate appstream file', appstreamcli,
|
|
args: ['validate', '--no-net', '--explain', appstream_file],
|
|
workdir: meson.current_build_dir()
|
|
)
|
|
endif
|
|
|
|
install_data('com.github.huluti.Curtail.gschema.xml',
|
|
install_dir: join_paths(get_option('datadir'), 'glib-2.0/schemas')
|
|
)
|
|
|
|
compile_schemas = find_program('glib-compile-schemas', required: false)
|
|
if compile_schemas.found()
|
|
test('Validate schema file', compile_schemas,
|
|
args: ['--strict', '--dry-run', meson.current_source_dir()]
|
|
)
|
|
endif
|
|
|
|
subdir('icons')
|