git.iko.soy/Idris-dev
on 019faba help sign in
Idris-dev/src/Core/TT.hs
320 lines 10 kB history raw
1{-# LANGUAGE MultiParamTypeClasses, FunctionalDependencies, DeriveFunctor #-}
3module Core.TT where
5import Control.Monad.State
6import Debug.Trace
7import qualified Data.Map as Map
9{- The language has:
10 * Full dependent types
11 * A hierarchy of universes, with cumulativity: Set : Set1, Set1 : Set2, ...
12 * Pattern matching letrec binding
13 * (primitive types defined externally)
15 Some technical stuff:
16 * Typechecker is kept as simple as possible
17 - no unification, just a checker for incomplete terms.
18 * We have a simple collection of tactics which we use to elaborate source
19 programs with implicit syntax into fully explicit terms.
20-}
22data Option = SetInSet
23 | CheckConv
24 deriving Eq
26data TC a = OK a
27 | Error String -- TMP! Make this an informative data structure
28 deriving (Eq, Functor)
30instance Show a => Show (TC a) where
31 show (OK x) = show x
32 show (Error str) = "Error: " ++ str
34-- at some point, this instance should also carry type checking options
35-- (e.g. Set:Set)
37instance Monad TC where
38 return = OK
39 x >>= k = case x of
40 OK v -> k v
41 Error e -> Error e
42 fail = Error
44instance MonadPlus TC where
45 mzero = Error "Unknown error"
46 (OK x) `mplus` _ = OK x
47 _ `mplus` (OK y) = OK y
48 err `mplus` _ = err
50discard :: Monad m => m a -> m ()
51discard f = f >> return ()
53showSep :: String -> [String] -> String
54showSep sep [] = ""
55showSep sep [x] = x
56showSep sep (x:xs) = x ++ sep ++ showSep sep xs
58-- RAW TERMS ----------------------------------------------------------------
60-- Names are hierarchies of strings, describing scope (so no danger of
61-- duplicate names, but need to be careful on lookup).
62-- Also MN for machine chosen names
64data Name = UN [String]
65 | MN Int String
66 deriving (Eq, Ord)
68instance Show Name where
69 show (UN [n]) = n
70 show (UN (n:ns)) = show (UN [n]) ++ "." ++ show (UN ns)
71 show (MN i s) = "{" ++ s ++ show i ++ "}"
74-- Contexts allow us to map names to things
75-- TODO: Namespaces and ambiguous names
77type Ctxt a = Map.Map Name a
78emptyContext = Map.empty
80addDef :: Name -> a -> Ctxt a -> Ctxt a
81addDef = Map.insert
83lookupCtxt :: Name -> Ctxt a -> Maybe a
84lookupCtxt = Map.lookup
86toAlist :: Ctxt a -> [(Name, a)]
87toAlist = Map.toList
90data Raw = Var Name
91 | RBind Name (Binder Raw) Raw
92 | RApp Raw Raw
93 | RSet Int
94 deriving Show
96data Binder b = Lam { binderTy :: b }
97 | Pi { binderTy :: b }
98 | Let { binderTy :: b,
99 binderVal :: b }
100 | NLet { binderTy :: b,
101 binderVal :: b }
102 | Hole { binderTy :: b}
103 | Guess { binderTy :: b,
104 binderVal :: b }
105 | PVar { binderTy :: b }
106 | PVTy { binderTy :: b }
107 deriving (Show, Eq, Functor)
109raw_apply :: Raw -> [Raw] -> Raw
110raw_apply f [] = f
111raw_apply f (a : as) = raw_apply (RApp f a) as
113data RawFun = RawFun { rtype :: Raw,
114 rval :: Raw
115 }
116 deriving Show
118data RawDatatype = RDatatype Name Raw [(Name, Raw)]
119 deriving Show
121data RDef = RFunction RawFun
122 | RConst Raw
123 | RData RawDatatype
124 deriving Show
126type RProgram = [(Name, RDef)]
128-- WELL TYPED TERMS ---------------------------------------------------------
130data NameType = Bound | Ref | DCon Int Int | TCon Int
131 deriving (Show, Eq)
133data TT n = P NameType n (TT n) -- embed type
134 | V Int
135 | Bind n (Binder (TT n)) (TT n)
136 | App (TT n) (TT n) -- function, function type, arg
137 | Set Int
138 deriving Functor
140type EnvTT n = [(n, Binder (TT n))]
142data Datatype n = Data { d_typename :: n,
143 d_type :: (TT n),
144 d_cons :: [(n, TT n)] }
145 deriving (Show, Functor, Eq)
147instance Eq n => Eq (TT n) where
148 (==) (P xt x _) (P yt y _) = xt == yt && x == y
149 (==) (V x) (V y) = x == y
150 (==) (Bind _ xb xs) (Bind _ yb ys) = xb == yb && xs == ys
151 (==) (App fx ax) (App fy ay) = fx == fy && ax == ay
152 (==) (Set x) (Set y) = x == y
153 (==) _ _ = False
155-- A few handy operations on well typed terms:
157instantiate :: TT n -> TT n -> TT n
158instantiate e = subst 0 where
159 subst i (V x) | i == x = e
160 subst i (Bind x b sc) = Bind x (fmap (subst i) b) (subst (i+1) sc)
161 subst i (App f a) = App (subst i f) (subst i a)
162 subst i t = t
164pToV :: Eq n => n -> TT n -> TT n
165pToV n = pToV' n 0
166pToV' n i (P _ x _) | n == x = V i
167pToV' n i (Bind x b sc)
168 | n == x = Bind x (fmap (pToV' n i) b) sc
169 | otherwise = Bind x (fmap (pToV' n i) b) (pToV' n (i+1) sc)
170pToV' n i (App f a) = App (pToV' n i f) (pToV' n i a)
171pToV' n i t = t
173-- Convert several names. First in the list comes out as V 0
174pToVs :: Eq n => [n] -> TT n -> TT n
175pToVs ns tm = pToVs' ns tm 0 where
176 pToVs' [] tm i = tm
177 pToVs' (n:ns) tm i = pToV' n i (pToVs' ns tm (i+1))
179vToP :: TT n -> TT n
180vToP = vToP' [] where
181 vToP' env (V i) = let (n, b) = (env !! i) in
182 P Bound n (binderTy b)
183 vToP' env (Bind n b sc) = let b' = fmap (vToP' env) b in
184 Bind n b' (vToP' ((n, b'):env) sc)
185 vToP' env (App f a) = App (vToP' env f) (vToP' env a)
186 vToP' env t = t
188finalise :: Eq n => TT n -> TT n
189finalise (Bind x b sc) = Bind x (fmap finalise b) (pToV x (finalise sc))
190finalise (App f a) = App (finalise f) (finalise a)
191finalise t = t
193subst :: Eq n => n -> TT n -> TT n -> TT n
194subst n v tm = instantiate v (pToV n tm)
196substNames :: Eq n => [(n, TT n)] -> TT n -> TT n
197substNames [] t = t
198substNames ((n, tm) : xs) t = subst n tm (substNames xs t)
200-- Returns true if V 0 and bound name n do not occur in the term
202noOccurrence :: Eq n => n -> TT n -> Bool
203noOccurrence n t = no' 0 t
204 where
205 no' i (V x) = not (i == x)
206 no' i (P Bound x _) = not (n == x)
207 no' i (Bind n b sc) = noB' i b && no' (i+1) sc
208 where noB' i (Let t v) = no' i t && no' i v
209 noB' i (Guess t v) = no' i t && no' i v
210 noB' i b = no' i (binderTy b)
211 no' i (App f a) = no' i f && no' i a
212 no' i _ = True
214-- Return the arity of a (normalised) type
216arity :: TT n -> Int
217arity (Bind n (Pi t) sc) = 1 + arity sc
218arity _ = 0
220-- deconstruct an application; returns the function and a list of arguments
222unApply :: TT n -> (TT n, [TT n])
223unApply t = ua [] t where
224 ua args (App f a) = ua (a:args) f
225 ua args t = (t, args)
227mkApp :: TT n -> [TT n] -> TT n
228mkApp f [] = f
229mkApp f (a:as) = mkApp (App f a) as
231forget :: TT Name -> Raw
232forget tm = fe [] tm
233 where
234 fe env (P _ n _) = Var n
235 fe env (V i) = Var (env !! i)
236 fe env (Bind n b sc) = RBind n (fmap (fe env) b)
237 (fe (n:env) sc)
238 fe env (App f a) = RApp (fe env f) (fe env a)
239 fe env (Set i) = RSet i
241type Term = TT Name
242type Type = Term
244type Env = EnvTT Name
246-- an environment with de Bruijn indices 'normalised' so that they all refer to
247-- this environment
249newtype WkEnvTT n = Wk (EnvTT n)
250type WkEnv = WkEnvTT Name
252instance (Eq n, Show n) => Show (TT n) where
253 show t = showEnv [] t
255showEnv env t = showEnv' env t False
256showEnvDbg env t = showEnv' env t True
258showEnv' env t dbg = se 10 env t where
259 se p env (P nt n t) = show n
260 ++ if dbg then "{" ++ show nt ++ " : " ++ se 10 env t ++ "}" else ""
261 se p env (V i) | i < length env = (show $ fst $ env!!i) ++
262 if dbg then "{" ++ show i ++ "}" else ""
263 | otherwise = "!!V " ++ show i ++ "!!"
264 se p env (Bind n b@(Pi t) sc)
265 | noOccurrence n sc && not dbg = bracket p 2 $ se 10 env t ++ " -> " ++ se 10 ((n,b):env) sc
266 se p env (Bind n b sc) = bracket p 2 $ sb env n b ++ se 10 ((n,b):env) sc
267 se p env (App f a) = bracket p 1 $ se 1 env f ++ " " ++ se 0 env a
268 se p env (Set i) = "Set" ++ show i
270 sb env n (Lam t) = showb env "\\ " " => " n t
271 sb env n (Hole t) = showb env "? " ". " n t
272 sb env n (Pi t) = showb env "(" ") -> " n t
273 sb env n (PVar t) = showb env "pat " ". " n t
274 sb env n (PVTy t) = showb env "pty " ". " n t
275 sb env n (Let t v) = showbv env "let " " in " n t v
276 sb env n (Guess t v) = showbv env "?? " " in " n t v
278 showb env op sc n t = op ++ show n ++ " : " ++ se 10 env t ++ sc
279 showbv env op sc n t v = op ++ show n ++ " : " ++ se 10 env t ++ " = " ++
280 se 10 env v ++ sc
282 bracket outer inner str | inner > outer = "(" ++ str ++ ")"
283 | otherwise = str
285-- Check whether a term has any holes in it - impure if so
287pureTerm :: TT n -> Bool
288pureTerm (App f a) = pureTerm f && pureTerm a
289pureTerm (Bind n b sc) = pureBinder b && pureTerm sc where
290 pureBinder (Hole _) = False
291 pureBinder (Guess _ _) = False
292 pureBinder (Let t v) = pureTerm t && pureTerm v
293 pureBinder t = pureTerm (binderTy t)
294pureTerm _ = True
296-- weaken a term by adding i to each de Bruijn index (i.e. lift it over i bindings)
298weakenTm :: Int -> TT n -> TT n
299weakenTm i t = wk i 0 t
300 where wk i min (V x) | x >= min = V (i + x)
301 wk i m (App f a) = App (wk i m f) (wk i m a)
302 wk i m (Bind x b sc) = Bind x (wkb i m b) (wk i (m + 1) sc)
303 wk i m t = t
304 wkb i m t = fmap (wk i m) t
306-- weaken an environment so that all the de Bruijn indices are correct according
307-- to the latest bound variable
309weakenEnv :: EnvTT n -> EnvTT n
310weakenEnv env = wk (length env - 1) env
311 where wk i [] = []
312 wk i ((n, b) : bs) = (n, weakenTmB i b) : wk (i - 1) bs
313 weakenTmB i (Let t v) = Let (weakenTm i t) (weakenTm i v)
314 weakenTmB i (Guess t v) = Guess (weakenTm i t) (weakenTm i v)
315 weakenTmB i t = t { binderTy = weakenTm i (binderTy t) }
317weakenTmEnv :: Int -> EnvTT n -> EnvTT n
318weakenTmEnv i = map (\ (n, b) -> (n, fmap (weakenTm i) b))