git.iko.soy/Idris-dev
on 2402885 help sign in
Idris-dev/src/Core/TT.hs
356 lines 11 kB history raw
1{-# LANGUAGE MultiParamTypeClasses, FunctionalDependencies, DeriveFunctor #-}
3module Core.TT where
5import Control.Monad.State
6import Debug.Trace
7import qualified Data.Map as Map
9{- The language has:
10 * Full dependent types
11 * A hierarchy of universes, with cumulativity: Set : Set1, Set1 : Set2, ...
12 * Pattern matching letrec binding
13 * (primitive types defined externally)
15 Some technical stuff:
16 * Typechecker is kept as simple as possible
17 - no unification, just a checker for incomplete terms.
18 * We have a simple collection of tactics which we use to elaborate source
19 programs with implicit syntax into fully explicit terms.
20-}
22data Option = SetInSet
23 | CheckConv
24 deriving Eq
26data Err = Msg String
27 | CantUnify Term Term
28 deriving Eq
30instance Show Err where
31 show (Msg s) = s
33data TC a = OK a
34 | Error Err
35 deriving (Eq, Functor)
37instance Show a => Show (TC a) where
38 show (OK x) = show x
39 show (Error str) = "Error: " ++ (show str)
41-- at some point, this instance should also carry type checking options
42-- (e.g. Set:Set)
44instance Monad TC where
45 return = OK
46 x >>= k = case x of
47 OK v -> k v
48 Error e -> Error e
49 fail e = Error (Msg e)
51tfail :: Err -> TC a
52tfail e = Error e
54instance MonadPlus TC where
55 mzero = fail "Unknown error"
56 (OK x) `mplus` _ = OK x
57 _ `mplus` (OK y) = OK y
58 err `mplus` _ = err
60discard :: Monad m => m a -> m ()
61discard f = f >> return ()
63showSep :: String -> [String] -> String
64showSep sep [] = ""
65showSep sep [x] = x
66showSep sep (x:xs) = x ++ sep ++ showSep sep xs
68-- RAW TERMS ----------------------------------------------------------------
70-- Names are hierarchies of strings, describing scope (so no danger of
71-- duplicate names, but need to be careful on lookup).
72-- Also MN for machine chosen names
74data Name = UN [String]
75 | MN Int String
76 deriving (Eq, Ord)
78instance Show Name where
79 show (UN [n]) = n
80 show (UN (n:ns)) = show (UN [n]) ++ "." ++ show (UN ns)
81 show (MN i s) = "{" ++ s ++ show i ++ "}"
84-- Contexts allow us to map names to things
85-- TODO: Namespaces and ambiguous names
87type Ctxt a = Map.Map Name a
88emptyContext = Map.empty
90addDef :: Name -> a -> Ctxt a -> Ctxt a
91addDef = Map.insert
93lookupCtxt :: Name -> Ctxt a -> Maybe a
94lookupCtxt = Map.lookup
96toAlist :: Ctxt a -> [(Name, a)]
97toAlist = Map.toList
99addAlist :: [(Name, a)] -> Ctxt a -> Ctxt a
100addAlist [] ctxt = ctxt
101addAlist ((n, tm) : ds) ctxt = addDef n tm (addAlist ds ctxt)
103data Const = I Int | Fl Double | Ch Char | Str String
104 | IType | FlType | ChType | StrType | PtrType
105 deriving Eq
107data Raw = Var Name
108 | RBind Name (Binder Raw) Raw
109 | RApp Raw Raw
110 | RSet Int
111 | RConstant Const
112 deriving Show
114data Binder b = Lam { binderTy :: b }
115 | Pi { binderTy :: b }
116 | Let { binderTy :: b,
117 binderVal :: b }
118 | NLet { binderTy :: b,
119 binderVal :: b }
120 | Hole { binderTy :: b}
121 | GHole { binderTy :: b}
122 | Guess { binderTy :: b,
123 binderVal :: b }
124 | PVar { binderTy :: b }
125 | PVTy { binderTy :: b }
126 deriving (Show, Eq, Functor)
128raw_apply :: Raw -> [Raw] -> Raw
129raw_apply f [] = f
130raw_apply f (a : as) = raw_apply (RApp f a) as
132data RawFun = RawFun { rtype :: Raw,
133 rval :: Raw
134 }
135 deriving Show
137data RawDatatype = RDatatype Name Raw [(Name, Raw)]
138 deriving Show
140data RDef = RFunction RawFun
141 | RConst Raw
142 | RData RawDatatype
143 deriving Show
145type RProgram = [(Name, RDef)]
147-- WELL TYPED TERMS ---------------------------------------------------------
149data NameType = Bound | Ref | DCon Int Int | TCon Int
150 deriving (Show, Eq)
152data TT n = P NameType n (TT n) -- embed type
153 | V Int
154 | Bind n (Binder (TT n)) (TT n)
155 | App (TT n) (TT n) -- function, function type, arg
156 | Constant Const
157 | Set Int
158 deriving Functor
160type EnvTT n = [(n, Binder (TT n))]
162data Datatype n = Data { d_typename :: n,
163 d_type :: (TT n),
164 d_cons :: [(n, TT n)] }
165 deriving (Show, Functor, Eq)
167instance Eq n => Eq (TT n) where
168 (==) (P xt x _) (P yt y _) = xt == yt && x == y
169 (==) (V x) (V y) = x == y
170 (==) (Bind _ xb xs) (Bind _ yb ys) = xb == yb && xs == ys
171 (==) (App fx ax) (App fy ay) = fx == fy && ax == ay
172 (==) (Set x) (Set y) = x == y
173 (==) (Constant x) (Constant y) = x == y
174 (==) _ _ = False
176-- A few handy operations on well typed terms:
178instantiate :: TT n -> TT n -> TT n
179instantiate e = subst 0 where
180 subst i (V x) | i == x = e
181 subst i (Bind x b sc) = Bind x (fmap (subst i) b) (subst (i+1) sc)
182 subst i (App f a) = App (subst i f) (subst i a)
183 subst i t = t
185pToV :: Eq n => n -> TT n -> TT n
186pToV n = pToV' n 0
187pToV' n i (P _ x _) | n == x = V i
188pToV' n i (Bind x b sc)
189 | n == x = Bind x (fmap (pToV' n i) b) sc
190 | otherwise = Bind x (fmap (pToV' n i) b) (pToV' n (i+1) sc)
191pToV' n i (App f a) = App (pToV' n i f) (pToV' n i a)
192pToV' n i t = t
194-- Convert several names. First in the list comes out as V 0
195pToVs :: Eq n => [n] -> TT n -> TT n
196pToVs ns tm = pToVs' ns tm 0 where
197 pToVs' [] tm i = tm
198 pToVs' (n:ns) tm i = pToV' n i (pToVs' ns tm (i+1))
200vToP :: TT n -> TT n
201vToP = vToP' [] where
202 vToP' env (V i) = let (n, b) = (env !! i) in
203 P Bound n (binderTy b)
204 vToP' env (Bind n b sc) = let b' = fmap (vToP' env) b in
205 Bind n b' (vToP' ((n, b'):env) sc)
206 vToP' env (App f a) = App (vToP' env f) (vToP' env a)
207 vToP' env t = t
209finalise :: Eq n => TT n -> TT n
210finalise (Bind x b sc) = Bind x (fmap finalise b) (pToV x (finalise sc))
211finalise (App f a) = App (finalise f) (finalise a)
212finalise t = t
214subst :: Eq n => n -> TT n -> TT n -> TT n
215subst n v tm = instantiate v (pToV n tm)
217substNames :: Eq n => [(n, TT n)] -> TT n -> TT n
218substNames [] t = t
219substNames ((n, tm) : xs) t = subst n tm (substNames xs t)
221-- Returns true if V 0 and bound name n do not occur in the term
223noOccurrence :: Eq n => n -> TT n -> Bool
224noOccurrence n t = no' 0 t
225 where
226 no' i (V x) = not (i == x)
227 no' i (P Bound x _) = not (n == x)
228 no' i (Bind n b sc) = noB' i b && no' (i+1) sc
229 where noB' i (Let t v) = no' i t && no' i v
230 noB' i (Guess t v) = no' i t && no' i v
231 noB' i b = no' i (binderTy b)
232 no' i (App f a) = no' i f && no' i a
233 no' i _ = True
235-- Return the arity of a (normalised) type
237arity :: TT n -> Int
238arity (Bind n (Pi t) sc) = 1 + arity sc
239arity _ = 0
241-- deconstruct an application; returns the function and a list of arguments
243unApply :: TT n -> (TT n, [TT n])
244unApply t = ua [] t where
245 ua args (App f a) = ua (a:args) f
246 ua args t = (t, args)
248mkApp :: TT n -> [TT n] -> TT n
249mkApp f [] = f
250mkApp f (a:as) = mkApp (App f a) as
252forget :: TT Name -> Raw
253forget tm = fe [] tm
254 where
255 fe env (P _ n _) = Var n
256 fe env (V i) = Var (env !! i)
257 fe env (Bind n b sc) = RBind n (fmap (fe env) b)
258 (fe (n:env) sc)
259 fe env (App f a) = RApp (fe env f) (fe env a)
260 fe env (Constant c)
261 = RConstant c
262 fe env (Set i) = RSet i
264type Term = TT Name
265type Type = Term
267type Env = EnvTT Name
269-- an environment with de Bruijn indices 'normalised' so that they all refer to
270-- this environment
272newtype WkEnvTT n = Wk (EnvTT n)
273type WkEnv = WkEnvTT Name
275instance (Eq n, Show n) => Show (TT n) where
276 show t = showEnv [] t
278instance Show Const where
279 show (I i) = show i
280 show (Fl f) = show f
281 show (Ch c) = show c
282 show (Str s) = show s
283 show IType = "Int"
284 show FlType = "Float"
285 show ChType = "Char"
286 show StrType = "String"
287 show PtrType = "Ptr"
289showEnv env t = showEnv' env t False
290showEnvDbg env t = showEnv' env t True
292showEnv' env t dbg = se 10 env t where
293 se p env (P nt n t) = show n
294 ++ if dbg then "{" ++ show nt ++ " : " ++ se 10 env t ++ "}" else ""
295 se p env (V i) | i < length env = (show $ fst $ env!!i) ++
296 if dbg then "{" ++ show i ++ "}" else ""
297 | otherwise = "!!V " ++ show i ++ "!!"
298 se p env (Bind n b@(Pi t) sc)
299 | noOccurrence n sc && not dbg = bracket p 2 $ se 1 env t ++ " -> " ++ se 10 ((n,b):env) sc
300 se p env (Bind n b sc) = bracket p 2 $ sb env n b ++ se 10 ((n,b):env) sc
301 se p env (App f a) = bracket p 1 $ se 1 env f ++ " " ++ se 0 env a
302 se p env (Constant c) = show c
303 se p env (Set i) = "Set" ++ show i
305 sb env n (Lam t) = showb env "\\ " " => " n t
306 sb env n (Hole t) = showb env "? " ". " n t
307 sb env n (GHole t) = showb env "?defer " ". " n t
308 sb env n (Pi t) = showb env "(" ") -> " n t
309 sb env n (PVar t) = showb env "pat " ". " n t
310 sb env n (PVTy t) = showb env "pty " ". " n t
311 sb env n (Let t v) = showbv env "let " " in " n t v
312 sb env n (Guess t v) = showbv env "?? " " in " n t v
314 showb env op sc n t = op ++ show n ++ " : " ++ se 10 env t ++ sc
315 showbv env op sc n t v = op ++ show n ++ " : " ++ se 10 env t ++ " = " ++
316 se 10 env v ++ sc
318 bracket outer inner str | inner > outer = "(" ++ str ++ ")"
319 | otherwise = str
321-- Check whether a term has any holes in it - impure if so
323pureTerm :: TT n -> Bool
324pureTerm (App f a) = pureTerm f && pureTerm a
325pureTerm (Bind n b sc) = pureBinder b && pureTerm sc where
326 pureBinder (Hole _) = False
327 pureBinder (Guess _ _) = False
328 pureBinder (Let t v) = pureTerm t && pureTerm v
329 pureBinder t = pureTerm (binderTy t)
330pureTerm _ = True
332-- weaken a term by adding i to each de Bruijn index (i.e. lift it over i bindings)
334weakenTm :: Int -> TT n -> TT n
335weakenTm i t = wk i 0 t
336 where wk i min (V x) | x >= min = V (i + x)
337 wk i m (App f a) = App (wk i m f) (wk i m a)
338 wk i m (Bind x b sc) = Bind x (wkb i m b) (wk i (m + 1) sc)
339 wk i m t = t
340 wkb i m t = fmap (wk i m) t
342-- weaken an environment so that all the de Bruijn indices are correct according
343-- to the latest bound variable
345weakenEnv :: EnvTT n -> EnvTT n
346weakenEnv env = wk (length env - 1) env
347 where wk i [] = []
348 wk i ((n, b) : bs) = (n, weakenTmB i b) : wk (i - 1) bs
349 weakenTmB i (Let t v) = Let (weakenTm i t) (weakenTm i v)
350 weakenTmB i (Guess t v) = Guess (weakenTm i t) (weakenTm i v)
351 weakenTmB i t = t { binderTy = weakenTm i (binderTy t) }
353weakenTmEnv :: Int -> EnvTT n -> EnvTT n
354weakenTmEnv i = map (\ (n, b) -> (n, fmap (weakenTm i) b))