git.iko.soy/Idris-dev
on 77be0d0 help sign in
Idris-dev/src/Core.hs
216 lines 6.9 kB history raw
1{-# LANGUAGE MultiParamTypeClasses, FunctionalDependencies, DeriveFunctor #-}
3module Core where
5import Control.Monad.State
6import Debug.Trace
8{- The language has:
9 * Full dependent types
10 * A hierarchy of universes, with cumulativity: Set : Set1, Set1 : Set2, ...
11 * Pattern matching letrec binding
12 * (primitive types defined externally)
14 Some technical stuff:
15 * Typechecker is kept as simple as possible
16 - no unification, just a checker for incomplete terms.
17 * We have a simple collection of tactics which we use to elaborate source
18 programs with implicit syntax into fully explicit terms.
19-}
21data Option = SetInSet
22 | CheckConv
23 deriving Eq
25data TC a = OK a
26 | Error String -- TMP! Make this an informative data structure
27 deriving (Eq, Functor)
29instance Show a => Show (TC a) where
30 show (OK x) = show x
31 show (Error str) = "Error: " ++ str
33-- at some point, this instance should also carry type checking options
34-- (e.g. Set:Set)
36instance Monad TC where
37 return = OK
38 x >>= k = case x of
39 OK v -> k v
40 Error e -> Error e
41 fail = Error
43instance MonadPlus TC where
44 mzero = Error "Unknown error"
45 (OK x) `mplus` _ = OK x
46 _ `mplus` (OK y) = OK y
47 err `mplus` _ = err
49-- RAW TERMS ----------------------------------------------------------------
51-- Names are hierarchies of strings, describing scope (so no danger of
52-- duplicate names, but need to be careful on lookup).
53-- Also MN for machine chosen names
55data Name = UN [String]
56 | MN Int String
57 deriving Eq
59instance Show Name where
60 show (UN [n]) = n
61 show (UN (n:ns)) = show (UN [n]) ++ "." ++ show (UN ns)
62 show (MN i s) = "{" ++ s ++ show i ++ "}"
64data Raw = Var Name
65 | RBind Name (Binder Raw) Raw
66 | RApp Raw Raw
67 | RSet Int
68 deriving Show
70data Binder b = Lam { binderTy :: b }
71 | Pi { binderTy :: b }
72 | Let { binderTy :: b,
73 binderVal :: b }
74 | NLet { binderTy :: b,
75 binderVal :: b }
76 | Hole { binderTy :: b}
77 | Guess { binderTy :: b,
78 binderVal :: b }
79 | PVar { binderTy :: b }
80 deriving (Show, Eq, Functor)
82data RawFun = RawFun { rtype :: Raw,
83 rval :: Raw
84 }
85 deriving Show
87data RawDatatype = RDatatype Name Raw [(Name, Raw)]
88 deriving Show
90data RDef = RFunction RawFun
91 | RConst Raw
92 | RData RawDatatype
93 deriving Show
95type RProgram = [(Name, RDef)]
97-- WELL TYPED TERMS ---------------------------------------------------------
99data NameType = Bound | Ref | DCon Int Int | TCon Int
100 deriving (Show, Eq)
102-- FIXME: Consider changing this to birectional, with type annotations.
104data TT n = P NameType n (TT n) -- embed type
105 | V Int
106 | Bind n (Binder (TT n)) (TT n)
107 | App (TT n) (TT n) -- function, function type, arg
108 | Set Int
109 deriving (Functor, Eq)
111type EnvTT n = [(n, Binder (TT n))]
113data Datatype n = Data { d_typename :: n,
114 d_type :: (TT n),
115 d_cons :: [(n, TT n)] }
116 deriving (Show, Functor, Eq)
118-- Returns true if V 0 and bound name n do not occur in the term
120noOccurrence :: Eq n => n -> TT n -> Bool
121noOccurrence n t = no' 0 t
122 where
123 no' i (V x) = not (i == x)
124 no' i (P Bound x _) = not (n == x)
125 no' i (Bind n b sc) = noB' i b && no' (i+1) sc
126 where noB' i (Let t v) = no' i t && no' i v
127 noB' i (Guess t v) = no' i t && no' i v
128 noB' i b = no' i (binderTy b)
129 no' i (App f a) = no' i f && no' i a
130 no' i _ = True
132-- Return the arity of a (normalised) type
134arity :: TT n -> Int
135arity (Bind n (Pi t) sc) = 1 + arity sc
136arity _ = 0
138type Term = TT Name
139type Type = Term
141type Env = EnvTT Name
143-- an environment with de Bruijn indices 'normalised' so that they all refer to
144-- this environment
146newtype WkEnvTT n = Wk (EnvTT n)
147type WkEnv = WkEnvTT Name
149instance (Eq n, Show n) => Show (TT n) where
150 show t = showEnv [] t
152showEnv env t = showEnv' env t False
153showEnvDbg env t = showEnv' env t True
155showEnv' env t dbg = se 10 env t where
156 se p env (P nt n t) = show n
157-- ++ if dbg then "{" ++ show nt ++ " : " ++ se 10 env t ++ "}" else ""
158 se p env (V i) | i < length env = (show $ fst $ env!!i) ++
159 if dbg then "{" ++ show i ++ "}" else ""
160 | otherwise = "!!V " ++ show i ++ "!!"
161 se p env (Bind n b@(Pi t) sc)
162 | noOccurrence n sc = bracket p 2 $ se 10 env t ++ " -> " ++ se 10 ((n,b):env) sc
163 se p env (Bind n b sc) = bracket p 2 $ sb env n b ++ se 10 ((n,b):env) sc
164 se p env (App f a) = bracket p 1 $ se 1 env f ++ " " ++ se 0 env a
165 se p env (Set i) = "Set" ++ show i
167 sb env n (Lam t) = showb env "\\ " " => " n t
168 sb env n (Hole t) = showb env "? " ". " n t
169 sb env n (Pi t) = showb env "(" ") -> " n t
170 sb env n (PVar t) = showb env "! " ". " n t
171 sb env n (Let t v) = showbv env "let " " in " n t v
172 sb env n (Guess t v) = showbv env "?? " " in " n t v
174 showb env op sc n t = op ++ show n ++ " : " ++ se 10 env t ++ sc
175 showbv env op sc n t v = op ++ show n ++ " : " ++ se 10 env t ++ " = " ++
176 se 10 env v ++ sc
178 bracket outer inner str | inner > outer = "(" ++ str ++ ")"
179 | otherwise = str
181-- Check whether a term has any holes in it - impure if so
183pureTerm :: TT n -> Bool
184pureTerm (App f a) = pureTerm f && pureTerm a
185pureTerm (Bind n b sc) = pureBinder b && pureTerm sc where
186 pureBinder (Hole _) = False
187 pureBinder (Guess _ _) = False
188 pureBinder (Let t v) = pureTerm t && pureTerm v
189 pureBinder t = pureTerm (binderTy t)
190pureTerm _ = True
192-- weaken a term by adding i to each de Bruijn index (i.e. lift it over i bindings)
194weakenTm :: Int -> TT n -> TT n
195weakenTm i t = wk i 0 t
196 where wk i min (V x) | x >= min = V (i + x)
197 wk i m (App f a) = App (wk i m f) (wk i m a)
198 wk i m (Bind x b sc) = Bind x (wkb i m b) (wk i (m + 1) sc)
199 wk i m t = t
200 wkb i m t = fmap (wk i m) t
202-- weaken an environment so that all the de Bruijn indices are correct according
203-- to the latest bound variable
205weakenEnv :: EnvTT n -> EnvTT n
206weakenEnv env = wk (length env - 1) env
207 where wk i [] = []
208 wk i ((n, b) : bs) = (n, weakenTmB i b) : wk (i - 1) bs
209 weakenTmB i (Let t v) = Let (weakenTm i t) (weakenTm i v)
210 weakenTmB i (Guess t v) = Guess (weakenTm i t) (weakenTm i v)
211 weakenTmB i t = t { binderTy = weakenTm i (binderTy t) }
213weakenTmEnv :: Int -> EnvTT n -> EnvTT n
214weakenTmEnv i = map (\ (n, b) -> (n, fmap (weakenTm i) b))