git.iko.soy/Idris-dev
on 09eebbf help sign in
Idris-dev/src/IRTS/Lang.hs
233 lines 9.8 kB history raw
1module IRTS.Lang where
3import Control.Monad.State hiding (lift)
4import Core.TT
5import Data.List
6import Debug.Trace
8data LVar = Loc Int | Glob Name
9 deriving (Show, Eq)
11data LExp = LV LVar
12 | LApp Bool LExp [LExp] -- True = tail call
13 | LLazyApp Name [LExp] -- True = tail call
14 | LLazyExp LExp
15 | LForce LExp -- make sure Exp is evaluted
16 | LLet Name LExp LExp -- name just for pretty printing
17 | LLam [Name] LExp -- lambda, lifted out before compiling
18 | LProj LExp Int -- projection
19 | LCon Int Name [LExp]
20 | LCase LExp [LAlt]
21 | LConst Const
22 | LForeign FLang FType String [(FType, LExp)]
23 | LOp PrimFn [LExp]
24 | LNothing
25 | LError String
26 deriving Eq
28-- Primitive operators. Backends are not *required* to implement all
29-- of these, but should report an error if they are unable
31data PrimFn = LPlus ArithTy | LMinus ArithTy | LTimes ArithTy
32 | LUDiv IntTy | LSDiv ArithTy | LURem IntTy | LSRem ArithTy
33 | LAnd IntTy | LOr IntTy | LXOr IntTy | LCompl IntTy
34 | LSHL IntTy | LLSHR IntTy | LASHR IntTy
35 | LEq ArithTy | LLt ArithTy | LLe ArithTy | LGt ArithTy | LGe ArithTy
36 | LSExt IntTy IntTy | LZExt IntTy IntTy | LTrunc IntTy IntTy
37 | LStrConcat | LStrLt | LStrEq | LStrLen
38 | LIntFloat IntTy | LFloatInt IntTy | LIntStr IntTy | LStrInt IntTy
39 | LFloatStr | LStrFloat | LChInt IntTy | LIntCh IntTy
40 | LPrintNum | LPrintStr | LReadStr
41 | LBitCast ArithTy ArithTy -- Only for values of equal width
43 | LFExp | LFLog | LFSin | LFCos | LFTan | LFASin | LFACos | LFATan
44 | LFSqrt | LFFloor | LFCeil
46 -- construction element extraction element insertion
47 | LMkVec NativeTy Int | LIdxVec NativeTy Int | LUpdateVec NativeTy Int
49 | LStrHead | LStrTail | LStrCons | LStrIndex | LStrRev
50 | LStdIn | LStdOut | LStdErr
52 | LFork
53 | LPar -- evaluate argument anywhere, possibly on another
54 -- core or another machine. 'id' is a valid implementation
55 | LVMPtr
56 | LNoOp
57 deriving (Show, Eq)
59-- Supported target languages for foreign calls
61data FCallType = FStatic | FObject | FConstructor
62 deriving (Show, Eq)
64data FLang = LANG_C | LANG_JAVA FCallType
65 deriving (Show, Eq)
67data FType = FArith ArithTy
68 | FFunction
69 | FFunctionIO
70 | FString
71 | FUnit
72 | FPtr
73 | FAny
74 deriving (Show, Eq)
76data LAlt = LConCase Int Name [Name] LExp
77 | LConstCase Const LExp
78 | LDefaultCase LExp
79 deriving (Show, Eq)
81data LDecl = LFun [LOpt] Name [Name] LExp -- options, name, arg names, def
82 | LConstructor Name Int Int -- constructor name, tag, arity
83 deriving (Show, Eq)
85type LDefs = Ctxt LDecl
87data LOpt = Inline | NoInline
88 deriving (Show, Eq)
90addTags :: Int -> [(Name, LDecl)] -> (Int, [(Name, LDecl)])
91addTags i ds = tag i ds []
92 where tag i ((n, LConstructor n' (-1) a) : as) acc
93 = tag (i + 1) as ((n, LConstructor n' i a) : acc)
94 tag i ((n, LConstructor n' t a) : as) acc
95 = tag i as ((n, LConstructor n' t a) : acc)
96 tag i (x : as) acc = tag i as (x : acc)
97 tag i [] acc = (i, reverse acc)
99data LiftState = LS Name Int [(Name, LDecl)]
101lname (NS n x) i = NS (lname n i) x
102lname (UN n) i = MN i n
103lname x i = MN i (show x)
105liftAll :: [(Name, LDecl)] -> [(Name, LDecl)]
106liftAll xs = concatMap (\ (x, d) -> lambdaLift x d) xs
108lambdaLift :: Name -> LDecl -> [(Name, LDecl)]
109lambdaLift n (LFun _ _ args e)
110 = let (e', (LS _ _ decls)) = runState (lift args e) (LS n 0 []) in
111 (n, LFun [] n args e') : decls
112lambdaLift n x = [(n, x)]
114getNextName :: State LiftState Name
115getNextName = do LS n i ds <- get
116 put (LS n (i + 1) ds)
117 return (lname n i)
119addFn :: Name -> LDecl -> State LiftState ()
120addFn fn d = do LS n i ds <- get
121 put (LS n i ((fn, d) : ds))
123lift :: [Name] -> LExp -> State LiftState LExp
124lift env (LV v) = return (LV v) -- Lifting happens before these can exist...
125lift env (LApp tc (LV (Glob n)) args) = do args' <- mapM (lift env) args
126 return (LApp tc (LV (Glob n)) args')
127lift env (LApp tc f args) = do f' <- lift env f
128 fn <- getNextName
129 addFn fn (LFun [Inline] fn env f')
130 args' <- mapM (lift env) args
131 return (LApp tc (LV (Glob fn)) (map (LV . Glob) env ++ args'))
132lift env (LLazyApp n args) = do args' <- mapM (lift env) args
133 return (LLazyApp n args')
134lift env (LLazyExp (LConst c)) = return (LConst c)
135-- lift env (LLazyExp (LApp tc (LV (Glob f)) args))
136-- = lift env (LLazyApp f args)
137lift env (LLazyExp e) = do e' <- lift env e
138 let usedArgs = nub $ usedIn env e'
139 fn <- getNextName
140 addFn fn (LFun [NoInline] fn usedArgs e')
141 return (LLazyApp fn (map (LV . Glob) usedArgs))
142lift env (LForce e) = do e' <- lift env e
143 return (LForce e')
144lift env (LLet n v e) = do v' <- lift env v
145 e' <- lift (env ++ [n]) e
146 return (LLet n v' e')
147lift env (LLam args e) = do e' <- lift (env ++ args) e
148 let usedArgs = nub $ usedIn env e'
149 fn <- getNextName
150 addFn fn (LFun [Inline] fn (usedArgs ++ args) e')
151 return (LApp False (LV (Glob fn)) (map (LV . Glob) usedArgs))
152lift env (LProj t i) = do t' <- lift env t
153 return (LProj t' i)
154lift env (LCon i n args) = do args' <- mapM (lift env) args
155 return (LCon i n args')
156lift env (LCase e alts) = do alts' <- mapM liftA alts
157 e' <- lift env e
158 return (LCase e' alts')
159 where
160 liftA (LConCase i n args e) = do e' <- lift (env ++ args) e
161 return (LConCase i n args e')
162 liftA (LConstCase c e) = do e' <- lift env e
163 return (LConstCase c e')
164 liftA (LDefaultCase e) = do e' <- lift env e
165 return (LDefaultCase e')
166lift env (LConst c) = return (LConst c)
167lift env (LForeign l t s args) = do args' <- mapM (liftF env) args
168 return (LForeign l t s args')
169 where
170 liftF env (t, e) = do e' <- lift env e
171 return (t, e')
172lift env (LOp f args) = do args' <- mapM (lift env) args
173 return (LOp f args')
174lift env (LError str) = return $ LError str
175lift env LNothing = return $ LNothing
177-- Return variables in list which are used in the expression
179usedArg env n | n `elem` env = [n]
180 | otherwise = []
182usedIn :: [Name] -> LExp -> [Name]
183usedIn env (LV (Glob n)) = usedArg env n
184usedIn env (LApp _ e args) = usedIn env e ++ concatMap (usedIn env) args
185usedIn env (LLazyApp n args) = concatMap (usedIn env) args ++ usedArg env n
186usedIn env (LLazyExp e) = usedIn env e
187usedIn env (LForce e) = usedIn env e
188usedIn env (LLet n v e) = usedIn env v ++ usedIn (env \\ [n]) e
189usedIn env (LLam ns e) = usedIn (env \\ ns) e
190usedIn env (LCon i n args) = concatMap (usedIn env) args
191usedIn env (LProj t i) = usedIn env t
192usedIn env (LCase e alts) = usedIn env e ++ concatMap (usedInA env) alts
193 where usedInA env (LConCase i n ns e) = usedIn env e
194 usedInA env (LConstCase c e) = usedIn env e
195 usedInA env (LDefaultCase e) = usedIn env e
196usedIn env (LForeign _ _ _ args) = concatMap (usedIn env) (map snd args)
197usedIn env (LOp f args) = concatMap (usedIn env) args
198usedIn env _ = []
200instance Show LExp where
201 show e = show' [] e where
202 show' env (LV (Loc i)) = env!!i
203 show' env (LV (Glob n)) = show n
204 show' env (LLazyApp e args) = show e ++ "|(" ++
205 showSep ", " (map (show' env) args) ++")"
206 show' env (LApp _ e args) = show' env e ++ "(" ++
207 showSep ", " (map (show' env) args) ++")"
208 show' env (LLazyExp e) = "%lazy(" ++ show' env e ++ ")"
209 show' env (LForce e) = "%force(" ++ show' env e ++ ")"
210 show' env (LLet n v e) = "let " ++ show n ++ " = " ++ show' env v ++ " in " ++
211 show' (env ++ [show n]) e
212 show' env (LLam args e) = "\\ " ++ showSep "," (map show args) ++ " => " ++
213 show' (env ++ (map show args)) e
214 show' env (LProj t i) = show t ++ "!" ++ show i
215 show' env (LCon i n args) = show n ++ ")" ++ showSep ", " (map (show' env) args) ++ ")"
216 show' env (LCase e alts) = "case " ++ show' env e ++ " of {\n\t" ++
217 showSep "\n\t| " (map (showAlt env) alts)
218 show' env (LConst c) = show c
219 show' env (LForeign lang ty n args)
220 = "foreign " ++ n ++ "(" ++ showSep ", " (map (show' env) (map snd args)) ++ ")"
221 show' env (LOp f args) = show f ++ "(" ++ showSep ", " (map (show' env) args) ++ ")"
222 show' env (LError str) = "error " ++ show str
223 show' env LNothing = "____"
225 showAlt env (LConCase _ n args e)
226 = show n ++ "(" ++ showSep ", " (map show args) ++ ") => "
227 ++ show' env e
228 showAlt env (LConstCase c e) = show c ++ " => " ++ show' env e
229 showAlt env (LDefaultCase e) = "_ => " ++ show' env e