git.iko.soy/Idris-dev
on 01ceead help sign in
Idris-dev/src/Core/TT.hs
438 lines 14 kB history raw
1{-# LANGUAGE MultiParamTypeClasses, FunctionalDependencies, DeriveFunctor #-}
3module Core.TT where
5import Control.Monad.State
6import Debug.Trace
7import qualified Data.Map as Map
8import Data.Char
9import Data.List
11{- The language has:
12 * Full dependent types
13 * A hierarchy of universes, with cumulativity: Set : Set1, Set1 : Set2, ...
14 * Pattern matching letrec binding
15 * (primitive types defined externally)
17 Some technical stuff:
18 * Typechecker is kept as simple as possible
19 - no unification, just a checker for incomplete terms.
20 * We have a simple collection of tactics which we use to elaborate source
21 programs with implicit syntax into fully explicit terms.
22-}
24data Option = SetInSet
25 | CheckConv
26 deriving Eq
28data FC = FC { fc_fname :: String,
29 fc_line :: Int }
30 deriving Eq
32instance Show FC where
33 show (FC f l) = f ++ ":" ++ show l
35data Err = Msg String
36 | CantUnify Term Term Err
37 | IncompleteTerm Term
38 | At FC Err
39 deriving Eq
41instance Show Err where
42 show (Msg s) = s
44data TC a = OK a
45 | Error Err
46 deriving (Eq, Functor)
48instance Show a => Show (TC a) where
49 show (OK x) = show x
50 show (Error str) = "Error: " ++ show str
52-- at some point, this instance should also carry type checking options
53-- (e.g. Set:Set)
55instance Monad TC where
56 return = OK
57 x >>= k = case x of
58 OK v -> k v
59 Error e -> Error e
60 fail e = Error (Msg e)
62tfail :: Err -> TC a
63tfail e = Error e
65trun :: FC -> TC a -> TC a
66trun fc (OK a) = OK a
67trun fc (Error e) = Error (At fc e)
69instance MonadPlus TC where
70 mzero = fail "Unknown error"
71 (OK x) `mplus` _ = OK x
72 _ `mplus` (OK y) = OK y
73 err `mplus` _ = err
75discard :: Monad m => m a -> m ()
76discard f = f >> return ()
78showSep :: String -> [String] -> String
79showSep sep [] = ""
80showSep sep [x] = x
81showSep sep (x:xs) = x ++ sep ++ showSep sep xs
83traceWhen True msg a = trace msg a
84traceWhen False _ a = a
86-- RAW TERMS ----------------------------------------------------------------
88-- Names are hierarchies of strings, describing scope (so no danger of
89-- duplicate names, but need to be careful on lookup).
90-- Also MN for machine chosen names
92data Name = UN String
93 | NS String Name
94 | MN Int String
95 deriving (Eq, Ord)
97instance Show Name where
98 show (UN n) = n
99 show (NS s n) = s ++ "." ++ show n
100 show (MN i s) = "{" ++ s ++ show i ++ "}"
103-- Contexts allow us to map names to things
104-- TODO: Namespaces and ambiguous names
106type Ctxt a = Map.Map Name a
107emptyContext = Map.empty
109addDef :: Name -> a -> Ctxt a -> Ctxt a
110addDef = Map.insert
112lookupCtxt :: Name -> Ctxt a -> Maybe a
113lookupCtxt = Map.lookup
115toAlist :: Ctxt a -> [(Name, a)]
116toAlist = Map.toList
118addAlist :: [(Name, a)] -> Ctxt a -> Ctxt a
119addAlist [] ctxt = ctxt
120addAlist ((n, tm) : ds) ctxt = addDef n tm (addAlist ds ctxt)
122data Const = I Int | BI Integer | Fl Double | Ch Char | Str String
123 | IType | BIType | FlType | ChType | StrType
124 | PtrType
125 deriving Eq
127data Raw = Var Name
128 | RBind Name (Binder Raw) Raw
129 | RApp Raw Raw
130 | RSet Int
131 | RConstant Const
132 deriving (Show, Eq)
134data Binder b = Lam { binderTy :: b }
135 | Pi { binderTy :: b }
136 | Let { binderTy :: b,
137 binderVal :: b }
138 | NLet { binderTy :: b,
139 binderVal :: b }
140 | Hole { binderTy :: b}
141 | GHole { binderTy :: b}
142 | Guess { binderTy :: b,
143 binderVal :: b }
144 | PVar { binderTy :: b }
145 | PVTy { binderTy :: b }
146 deriving (Show, Eq, Functor)
148fmapMB :: Monad m => (a -> m b) -> Binder a -> m (Binder b)
149fmapMB f (Let t v) = liftM2 Let (f t) (f v)
150fmapMB f (NLet t v) = liftM2 NLet (f t) (f v)
151fmapMB f (Guess t v) = liftM2 Guess (f t) (f v)
152fmapMB f (Lam t) = liftM Lam (f t)
153fmapMB f (Pi t) = liftM Pi (f t)
154fmapMB f (Hole t) = liftM Hole (f t)
155fmapMB f (GHole t) = liftM GHole (f t)
156fmapMB f (PVar t) = liftM PVar (f t)
157fmapMB f (PVTy t) = liftM PVTy (f t)
159raw_apply :: Raw -> [Raw] -> Raw
160raw_apply f [] = f
161raw_apply f (a : as) = raw_apply (RApp f a) as
163data RawFun = RawFun { rtype :: Raw,
164 rval :: Raw
165 }
166 deriving Show
168data RawDatatype = RDatatype Name Raw [(Name, Raw)]
169 deriving Show
171data RDef = RFunction RawFun
172 | RConst Raw
173 | RData RawDatatype
174 deriving Show
176type RProgram = [(Name, RDef)]
178-- WELL TYPED TERMS ---------------------------------------------------------
180data NameType = Bound | Ref | DCon Int Int | TCon Int Int
181 deriving (Show, Eq)
183data TT n = P NameType n (TT n) -- embed type
184 | V Int
185 | Bind n (Binder (TT n)) (TT n)
186 | App (TT n) (TT n) -- function, function type, arg
187 | Constant Const
188 | Set Int
189 deriving Functor
191type EnvTT n = [(n, Binder (TT n))]
193data Datatype n = Data { d_typename :: n,
194 d_typetag :: Int,
195 d_type :: (TT n),
196 d_cons :: [(n, TT n)] }
197 deriving (Show, Functor, Eq)
199instance Eq n => Eq (TT n) where
200 (==) (P xt x _) (P yt y _) = xt == yt && x == y
201 (==) (V x) (V y) = x == y
202 (==) (Bind _ xb xs) (Bind _ yb ys) = xb == yb && xs == ys
203 (==) (App fx ax) (App fy ay) = fx == fy && ax == ay
204 (==) (Set x) (Set y) = x == y
205 (==) (Constant x) (Constant y) = x == y
206 (==) _ _ = False
208-- A few handy operations on well typed terms:
210instantiate :: TT n -> TT n -> TT n
211instantiate e = subst 0 where
212 subst i (V x) | i == x = e
213 subst i (Bind x b sc) = Bind x (fmap (subst i) b) (subst (i+1) sc)
214 subst i (App f a) = App (subst i f) (subst i a)
215 subst i t = t
217pToV :: Eq n => n -> TT n -> TT n
218pToV n = pToV' n 0
219pToV' n i (P _ x _) | n == x = V i
220pToV' n i (Bind x b sc)
221 | n == x = Bind x (fmap (pToV' n i) b) sc
222 | otherwise = Bind x (fmap (pToV' n i) b) (pToV' n (i+1) sc)
223pToV' n i (App f a) = App (pToV' n i f) (pToV' n i a)
224pToV' n i t = t
226-- Convert several names. First in the list comes out as V 0
227pToVs :: Eq n => [n] -> TT n -> TT n
228pToVs ns tm = pToVs' ns tm 0 where
229 pToVs' [] tm i = tm
230 pToVs' (n:ns) tm i = pToV' n i (pToVs' ns tm (i+1))
232vToP :: TT n -> TT n
233vToP = vToP' [] where
234 vToP' env (V i) = let (n, b) = (env !! i) in
235 P Bound n (binderTy b)
236 vToP' env (Bind n b sc) = let b' = fmap (vToP' env) b in
237 Bind n b' (vToP' ((n, b'):env) sc)
238 vToP' env (App f a) = App (vToP' env f) (vToP' env a)
239 vToP' env t = t
241finalise :: Eq n => TT n -> TT n
242finalise (Bind x b sc) = Bind x (fmap finalise b) (pToV x (finalise sc))
243finalise (App f a) = App (finalise f) (finalise a)
244finalise t = t
246subst :: Eq n => n -> TT n -> TT n -> TT n
247subst n v tm = instantiate v (pToV n tm)
249substNames :: Eq n => [(n, TT n)] -> TT n -> TT n
250substNames [] t = t
251substNames ((n, tm) : xs) t = subst n tm (substNames xs t)
253-- Returns true if V 0 and bound name n do not occur in the term
255noOccurrence :: Eq n => n -> TT n -> Bool
256noOccurrence n t = no' 0 t
257 where
258 no' i (V x) = not (i == x)
259 no' i (P Bound x _) = not (n == x)
260 no' i (Bind n b sc) = noB' i b && no' (i+1) sc
261 where noB' i (Let t v) = no' i t && no' i v
262 noB' i (Guess t v) = no' i t && no' i v
263 noB' i b = no' i (binderTy b)
264 no' i (App f a) = no' i f && no' i a
265 no' i _ = True
267-- Return the arity of a (normalised) type
269arity :: TT n -> Int
270arity (Bind n (Pi t) sc) = 1 + arity sc
271arity _ = 0
273-- deconstruct an application; returns the function and a list of arguments
275unApply :: TT n -> (TT n, [TT n])
276unApply t = ua [] t where
277 ua args (App f a) = ua (a:args) f
278 ua args t = (t, args)
280mkApp :: TT n -> [TT n] -> TT n
281mkApp f [] = f
282mkApp f (a:as) = mkApp (App f a) as
284forget :: TT Name -> Raw
285forget tm = fe [] tm
286 where
287 fe env (P _ n _) = Var n
288 fe env (V i) = Var (env !! i)
289 fe env (Bind n b sc) = RBind n (fmap (fe env) b)
290 (fe (n:env) sc)
291 fe env (App f a) = RApp (fe env f) (fe env a)
292 fe env (Constant c)
293 = RConstant c
294 fe env (Set i) = RSet i
296bindAll :: [(n, Binder (TT n))] -> TT n -> TT n
297bindAll [] t =t
298bindAll ((n, b) : bs) t = Bind n b (bindAll bs t)
300bindTyArgs :: (TT n -> Binder (TT n)) -> [(n, TT n)] -> TT n -> TT n
301bindTyArgs b xs = bindAll (map (\ (n, ty) -> (n, b ty)) xs)
303getArgTys :: TT n -> [(n, TT n)]
304getArgTys (Bind n (Pi t) sc) = (n, t) : getArgTys sc
305getArgTys _ = []
307uniqueName :: Name -> [Name] -> Name
308uniqueName n hs | n `elem` hs = uniqueName (nextName n) hs
309 | otherwise = n
311nextName (MN i n) = MN (i+1) n
312nextName (UN x) = let (num', nm') = span isDigit (reverse x)
313 nm = reverse nm'
314 num = readN (reverse num') in
315 UN (nm ++ show (num+1))
316 where
317 readN "" = 0
318 readN x = read x
320type Term = TT Name
321type Type = Term
323type Env = EnvTT Name
325-- an environment with de Bruijn indices 'normalised' so that they all refer to
326-- this environment
328newtype WkEnvTT n = Wk (EnvTT n)
329type WkEnv = WkEnvTT Name
331instance (Eq n, Show n) => Show (TT n) where
332 show t = showEnv [] t
334instance Show Const where
335 show (I i) = show i
336 show (BI i) = show i ++ "L"
337 show (Fl f) = show f
338 show (Ch c) = show c
339 show (Str s) = show s
340 show IType = "Int"
341 show BIType = "Integer"
342 show FlType = "Float"
343 show ChType = "Char"
344 show StrType = "String"
345 show PtrType = "Ptr"
347showEnv env t = showEnv' env t False
348showEnvDbg env t = showEnv' env t True
350showEnv' env t dbg = se 10 env t where
351 se p env (P nt n t) = show n
352 -- ++ if dbg then "{" ++ show nt ++ " : " ++ se 10 env t ++ "}" else ""
353 se p env (V i) | i < length env = (show $ fst $ env!!i) ++
354 if dbg then "{" ++ show i ++ "}" else ""
355 | otherwise = "!!V " ++ show i ++ "!!"
356 se p env (Bind n b@(Pi t) sc)
357 | noOccurrence n sc && not dbg = bracket p 2 $ se 1 env t ++ " -> " ++ se 10 ((n,b):env) sc
358 se p env (Bind n b sc) = bracket p 2 $ sb env n b ++ se 10 ((n,b):env) sc
359 se p env (App f a) = bracket p 1 $ se 1 env f ++ " " ++ se 0 env a
360 se p env (Constant c) = show c
361 se p env (Set i) = "Set" ++ show i
363 sb env n (Lam t) = showb env "\\ " " => " n t
364 sb env n (Hole t) = showb env "? " ". " n t
365 sb env n (GHole t) = showb env "?defer " ". " n t
366 sb env n (Pi t) = showb env "(" ") -> " n t
367 sb env n (PVar t) = showb env "pat " ". " n t
368 sb env n (PVTy t) = showb env "pty " ". " n t
369 sb env n (Let t v) = showbv env "let " " in " n t v
370 sb env n (Guess t v) = showbv env "?? " " in " n t v
372 showb env op sc n t = op ++ show n ++ " : " ++ se 10 env t ++ sc
373 showbv env op sc n t v = op ++ show n ++ " : " ++ se 10 env t ++ " = " ++
374 se 10 env v ++ sc
376 bracket outer inner str | inner > outer = "(" ++ str ++ ")"
377 | otherwise = str
379-- Check whether a term has any holes in it - impure if so
381pureTerm :: TT n -> Bool
382pureTerm (App f a) = pureTerm f && pureTerm a
383pureTerm (Bind n b sc) = pureBinder b && pureTerm sc where
384 pureBinder (Hole _) = False
385 pureBinder (Guess _ _) = False
386 pureBinder (Let t v) = pureTerm t && pureTerm v
387 pureBinder t = pureTerm (binderTy t)
388pureTerm _ = True
390-- weaken a term by adding i to each de Bruijn index (i.e. lift it over i bindings)
392weakenTm :: Int -> TT n -> TT n
393weakenTm i t = wk i 0 t
394 where wk i min (V x) | x >= min = V (i + x)
395 wk i m (App f a) = App (wk i m f) (wk i m a)
396 wk i m (Bind x b sc) = Bind x (wkb i m b) (wk i (m + 1) sc)
397 wk i m t = t
398 wkb i m t = fmap (wk i m) t
400-- weaken an environment so that all the de Bruijn indices are correct according
401-- to the latest bound variable
403weakenEnv :: EnvTT n -> EnvTT n
404weakenEnv env = wk (length env - 1) env
405 where wk i [] = []
406 wk i ((n, b) : bs) = (n, weakenTmB i b) : wk (i - 1) bs
407 weakenTmB i (Let t v) = Let (weakenTm i t) (weakenTm i v)
408 weakenTmB i (Guess t v) = Guess (weakenTm i t) (weakenTm i v)
409 weakenTmB i t = t { binderTy = weakenTm i (binderTy t) }
411weakenTmEnv :: Int -> EnvTT n -> EnvTT n
412weakenTmEnv i = map (\ (n, b) -> (n, fmap (weakenTm i) b))
414orderPats :: Term -> Term
415orderPats tm = op [] tm
416 where
417 op ps (Bind n (PVar t) sc) = op ((n, t) : ps) sc
418 op ps sc = bindAll (map (\ (n, t) -> (n, PVar t)) (sortP ps)) sc
420 sortP ps = pick [] (reverse ps)
422 namesIn (P _ n _) = [n]
423 namesIn (Bind n b t) = nub $ nb b ++ (namesIn t \\ [n])
424 where nb (Let t v) = nub (namesIn t) ++ nub (namesIn v)
425 nb (Guess t v) = nub (namesIn t) ++ nub (namesIn v)
426 nb t = namesIn (binderTy t)
427 namesIn (App f a) = nub (namesIn f ++ namesIn a)
428 namesIn _ = []
430 pick acc [] = reverse acc
431 pick acc ((n, t) : ps) = pick (insert n t acc) ps
433 insert n t [] = [(n, t)]
434 insert n t ((n',t') : ps)
435 | n `elem` (namesIn t' ++ concatMap namesIn (map snd ps))
436 = (n', t') : insert n t ps
437 | otherwise = (n,t):(n',t'):ps