git.iko.soy/Idris-dev
on 34f92f3 help sign in
Idris-dev/src/Core/TT.hs
437 lines 14 kB history raw
1{-# LANGUAGE MultiParamTypeClasses, FunctionalDependencies, DeriveFunctor #-}
3module Core.TT where
5import Control.Monad.State
6import Debug.Trace
7import qualified Data.Map as Map
8import Data.Char
9import Data.List
11{- The language has:
12 * Full dependent types
13 * A hierarchy of universes, with cumulativity: Set : Set1, Set1 : Set2, ...
14 * Pattern matching letrec binding
15 * (primitive types defined externally)
17 Some technical stuff:
18 * Typechecker is kept as simple as possible
19 - no unification, just a checker for incomplete terms.
20 * We have a simple collection of tactics which we use to elaborate source
21 programs with implicit syntax into fully explicit terms.
22-}
24data Option = SetInSet
25 | CheckConv
26 deriving Eq
28data FC = FC { fc_fname :: String,
29 fc_line :: Int }
30 deriving Eq
32instance Show FC where
33 show (FC f l) = f ++ ":" ++ show l
35data Err = Msg String
36 | CantUnify Term Term Err
37 | IncompleteTerm Term
38 | At FC Err
39 deriving Eq
41instance Show Err where
42 show (Msg s) = s
44data TC a = OK a
45 | Error Err
46 deriving (Eq, Functor)
48instance Show a => Show (TC a) where
49 show (OK x) = show x
50 show (Error str) = "Error: " ++ show str
52-- at some point, this instance should also carry type checking options
53-- (e.g. Set:Set)
55instance Monad TC where
56 return = OK
57 x >>= k = case x of
58 OK v -> k v
59 Error e -> Error e
60 fail e = Error (Msg e)
62tfail :: Err -> TC a
63tfail e = Error e
65trun :: FC -> TC a -> TC a
66trun fc (OK a) = OK a
67trun fc (Error e) = Error (At fc e)
69instance MonadPlus TC where
70 mzero = fail "Unknown error"
71 (OK x) `mplus` _ = OK x
72 _ `mplus` (OK y) = OK y
73 err `mplus` _ = err
75discard :: Monad m => m a -> m ()
76discard f = f >> return ()
78showSep :: String -> [String] -> String
79showSep sep [] = ""
80showSep sep [x] = x
81showSep sep (x:xs) = x ++ sep ++ showSep sep xs
83traceWhen True msg a = trace msg a
84traceWhen False _ a = a
86-- RAW TERMS ----------------------------------------------------------------
88-- Names are hierarchies of strings, describing scope (so no danger of
89-- duplicate names, but need to be careful on lookup).
90-- Also MN for machine chosen names
92data Name = UN [String]
93 | MN Int String
94 deriving (Eq, Ord)
96instance Show Name where
97 show (UN [n]) = n
98 show (UN (n:ns)) = show (UN [n]) ++ "." ++ show (UN ns)
99 show (MN i s) = "{" ++ s ++ show i ++ "}"
102-- Contexts allow us to map names to things
103-- TODO: Namespaces and ambiguous names
105type Ctxt a = Map.Map Name a
106emptyContext = Map.empty
108addDef :: Name -> a -> Ctxt a -> Ctxt a
109addDef = Map.insert
111lookupCtxt :: Name -> Ctxt a -> Maybe a
112lookupCtxt = Map.lookup
114toAlist :: Ctxt a -> [(Name, a)]
115toAlist = Map.toList
117addAlist :: [(Name, a)] -> Ctxt a -> Ctxt a
118addAlist [] ctxt = ctxt
119addAlist ((n, tm) : ds) ctxt = addDef n tm (addAlist ds ctxt)
121data Const = I Int | BI Integer | Fl Double | Ch Char | Str String
122 | IType | BIType | FlType | ChType | StrType
123 | PtrType
124 deriving Eq
126data Raw = Var Name
127 | RBind Name (Binder Raw) Raw
128 | RApp Raw Raw
129 | RSet Int
130 | RConstant Const
131 deriving (Show, Eq)
133data Binder b = Lam { binderTy :: b }
134 | Pi { binderTy :: b }
135 | Let { binderTy :: b,
136 binderVal :: b }
137 | NLet { binderTy :: b,
138 binderVal :: b }
139 | Hole { binderTy :: b}
140 | GHole { binderTy :: b}
141 | Guess { binderTy :: b,
142 binderVal :: b }
143 | PVar { binderTy :: b }
144 | PVTy { binderTy :: b }
145 deriving (Show, Eq, Functor)
147fmapMB :: Monad m => (a -> m b) -> Binder a -> m (Binder b)
148fmapMB f (Let t v) = liftM2 Let (f t) (f v)
149fmapMB f (NLet t v) = liftM2 NLet (f t) (f v)
150fmapMB f (Guess t v) = liftM2 Guess (f t) (f v)
151fmapMB f (Lam t) = liftM Lam (f t)
152fmapMB f (Pi t) = liftM Pi (f t)
153fmapMB f (Hole t) = liftM Hole (f t)
154fmapMB f (GHole t) = liftM GHole (f t)
155fmapMB f (PVar t) = liftM PVar (f t)
156fmapMB f (PVTy t) = liftM PVTy (f t)
158raw_apply :: Raw -> [Raw] -> Raw
159raw_apply f [] = f
160raw_apply f (a : as) = raw_apply (RApp f a) as
162data RawFun = RawFun { rtype :: Raw,
163 rval :: Raw
164 }
165 deriving Show
167data RawDatatype = RDatatype Name Raw [(Name, Raw)]
168 deriving Show
170data RDef = RFunction RawFun
171 | RConst Raw
172 | RData RawDatatype
173 deriving Show
175type RProgram = [(Name, RDef)]
177-- WELL TYPED TERMS ---------------------------------------------------------
179data NameType = Bound | Ref | DCon Int Int | TCon Int Int
180 deriving (Show, Eq)
182data TT n = P NameType n (TT n) -- embed type
183 | V Int
184 | Bind n (Binder (TT n)) (TT n)
185 | App (TT n) (TT n) -- function, function type, arg
186 | Constant Const
187 | Set Int
188 deriving Functor
190type EnvTT n = [(n, Binder (TT n))]
192data Datatype n = Data { d_typename :: n,
193 d_typetag :: Int,
194 d_type :: (TT n),
195 d_cons :: [(n, TT n)] }
196 deriving (Show, Functor, Eq)
198instance Eq n => Eq (TT n) where
199 (==) (P xt x _) (P yt y _) = xt == yt && x == y
200 (==) (V x) (V y) = x == y
201 (==) (Bind _ xb xs) (Bind _ yb ys) = xb == yb && xs == ys
202 (==) (App fx ax) (App fy ay) = fx == fy && ax == ay
203 (==) (Set x) (Set y) = x == y
204 (==) (Constant x) (Constant y) = x == y
205 (==) _ _ = False
207-- A few handy operations on well typed terms:
209instantiate :: TT n -> TT n -> TT n
210instantiate e = subst 0 where
211 subst i (V x) | i == x = e
212 subst i (Bind x b sc) = Bind x (fmap (subst i) b) (subst (i+1) sc)
213 subst i (App f a) = App (subst i f) (subst i a)
214 subst i t = t
216pToV :: Eq n => n -> TT n -> TT n
217pToV n = pToV' n 0
218pToV' n i (P _ x _) | n == x = V i
219pToV' n i (Bind x b sc)
220 | n == x = Bind x (fmap (pToV' n i) b) sc
221 | otherwise = Bind x (fmap (pToV' n i) b) (pToV' n (i+1) sc)
222pToV' n i (App f a) = App (pToV' n i f) (pToV' n i a)
223pToV' n i t = t
225-- Convert several names. First in the list comes out as V 0
226pToVs :: Eq n => [n] -> TT n -> TT n
227pToVs ns tm = pToVs' ns tm 0 where
228 pToVs' [] tm i = tm
229 pToVs' (n:ns) tm i = pToV' n i (pToVs' ns tm (i+1))
231vToP :: TT n -> TT n
232vToP = vToP' [] where
233 vToP' env (V i) = let (n, b) = (env !! i) in
234 P Bound n (binderTy b)
235 vToP' env (Bind n b sc) = let b' = fmap (vToP' env) b in
236 Bind n b' (vToP' ((n, b'):env) sc)
237 vToP' env (App f a) = App (vToP' env f) (vToP' env a)
238 vToP' env t = t
240finalise :: Eq n => TT n -> TT n
241finalise (Bind x b sc) = Bind x (fmap finalise b) (pToV x (finalise sc))
242finalise (App f a) = App (finalise f) (finalise a)
243finalise t = t
245subst :: Eq n => n -> TT n -> TT n -> TT n
246subst n v tm = instantiate v (pToV n tm)
248substNames :: Eq n => [(n, TT n)] -> TT n -> TT n
249substNames [] t = t
250substNames ((n, tm) : xs) t = subst n tm (substNames xs t)
252-- Returns true if V 0 and bound name n do not occur in the term
254noOccurrence :: Eq n => n -> TT n -> Bool
255noOccurrence n t = no' 0 t
256 where
257 no' i (V x) = not (i == x)
258 no' i (P Bound x _) = not (n == x)
259 no' i (Bind n b sc) = noB' i b && no' (i+1) sc
260 where noB' i (Let t v) = no' i t && no' i v
261 noB' i (Guess t v) = no' i t && no' i v
262 noB' i b = no' i (binderTy b)
263 no' i (App f a) = no' i f && no' i a
264 no' i _ = True
266-- Return the arity of a (normalised) type
268arity :: TT n -> Int
269arity (Bind n (Pi t) sc) = 1 + arity sc
270arity _ = 0
272-- deconstruct an application; returns the function and a list of arguments
274unApply :: TT n -> (TT n, [TT n])
275unApply t = ua [] t where
276 ua args (App f a) = ua (a:args) f
277 ua args t = (t, args)
279mkApp :: TT n -> [TT n] -> TT n
280mkApp f [] = f
281mkApp f (a:as) = mkApp (App f a) as
283forget :: TT Name -> Raw
284forget tm = fe [] tm
285 where
286 fe env (P _ n _) = Var n
287 fe env (V i) = Var (env !! i)
288 fe env (Bind n b sc) = RBind n (fmap (fe env) b)
289 (fe (n:env) sc)
290 fe env (App f a) = RApp (fe env f) (fe env a)
291 fe env (Constant c)
292 = RConstant c
293 fe env (Set i) = RSet i
295bindAll :: [(n, Binder (TT n))] -> TT n -> TT n
296bindAll [] t =t
297bindAll ((n, b) : bs) t = Bind n b (bindAll bs t)
299bindTyArgs :: (TT n -> Binder (TT n)) -> [(n, TT n)] -> TT n -> TT n
300bindTyArgs b xs = bindAll (map (\ (n, ty) -> (n, b ty)) xs)
302getArgTys :: TT n -> [(n, TT n)]
303getArgTys (Bind n (Pi t) sc) = (n, t) : getArgTys sc
304getArgTys _ = []
306uniqueName :: Name -> [Name] -> Name
307uniqueName n hs | n `elem` hs = uniqueName (nextName n) hs
308 | otherwise = n
310nextName (MN i n) = MN (i+1) n
311nextName (UN (x:xs)) = let (num', nm') = span isDigit (reverse x)
312 nm = reverse nm'
313 num = readN (reverse num') in
314 UN ((nm ++ show (num+1)) : xs)
315 where
316 readN "" = 0
317 readN x = read x
319type Term = TT Name
320type Type = Term
322type Env = EnvTT Name
324-- an environment with de Bruijn indices 'normalised' so that they all refer to
325-- this environment
327newtype WkEnvTT n = Wk (EnvTT n)
328type WkEnv = WkEnvTT Name
330instance (Eq n, Show n) => Show (TT n) where
331 show t = showEnv [] t
333instance Show Const where
334 show (I i) = show i
335 show (BI i) = show i ++ "L"
336 show (Fl f) = show f
337 show (Ch c) = show c
338 show (Str s) = show s
339 show IType = "Int"
340 show BIType = "Integer"
341 show FlType = "Float"
342 show ChType = "Char"
343 show StrType = "String"
344 show PtrType = "Ptr"
346showEnv env t = showEnv' env t False
347showEnvDbg env t = showEnv' env t True
349showEnv' env t dbg = se 10 env t where
350 se p env (P nt n t) = show n
351 -- ++ if dbg then "{" ++ show nt ++ " : " ++ se 10 env t ++ "}" else ""
352 se p env (V i) | i < length env = (show $ fst $ env!!i) ++
353 if dbg then "{" ++ show i ++ "}" else ""
354 | otherwise = "!!V " ++ show i ++ "!!"
355 se p env (Bind n b@(Pi t) sc)
356 | noOccurrence n sc && not dbg = bracket p 2 $ se 1 env t ++ " -> " ++ se 10 ((n,b):env) sc
357 se p env (Bind n b sc) = bracket p 2 $ sb env n b ++ se 10 ((n,b):env) sc
358 se p env (App f a) = bracket p 1 $ se 1 env f ++ " " ++ se 0 env a
359 se p env (Constant c) = show c
360 se p env (Set i) = "Set" ++ show i
362 sb env n (Lam t) = showb env "\\ " " => " n t
363 sb env n (Hole t) = showb env "? " ". " n t
364 sb env n (GHole t) = showb env "?defer " ". " n t
365 sb env n (Pi t) = showb env "(" ") -> " n t
366 sb env n (PVar t) = showb env "pat " ". " n t
367 sb env n (PVTy t) = showb env "pty " ". " n t
368 sb env n (Let t v) = showbv env "let " " in " n t v
369 sb env n (Guess t v) = showbv env "?? " " in " n t v
371 showb env op sc n t = op ++ show n ++ " : " ++ se 10 env t ++ sc
372 showbv env op sc n t v = op ++ show n ++ " : " ++ se 10 env t ++ " = " ++
373 se 10 env v ++ sc
375 bracket outer inner str | inner > outer = "(" ++ str ++ ")"
376 | otherwise = str
378-- Check whether a term has any holes in it - impure if so
380pureTerm :: TT n -> Bool
381pureTerm (App f a) = pureTerm f && pureTerm a
382pureTerm (Bind n b sc) = pureBinder b && pureTerm sc where
383 pureBinder (Hole _) = False
384 pureBinder (Guess _ _) = False
385 pureBinder (Let t v) = pureTerm t && pureTerm v
386 pureBinder t = pureTerm (binderTy t)
387pureTerm _ = True
389-- weaken a term by adding i to each de Bruijn index (i.e. lift it over i bindings)
391weakenTm :: Int -> TT n -> TT n
392weakenTm i t = wk i 0 t
393 where wk i min (V x) | x >= min = V (i + x)
394 wk i m (App f a) = App (wk i m f) (wk i m a)
395 wk i m (Bind x b sc) = Bind x (wkb i m b) (wk i (m + 1) sc)
396 wk i m t = t
397 wkb i m t = fmap (wk i m) t
399-- weaken an environment so that all the de Bruijn indices are correct according
400-- to the latest bound variable
402weakenEnv :: EnvTT n -> EnvTT n
403weakenEnv env = wk (length env - 1) env
404 where wk i [] = []
405 wk i ((n, b) : bs) = (n, weakenTmB i b) : wk (i - 1) bs
406 weakenTmB i (Let t v) = Let (weakenTm i t) (weakenTm i v)
407 weakenTmB i (Guess t v) = Guess (weakenTm i t) (weakenTm i v)
408 weakenTmB i t = t { binderTy = weakenTm i (binderTy t) }
410weakenTmEnv :: Int -> EnvTT n -> EnvTT n
411weakenTmEnv i = map (\ (n, b) -> (n, fmap (weakenTm i) b))
413orderPats :: Term -> Term
414orderPats tm = op [] tm
415 where
416 op ps (Bind n (PVar t) sc) = op ((n, t) : ps) sc
417 op ps sc = bindAll (map (\ (n, t) -> (n, PVar t)) (sortP ps)) sc
419 sortP ps = pick [] (reverse ps)
421 namesIn (P _ n _) = [n]
422 namesIn (Bind n b t) = nub $ nb b ++ (namesIn t \\ [n])
423 where nb (Let t v) = nub (namesIn t) ++ nub (namesIn v)
424 nb (Guess t v) = nub (namesIn t) ++ nub (namesIn v)
425 nb t = namesIn (binderTy t)
426 namesIn (App f a) = nub (namesIn f ++ namesIn a)
427 namesIn _ = []
429 pick acc [] = reverse acc
430 pick acc ((n, t) : ps) = pick (insert n t acc) ps
432 insert n t [] = [(n, t)]
433 insert n t ((n',t') : ps)
434 | n `elem` (namesIn t' ++ concatMap namesIn (map snd ps))
435 = (n', t') : insert n t ps
436 | otherwise = (n,t):(n',t'):ps