git.iko.soy/Idris-dev
on 3900c38 help sign in
Idris-dev/src/Core/TT.hs
588 lines 19 kB history raw
1{-# LANGUAGE MultiParamTypeClasses, FunctionalDependencies, DeriveFunctor #-}
3module Core.TT where
5import Control.Monad.State
6import Debug.Trace
7import qualified Data.Map as Map
8import Data.Char
9import Data.List
10import qualified Data.Binary as B
11import Data.Binary hiding (get, put)
13{- The language has:
14 * Full dependent types
15 * A hierarchy of universes, with cumulativity: Set : Set1, Set1 : Set2, ...
16 * Pattern matching letrec binding
17 * (primitive types defined externally)
19 Some technical stuff:
20 * Typechecker is kept as simple as possible
21 - no unification, just a checker for incomplete terms.
22 * We have a simple collection of tactics which we use to elaborate source
23 programs with implicit syntax into fully explicit terms.
24-}
26data Option = SetInSet
27 | CheckConv
28 deriving Eq
30data FC = FC { fc_fname :: String,
31 fc_line :: Int }
32 deriving Eq
33{-!
34deriving instance Binary FC
35!-}
37instance Show FC where
38 show (FC f l) = f ++ ":" ++ show l
40data Err = Msg String
41 | CantUnify Term Term Err Int -- Int is 'score' - how much we did unify
42 | NoSuchVariable Name
43 | NotInjective Term Term Term
44 | CantResolve Term
45 | IncompleteTerm Term
46 | UniverseError
47 | ProgramLineComment
48 | At FC Err
49 deriving Eq
51score :: Err -> Int
52score (CantUnify _ _ m s) = s + score m
53score (CantResolve _) = 20
54score (NoSuchVariable _) = 1000
55score _ = 0
57instance Show Err where
58 show (Msg s) = s
59 show (CantUnify l r e i) = "CantUnify " ++ show l ++ " " ++ show r ++ " "
60 ++ show e ++ " " ++ show i
61 show _ = "Error"
63data TC a = OK a
64 | Error Err
65 deriving (Eq, Functor)
67instance Show a => Show (TC a) where
68 show (OK x) = show x
69 show (Error str) = "Error: " ++ show str
71-- at some point, this instance should also carry type checking options
72-- (e.g. Set:Set)
74instance Monad TC where
75 return = OK
76 x >>= k = case x of
77 OK v -> k v
78 Error e -> Error e
79 fail e = Error (Msg e)
81tfail :: Err -> TC a
82tfail e = Error e
84trun :: FC -> TC a -> TC a
85trun fc (OK a) = OK a
86trun fc (Error e) = Error (At fc e)
88instance MonadPlus TC where
89 mzero = fail "Unknown error"
90 (OK x) `mplus` _ = OK x
91 _ `mplus` (OK y) = OK y
92 err `mplus` _ = err
94discard :: Monad m => m a -> m ()
95discard f = f >> return ()
97showSep :: String -> [String] -> String
98showSep sep [] = ""
99showSep sep [x] = x
100showSep sep (x:xs) = x ++ sep ++ showSep sep xs
102pmap f (x, y) = (f x, f y)
104traceWhen True msg a = trace msg a
105traceWhen False _ a = a
107-- RAW TERMS ----------------------------------------------------------------
109-- Names are hierarchies of strings, describing scope (so no danger of
110-- duplicate names, but need to be careful on lookup).
111-- Also MN for machine chosen names
113data Name = UN String
114 | NS Name [String] -- root, namespaces
115 | MN Int String
116 deriving (Eq, Ord)
117{-!
118deriving instance Binary Name
119!-}
121instance Show Name where
122 show (UN n) = n
123 show (NS n s) = showSep "." (reverse s) ++ "." ++ show n
124 show (MN i s) = "{" ++ s ++ show i ++ "}"
127-- Contexts allow us to map names to things. A root name maps to a collection
128-- of things in different namespaces with that name.
130type Ctxt a = Map.Map Name (Map.Map Name a)
131emptyContext = Map.empty
133nsroot (NS n _) = n
134nsroot n = n
136addDef :: Name -> a -> Ctxt a -> Ctxt a
137addDef n v ctxt = case Map.lookup (nsroot n) ctxt of
138 Nothing -> Map.insert (nsroot n)
139 (Map.insert n v Map.empty) ctxt
140 Just xs -> Map.insert (nsroot n)
141 (Map.insert n v xs) ctxt
143{- lookup a name in the context, given an optional namespace.
144 The name (n) may itself have a (partial) namespace given.
146 Rules for resolution:
147 - if an explicit namespace is given, return the names which match it. If none
148 match, return all names.
149 - if the name has has explicit namespace given, return the names which match it
150 and ignore the given namespace.
151 - otherwise, return all names.
153-}
155lookupCtxtName :: Maybe [String] -> Name -> Ctxt a -> [(Name, a)]
156lookupCtxtName nspace n ctxt = case Map.lookup (nsroot n) ctxt of
157 Just xs -> filterNS (Map.toList xs)
158 Nothing -> []
159 where
160 filterNS [] = []
161 filterNS ((found, v) : xs)
162 | nsmatch n found = (found, v) : filterNS xs
163 | otherwise = filterNS xs
165 nsmatch (NS n ns) (NS p ps) = ns `isPrefixOf` ps
166 nsmatch (NS _ _) _ = False
167 nsmatch looking found = True
169lookupCtxt :: Maybe [String] -> Name -> Ctxt a -> [a]
170lookupCtxt ns n ctxt = map snd (lookupCtxtName ns n ctxt)
172updateDef :: Name -> (a -> a) -> Ctxt a -> Ctxt a
173updateDef n f ctxt
174 = let ds = lookupCtxtName Nothing n ctxt in
175 foldr (\ (n, t) c -> addDef n (f t) c) ctxt ds
177toAlist :: Ctxt a -> [(Name, a)]
178toAlist ctxt = let allns = map snd (Map.toList ctxt) in
179 concat (map (Map.toList) allns)
181addAlist :: Show a => [(Name, a)] -> Ctxt a -> Ctxt a
182addAlist [] ctxt = ctxt
183addAlist ((n, tm) : ds) ctxt = addDef n tm (addAlist ds ctxt)
185data Const = I Int | BI Integer | Fl Double | Ch Char | Str String
186 | IType | BIType | FlType | ChType | StrType
187 | PtrType | Forgot
188 deriving Eq
189{-!
190deriving instance Binary Const
191!-}
193data Raw = Var Name
194 | RBind Name (Binder Raw) Raw
195 | RApp Raw Raw
196 | RSet
197 | RForce Raw
198 | RConstant Const
199 deriving (Show, Eq)
200{-!
201deriving instance Binary Raw
202!-}
204data Binder b = Lam { binderTy :: b }
205 | Pi { binderTy :: b }
206 | Let { binderTy :: b,
207 binderVal :: b }
208 | NLet { binderTy :: b,
209 binderVal :: b }
210 | Hole { binderTy :: b}
211 | GHole { binderTy :: b}
212 | Guess { binderTy :: b,
213 binderVal :: b }
214 | PVar { binderTy :: b }
215 | PVTy { binderTy :: b }
216 deriving (Show, Eq, Functor)
217{-!
218deriving instance Binary Binder
219!-}
221fmapMB :: Monad m => (a -> m b) -> Binder a -> m (Binder b)
222fmapMB f (Let t v) = liftM2 Let (f t) (f v)
223fmapMB f (NLet t v) = liftM2 NLet (f t) (f v)
224fmapMB f (Guess t v) = liftM2 Guess (f t) (f v)
225fmapMB f (Lam t) = liftM Lam (f t)
226fmapMB f (Pi t) = liftM Pi (f t)
227fmapMB f (Hole t) = liftM Hole (f t)
228fmapMB f (GHole t) = liftM GHole (f t)
229fmapMB f (PVar t) = liftM PVar (f t)
230fmapMB f (PVTy t) = liftM PVTy (f t)
232raw_apply :: Raw -> [Raw] -> Raw
233raw_apply f [] = f
234raw_apply f (a : as) = raw_apply (RApp f a) as
236raw_unapply :: Raw -> (Raw, [Raw])
237raw_unapply t = ua [] t where
238 ua args (RApp f a) = ua (a:args) f
239 ua args t = (t, args)
241data RawFun = RawFun { rtype :: Raw,
242 rval :: Raw
243 }
244 deriving Show
246data RawDatatype = RDatatype Name Raw [(Name, Raw)]
247 deriving Show
249data RDef = RFunction RawFun
250 | RConst Raw
251 | RData RawDatatype
252 deriving Show
254type RProgram = [(Name, RDef)]
256-- WELL TYPED TERMS ---------------------------------------------------------
258data UExp = UVar Int -- universe variable
259 | UVal Int -- explicit universe level
260 deriving (Eq, Ord)
262-- We assume that universe levels have been checked, so anything external
263-- can just have the same universe variable and we won't get any new
264-- cycles.
266instance Binary UExp where
267 put x = return ()
268 get = return (UVar (-1))
270instance Show UExp where
271 show (UVar x) | x < 26 = [toEnum (x + fromEnum 'a')]
272 | otherwise = toEnum ((x `mod` 26) + fromEnum 'a') : show (x `div` 26)
273 show (UVal x) = show x
274-- show (UMax l r) = "max(" ++ show l ++ ", " ++ show r ++")"
276data UConstraint = ULT UExp UExp
277 | ULE UExp UExp
278 deriving Eq
280instance Show UConstraint where
281 show (ULT x y) = show x ++ " < " ++ show y
282 show (ULE x y) = show x ++ " <= " ++ show y
284type UCs = (Int, [UConstraint])
286data NameType = Bound | Ref | DCon Int Int | TCon Int Int
287 deriving (Show)
288{-!
289deriving instance Binary NameType
290!-}
292instance Eq NameType where
293 Bound == Bound = True
294 Ref == Ref = True
295 DCon _ a == DCon _ b = (a == b) -- ignore tag
296 TCon _ a == TCon _ b = (a == b) -- ignore tag
297 _ == _ = False
299data TT n = P NameType n (TT n) -- embed type
300 | V Int
301 | Bind n (Binder (TT n)) (TT n)
302 | App (TT n) (TT n) -- function, function type, arg
303 | Constant Const
304 | Erased
305 | Set UExp
306 deriving Functor
307{-!
308deriving instance Binary TT
309!-}
311type EnvTT n = [(n, Binder (TT n))]
313data Datatype n = Data { d_typename :: n,
314 d_typetag :: Int,
315 d_type :: (TT n),
316 d_cons :: [(n, TT n)] }
317 deriving (Show, Functor, Eq)
319instance Eq n => Eq (TT n) where
320 (==) (P xt x _) (P yt y _) = xt == yt && x == y
321 (==) (V x) (V y) = x == y
322 (==) (Bind _ xb xs) (Bind _ yb ys) = xb == yb && xs == ys
323 (==) (App fx ax) (App fy ay) = fx == fy && ax == ay
324 (==) (Set _) (Set _) = True -- deal with constraints later
325 (==) (Constant x) (Constant y) = x == y
326 (==) Erased _ = True
327 (==) _ Erased = True
328 (==) _ _ = False
330-- A few handy operations on well typed terms:
332isInjective :: TT n -> Bool
333isInjective (P (DCon _ _) _ _) = True
334isInjective (P (TCon _ _) _ _) = True
335isInjective (Constant _) = True
336isInjective (Set x) = True
337isInjective (Bind _ (Pi _) sc) = True
338isInjective (App f a) = isInjective f
339isInjective _ = False
341instantiate :: TT n -> TT n -> TT n
342instantiate e = subst 0 where
343 subst i (V x) | i == x = e
344 subst i (Bind x b sc) = Bind x (fmap (subst i) b) (subst (i+1) sc)
345 subst i (App f a) = App (subst i f) (subst i a)
346 subst i t = t
348pToV :: Eq n => n -> TT n -> TT n
349pToV n = pToV' n 0
350pToV' n i (P _ x _) | n == x = V i
351pToV' n i (Bind x b sc)
352 | n == x = Bind x (fmap (pToV' n i) b) sc
353 | otherwise = Bind x (fmap (pToV' n i) b) (pToV' n (i+1) sc)
354pToV' n i (App f a) = App (pToV' n i f) (pToV' n i a)
355pToV' n i t = t
357-- Convert several names. First in the list comes out as V 0
358pToVs :: Eq n => [n] -> TT n -> TT n
359pToVs ns tm = pToVs' ns tm 0 where
360 pToVs' [] tm i = tm
361 pToVs' (n:ns) tm i = pToV' n i (pToVs' ns tm (i+1))
363vToP :: TT n -> TT n
364vToP = vToP' [] where
365 vToP' env (V i) = let (n, b) = (env !! i) in
366 P Bound n (binderTy b)
367 vToP' env (Bind n b sc) = let b' = fmap (vToP' env) b in
368 Bind n b' (vToP' ((n, b'):env) sc)
369 vToP' env (App f a) = App (vToP' env f) (vToP' env a)
370 vToP' env t = t
372finalise :: Eq n => TT n -> TT n
373finalise (Bind x b sc) = Bind x (fmap finalise b) (pToV x (finalise sc))
374finalise (App f a) = App (finalise f) (finalise a)
375finalise t = t
377subst :: Eq n => n -> TT n -> TT n -> TT n
378subst n v tm = instantiate v (pToV n tm)
380substNames :: Eq n => [(n, TT n)] -> TT n -> TT n
381substNames [] t = t
382substNames ((n, tm) : xs) t = subst n tm (substNames xs t)
384-- Returns true if V 0 and bound name n do not occur in the term
386noOccurrence :: Eq n => n -> TT n -> Bool
387noOccurrence n t = no' 0 t
388 where
389 no' i (V x) = not (i == x)
390 no' i (P Bound x _) = not (n == x)
391 no' i (Bind n b sc) = noB' i b && no' (i+1) sc
392 where noB' i (Let t v) = no' i t && no' i v
393 noB' i (Guess t v) = no' i t && no' i v
394 noB' i b = no' i (binderTy b)
395 no' i (App f a) = no' i f && no' i a
396 no' i _ = True
398-- Returns all names used free in the term
400freeNames :: Eq n => TT n -> [n]
401freeNames (P _ n _) = [n]
402freeNames (Bind n (Let t v) sc) = nub $ freeNames v ++ (freeNames sc \\ [n])
403 ++ freeNames t
404freeNames (Bind n b sc) = nub $ freeNames (binderTy b) ++ (freeNames sc \\ [n])
405freeNames (App f a) = nub $ freeNames f ++ freeNames a
406freeNames _ = []
408-- Return the arity of a (normalised) type
410arity :: TT n -> Int
411arity (Bind n (Pi t) sc) = 1 + arity sc
412arity _ = 0
414-- deconstruct an application; returns the function and a list of arguments
416unApply :: TT n -> (TT n, [TT n])
417unApply t = ua [] t where
418 ua args (App f a) = ua (a:args) f
419 ua args t = (t, args)
421mkApp :: TT n -> [TT n] -> TT n
422mkApp f [] = f
423mkApp f (a:as) = mkApp (App f a) as
425forget :: TT Name -> Raw
426forget tm = fe [] tm
427 where
428 fe env (P _ n _) = Var n
429 fe env (V i) = Var (env !! i)
430 fe env (Bind n b sc) = RBind n (fmap (fe env) b)
431 (fe (n:env) sc)
432 fe env (App f a) = RApp (fe env f) (fe env a)
433 fe env (Constant c)
434 = RConstant c
435 fe env (Set i) = RSet
436 fe env Erased = RConstant Forgot
438bindAll :: [(n, Binder (TT n))] -> TT n -> TT n
439bindAll [] t =t
440bindAll ((n, b) : bs) t = Bind n b (bindAll bs t)
442bindTyArgs :: (TT n -> Binder (TT n)) -> [(n, TT n)] -> TT n -> TT n
443bindTyArgs b xs = bindAll (map (\ (n, ty) -> (n, b ty)) xs)
445getArgTys :: TT n -> [(n, TT n)]
446getArgTys (Bind n (Pi t) sc) = (n, t) : getArgTys sc
447getArgTys _ = []
449getRetTy :: TT n -> TT n
450getRetTy (Bind n (PVar _) sc) = getRetTy sc
451getRetTy (Bind n (PVTy _) sc) = getRetTy sc
452getRetTy (Bind n (Pi _) sc) = getRetTy sc
453getRetTy sc = sc
455uniqueName :: Name -> [Name] -> Name
456uniqueName n hs | n `elem` hs = uniqueName (nextName n) hs
457 | otherwise = n
459nextName (NS x s) = NS (nextName x) s
460nextName (MN i n) = MN (i+1) n
461nextName (UN x) = let (num', nm') = span isDigit (reverse x)
462 nm = reverse nm'
463 num = readN (reverse num') in
464 UN (nm ++ show (num+1))
465 where
466 readN "" = 0
467 readN x = read x
469type Term = TT Name
470type Type = Term
472type Env = EnvTT Name
474-- an environment with de Bruijn indices 'normalised' so that they all refer to
475-- this environment
477newtype WkEnvTT n = Wk (EnvTT n)
478type WkEnv = WkEnvTT Name
480instance (Eq n, Show n) => Show (TT n) where
481 show t = showEnv [] t
483instance Show Const where
484 show (I i) = show i
485 show (BI i) = show i ++ "L"
486 show (Fl f) = show f
487 show (Ch c) = show c
488 show (Str s) = show s
489 show IType = "Int"
490 show BIType = "Integer"
491 show FlType = "Float"
492 show ChType = "Char"
493 show StrType = "String"
494 show PtrType = "Ptr"
496showEnv env t = showEnv' env t False
497showEnvDbg env t = showEnv' env t True
499showEnv' env t dbg = se 10 env t where
500 se p env (P nt n t) = show n
501 ++ if dbg then "{" ++ show nt ++ " : " ++ se 10 env t ++ "}" else ""
502 se p env (V i) | i < length env = (show $ fst $ env!!i) ++
503 if dbg then "{" ++ show i ++ "}" else ""
504 | otherwise = "!!V " ++ show i ++ "!!"
505 se p env (Bind n b@(Pi t) sc)
506 | noOccurrence n sc && not dbg = bracket p 2 $ se 1 env t ++ " -> " ++ se 10 ((n,b):env) sc
507 se p env (Bind n b sc) = bracket p 2 $ sb env n b ++ se 10 ((n,b):env) sc
508 se p env (App f a) = bracket p 1 $ se 1 env f ++ " " ++ se 0 env a
509 se p env (Constant c) = show c
510 se p env Erased = "[__]"
511 se p env (Set i) = "Set " ++ show i
513 sb env n (Lam t) = showb env "\\ " " => " n t
514 sb env n (Hole t) = showb env "? " ". " n t
515 sb env n (GHole t) = showb env "?defer " ". " n t
516 sb env n (Pi t) = showb env "(" ") -> " n t
517 sb env n (PVar t) = showb env "pat " ". " n t
518 sb env n (PVTy t) = showb env "pty " ". " n t
519 sb env n (Let t v) = showbv env "let " " in " n t v
520 sb env n (Guess t v) = showbv env "?? " " in " n t v
522 showb env op sc n t = op ++ show n ++ " : " ++ se 10 env t ++ sc
523 showbv env op sc n t v = op ++ show n ++ " : " ++ se 10 env t ++ " = " ++
524 se 10 env v ++ sc
526 bracket outer inner str | inner > outer = "(" ++ str ++ ")"
527 | otherwise = str
529-- Check whether a term has any holes in it - impure if so
531pureTerm :: TT n -> Bool
532pureTerm (App f a) = pureTerm f && pureTerm a
533pureTerm (Bind n b sc) = pureBinder b && pureTerm sc where
534 pureBinder (Hole _) = False
535 pureBinder (Guess _ _) = False
536 pureBinder (Let t v) = pureTerm t && pureTerm v
537 pureBinder t = pureTerm (binderTy t)
538pureTerm _ = True
540-- weaken a term by adding i to each de Bruijn index (i.e. lift it over i bindings)
542weakenTm :: Int -> TT n -> TT n
543weakenTm i t = wk i 0 t
544 where wk i min (V x) | x >= min = V (i + x)
545 wk i m (App f a) = App (wk i m f) (wk i m a)
546 wk i m (Bind x b sc) = Bind x (wkb i m b) (wk i (m + 1) sc)
547 wk i m t = t
548 wkb i m t = fmap (wk i m) t
550-- weaken an environment so that all the de Bruijn indices are correct according
551-- to the latest bound variable
553weakenEnv :: EnvTT n -> EnvTT n
554weakenEnv env = wk (length env - 1) env
555 where wk i [] = []
556 wk i ((n, b) : bs) = (n, weakenTmB i b) : wk (i - 1) bs
557 weakenTmB i (Let t v) = Let (weakenTm i t) (weakenTm i v)
558 weakenTmB i (Guess t v) = Guess (weakenTm i t) (weakenTm i v)
559 weakenTmB i t = t { binderTy = weakenTm i (binderTy t) }
561weakenTmEnv :: Int -> EnvTT n -> EnvTT n
562weakenTmEnv i = map (\ (n, b) -> (n, fmap (weakenTm i) b))
564orderPats :: Term -> Term
565orderPats tm = op [] tm
566 where
567 op ps (Bind n (PVar t) sc) = op ((n, t) : ps) sc
568 op ps sc = bindAll (map (\ (n, t) -> (n, PVar t)) (sortP ps)) sc
570 sortP ps = pick [] (reverse ps)
572 namesIn (P _ n _) = [n]
573 namesIn (Bind n b t) = nub $ nb b ++ (namesIn t \\ [n])
574 where nb (Let t v) = nub (namesIn t) ++ nub (namesIn v)
575 nb (Guess t v) = nub (namesIn t) ++ nub (namesIn v)
576 nb t = namesIn (binderTy t)
577 namesIn (App f a) = nub (namesIn f ++ namesIn a)
578 namesIn _ = []
580 pick acc [] = reverse acc
581 pick acc ((n, t) : ps) = pick (insert n t acc) ps
583 insert n t [] = [(n, t)]
584 insert n t ((n',t') : ps)
585 | n `elem` (namesIn t' ++ concatMap namesIn (map snd ps))
586 = (n', t') : insert n t ps
587 | otherwise = (n,t):(n',t'):ps