git.iko.soy/Idris-dev
on 08797ae help sign in
Idris-dev/src/Core/TT.hs
743 lines 24 kB history raw
1{-# LANGUAGE MultiParamTypeClasses, FunctionalDependencies, DeriveFunctor #-}
3module Core.TT where
5import Control.Monad.State
6import Debug.Trace
7import qualified Data.Map as Map
8import Data.Char
9import Data.List
10import qualified Data.Binary as B
11import Data.Binary hiding (get, put)
13import Util.Pretty hiding (Str)
15{- The language has:
16 * Full dependent types
17 * A hierarchy of universes, with cumulativity: Set : Set1, Set1 : Set2, ...
18 * Pattern matching letrec binding
19 * (primitive types defined externally)
21 Some technical stuff:
22 * Typechecker is kept as simple as possible
23 - no unification, just a checker for incomplete terms.
24 * We have a simple collection of tactics which we use to elaborate source
25 programs with implicit syntax into fully explicit terms.
26-}
28data Option = SetInSet
29 | CheckConv
30 deriving Eq
32data FC = FC { fc_fname :: String,
33 fc_line :: Int }
34 deriving Eq
35{-!
36deriving instance Binary FC
37!-}
39instance Sized FC where
40 size (FC f l) = 1 + length f
42instance Show FC where
43 show (FC f l) = f ++ ":" ++ show l
45data Err = Msg String
46 | CantUnify Term Term Err Int -- Int is 'score' - how much we did unify
47 | NoSuchVariable Name
48 | NotInjective Term Term Term
49 | CantResolve Term
50 | IncompleteTerm Term
51 | UniverseError
52 | ProgramLineComment
53 | At FC Err
54 deriving Eq
56instance Sized Err where
57 size (Msg msg) = length msg
58 size (CantUnify left right err score) = size left + size right + size err
59 size (NoSuchVariable name) = size name
60 size (NotInjective l c r) = size l + size c + size r
61 size (CantResolve trm) = size trm
62 size (IncompleteTerm trm) = size trm
63 size UniverseError = 1
64 size ProgramLineComment = 1
65 size (At fc err) = size fc + size err
67score :: Err -> Int
68score (CantUnify _ _ m s) = s + score m
69score (CantResolve _) = 20
70score (NoSuchVariable _) = 1000
71score _ = 0
73instance Show Err where
74 show (Msg s) = s
75 show (CantUnify l r e i) = "CantUnify " ++ show l ++ " " ++ show r ++ " "
76 ++ show e ++ " " ++ show i
77 show _ = "Error"
79instance Pretty Err where
80 pretty (Msg m) = text m
81 pretty (CantUnify l r e i) =
82 if size l + size r > breakingSize then
83 text "Cannot unify" <+> colon $$
84 nest nestingSize (pretty l <+> text "and" <+> pretty r) $$
85 nest nestingSize (text "where" <+> pretty e <+> text "with" <+> (text . show $ i))
86 else
87 text "Cannot unify" <+> colon <+> pretty l <+> text "and" <+> pretty r $$
88 nest nestingSize (text "where" <+> pretty e <+> text "with" <+> (text . show $ i))
89 pretty _ = text "Error"
91data TC a = OK a
92 | Error Err
93 deriving (Eq, Functor)
95instance Pretty a => Pretty (TC a) where
96 pretty (OK ok) = pretty ok
97 pretty (Error err) =
98 if size err > breakingSize then
99 text "Error" <+> colon $$ (nest nestingSize $ pretty err)
100 else
101 text "Error" <+> colon <+> pretty err
103instance Show a => Show (TC a) where
104 show (OK x) = show x
105 show (Error str) = "Error: " ++ show str
107-- at some point, this instance should also carry type checking options
108-- (e.g. Set:Set)
110instance Monad TC where
111 return = OK
112 x >>= k = case x of
113 OK v -> k v
114 Error e -> Error e
115 fail e = Error (Msg e)
117tfail :: Err -> TC a
118tfail e = Error e
120trun :: FC -> TC a -> TC a
121trun fc (OK a) = OK a
122trun fc (Error e) = Error (At fc e)
124instance MonadPlus TC where
125 mzero = fail "Unknown error"
126 (OK x) `mplus` _ = OK x
127 _ `mplus` (OK y) = OK y
128 err `mplus` _ = err
130discard :: Monad m => m a -> m ()
131discard f = f >> return ()
133showSep :: String -> [String] -> String
134showSep sep [] = ""
135showSep sep [x] = x
136showSep sep (x:xs) = x ++ sep ++ showSep sep xs
138pmap f (x, y) = (f x, f y)
140traceWhen True msg a = trace msg a
141traceWhen False _ a = a
143-- RAW TERMS ----------------------------------------------------------------
145-- Names are hierarchies of strings, describing scope (so no danger of
146-- duplicate names, but need to be careful on lookup).
147-- Also MN for machine chosen names
149data Name = UN String
150 | NS Name [String] -- root, namespaces
151 | MN Int String
152 deriving (Eq, Ord)
153{-!
154deriving instance Binary Name
155!-}
157instance Sized Name where
158 size (UN n) = 1
159 size (NS n els) = 1 + length els
160 size (MN i n) = 1
162instance Pretty Name where
163 pretty (UN n) = text n
164 pretty (NS n s) = pretty n
165 pretty (MN i s) = lbrace <+> text s <+> (text . show $ i) <+> rbrace
167instance Show Name where
168 show (UN n) = n
169 show (NS n s) = showSep "." (reverse s) ++ "." ++ show n
170 show (MN i s) = "{" ++ s ++ show i ++ "}"
173-- Contexts allow us to map names to things. A root name maps to a collection
174-- of things in different namespaces with that name.
176type Ctxt a = Map.Map Name (Map.Map Name a)
177emptyContext = Map.empty
179nsroot (NS n _) = n
180nsroot n = n
182addDef :: Name -> a -> Ctxt a -> Ctxt a
183addDef n v ctxt = case Map.lookup (nsroot n) ctxt of
184 Nothing -> Map.insert (nsroot n)
185 (Map.insert n v Map.empty) ctxt
186 Just xs -> Map.insert (nsroot n)
187 (Map.insert n v xs) ctxt
189{- lookup a name in the context, given an optional namespace.
190 The name (n) may itself have a (partial) namespace given.
192 Rules for resolution:
193 - if an explicit namespace is given, return the names which match it. If none
194 match, return all names.
195 - if the name has has explicit namespace given, return the names which match it
196 and ignore the given namespace.
197 - otherwise, return all names.
199-}
201lookupCtxtName :: Maybe [String] -> Name -> Ctxt a -> [(Name, a)]
202lookupCtxtName nspace n ctxt = case Map.lookup (nsroot n) ctxt of
203 Just xs -> filterNS (Map.toList xs)
204 Nothing -> []
205 where
206 filterNS [] = []
207 filterNS ((found, v) : xs)
208 | nsmatch n found = (found, v) : filterNS xs
209 | otherwise = filterNS xs
211 nsmatch (NS n ns) (NS p ps) = ns `isPrefixOf` ps
212 nsmatch (NS _ _) _ = False
213 nsmatch looking found = True
215lookupCtxt :: Maybe [String] -> Name -> Ctxt a -> [a]
216lookupCtxt ns n ctxt = map snd (lookupCtxtName ns n ctxt)
218updateDef :: Name -> (a -> a) -> Ctxt a -> Ctxt a
219updateDef n f ctxt
220 = let ds = lookupCtxtName Nothing n ctxt in
221 foldr (\ (n, t) c -> addDef n (f t) c) ctxt ds
223toAlist :: Ctxt a -> [(Name, a)]
224toAlist ctxt = let allns = map snd (Map.toList ctxt) in
225 concat (map (Map.toList) allns)
227addAlist :: Show a => [(Name, a)] -> Ctxt a -> Ctxt a
228addAlist [] ctxt = ctxt
229addAlist ((n, tm) : ds) ctxt = addDef n tm (addAlist ds ctxt)
231data Const = I Int | BI Integer | Fl Double | Ch Char | Str String
232 | IType | BIType | FlType | ChType | StrType
233 | PtrType | Forgot
234 deriving Eq
235{-!
236deriving instance Binary Const
237!-}
239instance Sized Const where
240 size _ = 1
242instance Pretty Const where
243 pretty (I i) = text . show $ i
244 pretty (BI i) = text . show $ i
245 pretty (Fl f) = text . show $ f
246 pretty (Ch c) = text . show $ c
247 pretty (Str s) = text s
248 pretty IType = text "Int"
249 pretty BIType = text "BigInt"
250 pretty FlType = text "Float"
251 pretty ChType = text "Char"
252 pretty StrType = text "String"
253 pretty PtrType = text "Ptr"
254 pretty Forgot = text "Forgot"
256data Raw = Var Name
257 | RBind Name (Binder Raw) Raw
258 | RApp Raw Raw
259 | RSet
260 | RForce Raw
261 | RConstant Const
262 deriving (Show, Eq)
264instance Sized Raw where
265 size (Var name) = 1
266 size (RBind name bind right) = 1 + size bind + size right
267 size (RApp left right) = 1 + size left + size right
268 size RSet = 1
269 size (RForce raw) = 1 + size raw
270 size (RConstant const) = size const
272instance Pretty Raw where
273 pretty = text . show
275{-!
276deriving instance Binary Raw
277!-}
279data Binder b = Lam { binderTy :: b }
280 | Pi { binderTy :: b }
281 | Let { binderTy :: b,
282 binderVal :: b }
283 | NLet { binderTy :: b,
284 binderVal :: b }
285 | Hole { binderTy :: b}
286 | GHole { binderTy :: b}
287 | Guess { binderTy :: b,
288 binderVal :: b }
289 | PVar { binderTy :: b }
290 | PVTy { binderTy :: b }
291 deriving (Show, Eq, Functor)
292{-!
293deriving instance Binary Binder
294!-}
296instance Sized a => Sized (Binder a) where
297 size (Lam ty) = 1 + size ty
298 size (Pi ty) = 1 + size ty
299 size (Let ty val) = 1 + size ty + size val
300 size (NLet ty val) = 1 + size ty + size val
301 size (Hole ty) = 1 + size ty
302 size (GHole ty) = 1 + size ty
303 size (Guess ty val) = 1 + size ty + size val
304 size (PVar ty) = 1 + size ty
305 size (PVTy ty) = 1 + size ty
307fmapMB :: Monad m => (a -> m b) -> Binder a -> m (Binder b)
308fmapMB f (Let t v) = liftM2 Let (f t) (f v)
309fmapMB f (NLet t v) = liftM2 NLet (f t) (f v)
310fmapMB f (Guess t v) = liftM2 Guess (f t) (f v)
311fmapMB f (Lam t) = liftM Lam (f t)
312fmapMB f (Pi t) = liftM Pi (f t)
313fmapMB f (Hole t) = liftM Hole (f t)
314fmapMB f (GHole t) = liftM GHole (f t)
315fmapMB f (PVar t) = liftM PVar (f t)
316fmapMB f (PVTy t) = liftM PVTy (f t)
318raw_apply :: Raw -> [Raw] -> Raw
319raw_apply f [] = f
320raw_apply f (a : as) = raw_apply (RApp f a) as
322raw_unapply :: Raw -> (Raw, [Raw])
323raw_unapply t = ua [] t where
324 ua args (RApp f a) = ua (a:args) f
325 ua args t = (t, args)
327data RawFun = RawFun { rtype :: Raw,
328 rval :: Raw
329 }
330 deriving Show
332data RawDatatype = RDatatype Name Raw [(Name, Raw)]
333 deriving Show
335data RDef = RFunction RawFun
336 | RConst Raw
337 | RData RawDatatype
338 deriving Show
340type RProgram = [(Name, RDef)]
342-- WELL TYPED TERMS ---------------------------------------------------------
344data UExp = UVar Int -- universe variable
345 | UVal Int -- explicit universe level
346 deriving (Eq, Ord)
348instance Sized UExp where
349 size _ = 1
351-- We assume that universe levels have been checked, so anything external
352-- can just have the same universe variable and we won't get any new
353-- cycles.
355instance Binary UExp where
356 put x = return ()
357 get = return (UVar (-1))
359instance Show UExp where
360 show (UVar x) | x < 26 = [toEnum (x + fromEnum 'a')]
361 | otherwise = toEnum ((x `mod` 26) + fromEnum 'a') : show (x `div` 26)
362 show (UVal x) = show x
363-- show (UMax l r) = "max(" ++ show l ++ ", " ++ show r ++")"
365data UConstraint = ULT UExp UExp
366 | ULE UExp UExp
367 deriving Eq
369instance Show UConstraint where
370 show (ULT x y) = show x ++ " < " ++ show y
371 show (ULE x y) = show x ++ " <= " ++ show y
373type UCs = (Int, [UConstraint])
375data NameType = Bound | Ref | DCon Int Int | TCon Int Int
376 deriving (Show)
377{-!
378deriving instance Binary NameType
379!-}
381instance Sized NameType where
382 size _ = 1
384instance Pretty NameType where
385 pretty = text . show
387instance Eq NameType where
388 Bound == Bound = True
389 Ref == Ref = True
390 DCon _ a == DCon _ b = (a == b) -- ignore tag
391 TCon _ a == TCon _ b = (a == b) -- ignore tag
392 _ == _ = False
394data TT n = P NameType n (TT n) -- embed type
395 | V Int
396 | Bind n (Binder (TT n)) (TT n)
397 | App (TT n) (TT n) -- function, function type, arg
398 | Constant Const
399 | Erased
400 | Set UExp
401 deriving Functor
402{-!
403deriving instance Binary TT
404!-}
406instance Sized a => Sized (TT a) where
407 size (P name n trm) = 1 + size name + size n + size trm
408 size (V v) = 1
409 size (Bind nm binder bdy) = 1 + size nm + size binder + size bdy
410 size (App l r) = 1 + size l + size r
411 size (Constant c) = size c
412 size Erased = 1
413 size (Set u) = 1 + size u
415instance Pretty a => Pretty (TT a) where
416 pretty _ = text "test"
418type EnvTT n = [(n, Binder (TT n))]
420data Datatype n = Data { d_typename :: n,
421 d_typetag :: Int,
422 d_type :: (TT n),
423 d_cons :: [(n, TT n)] }
424 deriving (Show, Functor, Eq)
426instance Eq n => Eq (TT n) where
427 (==) (P xt x _) (P yt y _) = xt == yt && x == y
428 (==) (V x) (V y) = x == y
429 (==) (Bind _ xb xs) (Bind _ yb ys) = xb == yb && xs == ys
430 (==) (App fx ax) (App fy ay) = fx == fy && ax == ay
431 (==) (Set _) (Set _) = True -- deal with constraints later
432 (==) (Constant x) (Constant y) = x == y
433 (==) Erased _ = True
434 (==) _ Erased = True
435 (==) _ _ = False
437-- A few handy operations on well typed terms:
439isInjective :: TT n -> Bool
440isInjective (P (DCon _ _) _ _) = True
441isInjective (P (TCon _ _) _ _) = True
442isInjective (Constant _) = True
443isInjective (Set x) = True
444isInjective (Bind _ (Pi _) sc) = True
445isInjective (App f a) = isInjective f
446isInjective _ = False
448instantiate :: TT n -> TT n -> TT n
449instantiate e = subst 0 where
450 subst i (V x) | i == x = e
451 subst i (Bind x b sc) = Bind x (fmap (subst i) b) (subst (i+1) sc)
452 subst i (App f a) = App (subst i f) (subst i a)
453 subst i t = t
455pToV :: Eq n => n -> TT n -> TT n
456pToV n = pToV' n 0
457pToV' n i (P _ x _) | n == x = V i
458pToV' n i (Bind x b sc)
459 | n == x = Bind x (fmap (pToV' n i) b) sc
460 | otherwise = Bind x (fmap (pToV' n i) b) (pToV' n (i+1) sc)
461pToV' n i (App f a) = App (pToV' n i f) (pToV' n i a)
462pToV' n i t = t
464-- Convert several names. First in the list comes out as V 0
465pToVs :: Eq n => [n] -> TT n -> TT n
466pToVs ns tm = pToVs' ns tm 0 where
467 pToVs' [] tm i = tm
468 pToVs' (n:ns) tm i = pToV' n i (pToVs' ns tm (i+1))
470vToP :: TT n -> TT n
471vToP = vToP' [] where
472 vToP' env (V i) = let (n, b) = (env !! i) in
473 P Bound n (binderTy b)
474 vToP' env (Bind n b sc) = let b' = fmap (vToP' env) b in
475 Bind n b' (vToP' ((n, b'):env) sc)
476 vToP' env (App f a) = App (vToP' env f) (vToP' env a)
477 vToP' env t = t
479finalise :: Eq n => TT n -> TT n
480finalise (Bind x b sc) = Bind x (fmap finalise b) (pToV x (finalise sc))
481finalise (App f a) = App (finalise f) (finalise a)
482finalise t = t
484subst :: Eq n => n -> TT n -> TT n -> TT n
485subst n v tm = instantiate v (pToV n tm)
487substNames :: Eq n => [(n, TT n)] -> TT n -> TT n
488substNames [] t = t
489substNames ((n, tm) : xs) t = subst n tm (substNames xs t)
491-- Returns true if V 0 and bound name n do not occur in the term
493noOccurrence :: Eq n => n -> TT n -> Bool
494noOccurrence n t = no' 0 t
495 where
496 no' i (V x) = not (i == x)
497 no' i (P Bound x _) = not (n == x)
498 no' i (Bind n b sc) = noB' i b && no' (i+1) sc
499 where noB' i (Let t v) = no' i t && no' i v
500 noB' i (Guess t v) = no' i t && no' i v
501 noB' i b = no' i (binderTy b)
502 no' i (App f a) = no' i f && no' i a
503 no' i _ = True
505-- Returns all names used free in the term
507freeNames :: Eq n => TT n -> [n]
508freeNames (P _ n _) = [n]
509freeNames (Bind n (Let t v) sc) = nub $ freeNames v ++ (freeNames sc \\ [n])
510 ++ freeNames t
511freeNames (Bind n b sc) = nub $ freeNames (binderTy b) ++ (freeNames sc \\ [n])
512freeNames (App f a) = nub $ freeNames f ++ freeNames a
513freeNames _ = []
515-- Return the arity of a (normalised) type
517arity :: TT n -> Int
518arity (Bind n (Pi t) sc) = 1 + arity sc
519arity _ = 0
521-- deconstruct an application; returns the function and a list of arguments
523unApply :: TT n -> (TT n, [TT n])
524unApply t = ua [] t where
525 ua args (App f a) = ua (a:args) f
526 ua args t = (t, args)
528mkApp :: TT n -> [TT n] -> TT n
529mkApp f [] = f
530mkApp f (a:as) = mkApp (App f a) as
532forget :: TT Name -> Raw
533forget tm = fe [] tm
534 where
535 fe env (P _ n _) = Var n
536 fe env (V i) = Var (env !! i)
537 fe env (Bind n b sc) = RBind n (fmap (fe env) b)
538 (fe (n:env) sc)
539 fe env (App f a) = RApp (fe env f) (fe env a)
540 fe env (Constant c)
541 = RConstant c
542 fe env (Set i) = RSet
543 fe env Erased = RConstant Forgot
545bindAll :: [(n, Binder (TT n))] -> TT n -> TT n
546bindAll [] t =t
547bindAll ((n, b) : bs) t = Bind n b (bindAll bs t)
549bindTyArgs :: (TT n -> Binder (TT n)) -> [(n, TT n)] -> TT n -> TT n
550bindTyArgs b xs = bindAll (map (\ (n, ty) -> (n, b ty)) xs)
552getArgTys :: TT n -> [(n, TT n)]
553getArgTys (Bind n (Pi t) sc) = (n, t) : getArgTys sc
554getArgTys _ = []
556getRetTy :: TT n -> TT n
557getRetTy (Bind n (PVar _) sc) = getRetTy sc
558getRetTy (Bind n (PVTy _) sc) = getRetTy sc
559getRetTy (Bind n (Pi _) sc) = getRetTy sc
560getRetTy sc = sc
562uniqueName :: Name -> [Name] -> Name
563uniqueName n hs | n `elem` hs = uniqueName (nextName n) hs
564 | otherwise = n
566nextName (NS x s) = NS (nextName x) s
567nextName (MN i n) = MN (i+1) n
568nextName (UN x) = let (num', nm') = span isDigit (reverse x)
569 nm = reverse nm'
570 num = readN (reverse num') in
571 UN (nm ++ show (num+1))
572 where
573 readN "" = 0
574 readN x = read x
576type Term = TT Name
577type Type = Term
579type Env = EnvTT Name
581-- an environment with de Bruijn indices 'normalised' so that they all refer to
582-- this environment
584newtype WkEnvTT n = Wk (EnvTT n)
585type WkEnv = WkEnvTT Name
587instance (Eq n, Show n) => Show (TT n) where
588 show t = showEnv [] t
590instance Show Const where
591 show (I i) = show i
592 show (BI i) = show i ++ "L"
593 show (Fl f) = show f
594 show (Ch c) = show c
595 show (Str s) = show s
596 show IType = "Int"
597 show BIType = "Integer"
598 show FlType = "Float"
599 show ChType = "Char"
600 show StrType = "String"
601 show PtrType = "Ptr"
603showEnv env t = showEnv' env t False
604showEnvDbg env t = showEnv' env t True
606prettyEnv env t = prettyEnv' env t False
607 where
608 prettyEnv' env t dbg = prettySe 10 env t dbg
610 bracket outer inner p
611 | inner > outer = lparen <> p <> rparen
612 | otherwise = p
614 prettySe p env (P nt n t) debug =
615 pretty n <+>
616 if debug then
617 lbrack <+> pretty nt <+> colon <+> prettySe 10 env t debug <+> rbrack
618 else
619 empty
620 prettySe p env (V i) debug
621 | i < length env =
622 if debug then
623 text . show . fst $ env!!i
624 else
625 lbrack <+> text (show i) <+> rbrack
626 | otherwise = text "unbound" <+> text (show i) <+> text "!"
627 prettySe p env (Bind n b@(Pi t) sc) debug
628 | noOccurrence n sc && not debug =
629 bracket p 2 $ prettySb env n b debug <> prettySe 10 ((n, b):env) sc debug
630 prettySe p env (Bind n b sc) debug =
631 bracket p 2 $ prettySb env n b debug <> prettySe 10 ((n, b):env) sc debug
632 prettySe p env (App f a) debug =
633 bracket p 1 $ prettySe 1 env f debug <+> prettySe 0 env a debug
634 prettySe p env (Constant c) debug = pretty c
635 prettySe p env Erased debug = text "[_]"
636 prettySe p env (Set i) debug = text "Set" <+> (text . show $ i)
638 prettySb env n (Lam t) = prettyB env "λ" "=>" n t
639 prettySb env n (Hole t) = prettyB env "?defer" "." n t
640 prettySb env n (Pi t) = prettyB env "(" ") ->" n t
641 prettySb env n (PVar t) = prettyB env "pat" "." n t
642 prettySb env n (PVTy t) = prettyB env "pty" "." n t
643 prettySb env n (Let t v) = prettyBv env "let" "in" n t v
644 prettySb env n (Guess t v) = prettyBv env "??" "in" n t v
646 prettyB env op sc n t debug =
647 text op <> pretty n <+> colon <+> prettySe 10 env t debug <> text sc
649 prettyBv env op sc n t v debug =
650 text op <> pretty n <+> colon <+> prettySe 10 env t debug <+> text "=" <+>
651 prettySe 10 env v debug <> text sc
654showEnv' env t dbg = se 10 env t where
655 se p env (P nt n t) = show n
656 ++ if dbg then "{" ++ show nt ++ " : " ++ se 10 env t ++ "}" else ""
657 se p env (V i) | i < length env = (show $ fst $ env!!i) ++
658 if dbg then "{" ++ show i ++ "}" else ""
659 | otherwise = "!!V " ++ show i ++ "!!"
660 se p env (Bind n b@(Pi t) sc)
661 | noOccurrence n sc && not dbg = bracket p 2 $ se 1 env t ++ " -> " ++ se 10 ((n,b):env) sc
662 se p env (Bind n b sc) = bracket p 2 $ sb env n b ++ se 10 ((n,b):env) sc
663 se p env (App f a) = bracket p 1 $ se 1 env f ++ " " ++ se 0 env a
664 se p env (Constant c) = show c
665 se p env Erased = "[__]"
666 se p env (Set i) = "Set " ++ show i
668 sb env n (Lam t) = showb env "\\ " " => " n t
669 sb env n (Hole t) = showb env "? " ". " n t
670 sb env n (GHole t) = showb env "?defer " ". " n t
671 sb env n (Pi t) = showb env "(" ") -> " n t
672 sb env n (PVar t) = showb env "pat " ". " n t
673 sb env n (PVTy t) = showb env "pty " ". " n t
674 sb env n (Let t v) = showbv env "let " " in " n t v
675 sb env n (Guess t v) = showbv env "?? " " in " n t v
677 showb env op sc n t = op ++ show n ++ " : " ++ se 10 env t ++ sc
678 showbv env op sc n t v = op ++ show n ++ " : " ++ se 10 env t ++ " = " ++
679 se 10 env v ++ sc
681 bracket outer inner str | inner > outer = "(" ++ str ++ ")"
682 | otherwise = str
684-- Check whether a term has any holes in it - impure if so
686pureTerm :: TT n -> Bool
687pureTerm (App f a) = pureTerm f && pureTerm a
688pureTerm (Bind n b sc) = pureBinder b && pureTerm sc where
689 pureBinder (Hole _) = False
690 pureBinder (Guess _ _) = False
691 pureBinder (Let t v) = pureTerm t && pureTerm v
692 pureBinder t = pureTerm (binderTy t)
693pureTerm _ = True
695-- weaken a term by adding i to each de Bruijn index (i.e. lift it over i bindings)
697weakenTm :: Int -> TT n -> TT n
698weakenTm i t = wk i 0 t
699 where wk i min (V x) | x >= min = V (i + x)
700 wk i m (App f a) = App (wk i m f) (wk i m a)
701 wk i m (Bind x b sc) = Bind x (wkb i m b) (wk i (m + 1) sc)
702 wk i m t = t
703 wkb i m t = fmap (wk i m) t
705-- weaken an environment so that all the de Bruijn indices are correct according
706-- to the latest bound variable
708weakenEnv :: EnvTT n -> EnvTT n
709weakenEnv env = wk (length env - 1) env
710 where wk i [] = []
711 wk i ((n, b) : bs) = (n, weakenTmB i b) : wk (i - 1) bs
712 weakenTmB i (Let t v) = Let (weakenTm i t) (weakenTm i v)
713 weakenTmB i (Guess t v) = Guess (weakenTm i t) (weakenTm i v)
714 weakenTmB i t = t { binderTy = weakenTm i (binderTy t) }
716weakenTmEnv :: Int -> EnvTT n -> EnvTT n
717weakenTmEnv i = map (\ (n, b) -> (n, fmap (weakenTm i) b))
719orderPats :: Term -> Term
720orderPats tm = op [] tm
721 where
722 op ps (Bind n (PVar t) sc) = op ((n, t) : ps) sc
723 op ps sc = bindAll (map (\ (n, t) -> (n, PVar t)) (sortP ps)) sc
725 sortP ps = pick [] (reverse ps)
727 namesIn (P _ n _) = [n]
728 namesIn (Bind n b t) = nub $ nb b ++ (namesIn t \\ [n])
729 where nb (Let t v) = nub (namesIn t) ++ nub (namesIn v)
730 nb (Guess t v) = nub (namesIn t) ++ nub (namesIn v)
731 nb t = namesIn (binderTy t)
732 namesIn (App f a) = nub (namesIn f ++ namesIn a)
733 namesIn _ = []
735 pick acc [] = reverse acc
736 pick acc ((n, t) : ps) = pick (insert n t acc) ps
738 insert n t [] = [(n, t)]
739 insert n t ((n',t') : ps)
740 | n `elem` (namesIn t' ++ concatMap namesIn (map snd ps))
741 = (n', t') : insert n t ps
742 | otherwise = (n,t):(n',t'):ps