git.iko.soy/Idris-dev
on b1419b2 help sign in
Idris-dev/src/Core/TT.hs
353 lines 11 kB history raw
1{-# LANGUAGE MultiParamTypeClasses, FunctionalDependencies, DeriveFunctor #-}
3module Core.TT where
5import Control.Monad.State
6import Debug.Trace
7import qualified Data.Map as Map
9{- The language has:
10 * Full dependent types
11 * A hierarchy of universes, with cumulativity: Set : Set1, Set1 : Set2, ...
12 * Pattern matching letrec binding
13 * (primitive types defined externally)
15 Some technical stuff:
16 * Typechecker is kept as simple as possible
17 - no unification, just a checker for incomplete terms.
18 * We have a simple collection of tactics which we use to elaborate source
19 programs with implicit syntax into fully explicit terms.
20-}
22data Option = SetInSet
23 | CheckConv
24 deriving Eq
26data Err = Msg String
27 | CantUnify Term Term
28 deriving Eq
30instance Show Err where
31 show (Msg s) = s
33data TC a = OK a
34 | Error Err
35 deriving (Eq, Functor)
37instance Show a => Show (TC a) where
38 show (OK x) = show x
39 show (Error str) = "Error: " ++ (show str)
41-- at some point, this instance should also carry type checking options
42-- (e.g. Set:Set)
44instance Monad TC where
45 return = OK
46 x >>= k = case x of
47 OK v -> k v
48 Error e -> Error e
49 fail e = Error (Msg e)
51tfail :: Err -> TC a
52tfail e = Error e
54instance MonadPlus TC where
55 mzero = fail "Unknown error"
56 (OK x) `mplus` _ = OK x
57 _ `mplus` (OK y) = OK y
58 err `mplus` _ = err
60discard :: Monad m => m a -> m ()
61discard f = f >> return ()
63showSep :: String -> [String] -> String
64showSep sep [] = ""
65showSep sep [x] = x
66showSep sep (x:xs) = x ++ sep ++ showSep sep xs
68-- RAW TERMS ----------------------------------------------------------------
70-- Names are hierarchies of strings, describing scope (so no danger of
71-- duplicate names, but need to be careful on lookup).
72-- Also MN for machine chosen names
74data Name = UN [String]
75 | MN Int String
76 deriving (Eq, Ord)
78instance Show Name where
79 show (UN [n]) = n
80 show (UN (n:ns)) = show (UN [n]) ++ "." ++ show (UN ns)
81 show (MN i s) = "{" ++ s ++ show i ++ "}"
84-- Contexts allow us to map names to things
85-- TODO: Namespaces and ambiguous names
87type Ctxt a = Map.Map Name a
88emptyContext = Map.empty
90addDef :: Name -> a -> Ctxt a -> Ctxt a
91addDef = Map.insert
93lookupCtxt :: Name -> Ctxt a -> Maybe a
94lookupCtxt = Map.lookup
96toAlist :: Ctxt a -> [(Name, a)]
97toAlist = Map.toList
99addAlist :: [(Name, a)] -> Ctxt a -> Ctxt a
100addAlist [] ctxt = ctxt
101addAlist ((n, tm) : ds) ctxt = addDef n tm (addAlist ds ctxt)
103data Const = I Int | Fl Double | Ch Char | Str String
104 | IType | FlType | ChType | StrType | PtrType
105 deriving Eq
107data Raw = Var Name
108 | RBind Name (Binder Raw) Raw
109 | RApp Raw Raw
110 | RSet Int
111 | RConstant Const
112 deriving Show
114data Binder b = Lam { binderTy :: b }
115 | Pi { binderTy :: b }
116 | Let { binderTy :: b,
117 binderVal :: b }
118 | NLet { binderTy :: b,
119 binderVal :: b }
120 | Hole { binderTy :: b}
121 | Guess { binderTy :: b,
122 binderVal :: b }
123 | PVar { binderTy :: b }
124 | PVTy { binderTy :: b }
125 deriving (Show, Eq, Functor)
127raw_apply :: Raw -> [Raw] -> Raw
128raw_apply f [] = f
129raw_apply f (a : as) = raw_apply (RApp f a) as
131data RawFun = RawFun { rtype :: Raw,
132 rval :: Raw
133 }
134 deriving Show
136data RawDatatype = RDatatype Name Raw [(Name, Raw)]
137 deriving Show
139data RDef = RFunction RawFun
140 | RConst Raw
141 | RData RawDatatype
142 deriving Show
144type RProgram = [(Name, RDef)]
146-- WELL TYPED TERMS ---------------------------------------------------------
148data NameType = Bound | Ref | DCon Int Int | TCon Int
149 deriving (Show, Eq)
151data TT n = P NameType n (TT n) -- embed type
152 | V Int
153 | Bind n (Binder (TT n)) (TT n)
154 | App (TT n) (TT n) -- function, function type, arg
155 | Constant Const
156 | Set Int
157 deriving Functor
159type EnvTT n = [(n, Binder (TT n))]
161data Datatype n = Data { d_typename :: n,
162 d_type :: (TT n),
163 d_cons :: [(n, TT n)] }
164 deriving (Show, Functor, Eq)
166instance Eq n => Eq (TT n) where
167 (==) (P xt x _) (P yt y _) = xt == yt && x == y
168 (==) (V x) (V y) = x == y
169 (==) (Bind _ xb xs) (Bind _ yb ys) = xb == yb && xs == ys
170 (==) (App fx ax) (App fy ay) = fx == fy && ax == ay
171 (==) (Set x) (Set y) = x == y
172 (==) (Constant x) (Constant y) = x == y
173 (==) _ _ = False
175-- A few handy operations on well typed terms:
177instantiate :: TT n -> TT n -> TT n
178instantiate e = subst 0 where
179 subst i (V x) | i == x = e
180 subst i (Bind x b sc) = Bind x (fmap (subst i) b) (subst (i+1) sc)
181 subst i (App f a) = App (subst i f) (subst i a)
182 subst i t = t
184pToV :: Eq n => n -> TT n -> TT n
185pToV n = pToV' n 0
186pToV' n i (P _ x _) | n == x = V i
187pToV' n i (Bind x b sc)
188 | n == x = Bind x (fmap (pToV' n i) b) sc
189 | otherwise = Bind x (fmap (pToV' n i) b) (pToV' n (i+1) sc)
190pToV' n i (App f a) = App (pToV' n i f) (pToV' n i a)
191pToV' n i t = t
193-- Convert several names. First in the list comes out as V 0
194pToVs :: Eq n => [n] -> TT n -> TT n
195pToVs ns tm = pToVs' ns tm 0 where
196 pToVs' [] tm i = tm
197 pToVs' (n:ns) tm i = pToV' n i (pToVs' ns tm (i+1))
199vToP :: TT n -> TT n
200vToP = vToP' [] where
201 vToP' env (V i) = let (n, b) = (env !! i) in
202 P Bound n (binderTy b)
203 vToP' env (Bind n b sc) = let b' = fmap (vToP' env) b in
204 Bind n b' (vToP' ((n, b'):env) sc)
205 vToP' env (App f a) = App (vToP' env f) (vToP' env a)
206 vToP' env t = t
208finalise :: Eq n => TT n -> TT n
209finalise (Bind x b sc) = Bind x (fmap finalise b) (pToV x (finalise sc))
210finalise (App f a) = App (finalise f) (finalise a)
211finalise t = t
213subst :: Eq n => n -> TT n -> TT n -> TT n
214subst n v tm = instantiate v (pToV n tm)
216substNames :: Eq n => [(n, TT n)] -> TT n -> TT n
217substNames [] t = t
218substNames ((n, tm) : xs) t = subst n tm (substNames xs t)
220-- Returns true if V 0 and bound name n do not occur in the term
222noOccurrence :: Eq n => n -> TT n -> Bool
223noOccurrence n t = no' 0 t
224 where
225 no' i (V x) = not (i == x)
226 no' i (P Bound x _) = not (n == x)
227 no' i (Bind n b sc) = noB' i b && no' (i+1) sc
228 where noB' i (Let t v) = no' i t && no' i v
229 noB' i (Guess t v) = no' i t && no' i v
230 noB' i b = no' i (binderTy b)
231 no' i (App f a) = no' i f && no' i a
232 no' i _ = True
234-- Return the arity of a (normalised) type
236arity :: TT n -> Int
237arity (Bind n (Pi t) sc) = 1 + arity sc
238arity _ = 0
240-- deconstruct an application; returns the function and a list of arguments
242unApply :: TT n -> (TT n, [TT n])
243unApply t = ua [] t where
244 ua args (App f a) = ua (a:args) f
245 ua args t = (t, args)
247mkApp :: TT n -> [TT n] -> TT n
248mkApp f [] = f
249mkApp f (a:as) = mkApp (App f a) as
251forget :: TT Name -> Raw
252forget tm = fe [] tm
253 where
254 fe env (P _ n _) = Var n
255 fe env (V i) = Var (env !! i)
256 fe env (Bind n b sc) = RBind n (fmap (fe env) b)
257 (fe (n:env) sc)
258 fe env (App f a) = RApp (fe env f) (fe env a)
259 fe env (Constant c)
260 = RConstant c
261 fe env (Set i) = RSet i
263type Term = TT Name
264type Type = Term
266type Env = EnvTT Name
268-- an environment with de Bruijn indices 'normalised' so that they all refer to
269-- this environment
271newtype WkEnvTT n = Wk (EnvTT n)
272type WkEnv = WkEnvTT Name
274instance (Eq n, Show n) => Show (TT n) where
275 show t = showEnv [] t
277instance Show Const where
278 show (I i) = show i
279 show (Fl f) = show f
280 show (Ch c) = show c
281 show (Str s) = show s
282 show IType = "Int"
283 show FlType = "Float"
284 show ChType = "Char"
285 show StrType = "String"
287showEnv env t = showEnv' env t False
288showEnvDbg env t = showEnv' env t True
290showEnv' env t dbg = se 10 env t where
291 se p env (P nt n t) = show n
292 ++ if dbg then "{" ++ show nt ++ " : " ++ se 10 env t ++ "}" else ""
293 se p env (V i) | i < length env = (show $ fst $ env!!i) ++
294 if dbg then "{" ++ show i ++ "}" else ""
295 | otherwise = "!!V " ++ show i ++ "!!"
296 se p env (Bind n b@(Pi t) sc)
297 | noOccurrence n sc && not dbg = bracket p 2 $ se 1 env t ++ " -> " ++ se 10 ((n,b):env) sc
298 se p env (Bind n b sc) = bracket p 2 $ sb env n b ++ se 10 ((n,b):env) sc
299 se p env (App f a) = bracket p 1 $ se 1 env f ++ " " ++ se 0 env a
300 se p env (Constant c) = show c
301 se p env (Set i) = "Set" ++ show i
303 sb env n (Lam t) = showb env "\\ " " => " n t
304 sb env n (Hole t) = showb env "? " ". " n t
305 sb env n (Pi t) = showb env "(" ") -> " n t
306 sb env n (PVar t) = showb env "pat " ". " n t
307 sb env n (PVTy t) = showb env "pty " ". " n t
308 sb env n (Let t v) = showbv env "let " " in " n t v
309 sb env n (Guess t v) = showbv env "?? " " in " n t v
311 showb env op sc n t = op ++ show n ++ " : " ++ se 10 env t ++ sc
312 showbv env op sc n t v = op ++ show n ++ " : " ++ se 10 env t ++ " = " ++
313 se 10 env v ++ sc
315 bracket outer inner str | inner > outer = "(" ++ str ++ ")"
316 | otherwise = str
318-- Check whether a term has any holes in it - impure if so
320pureTerm :: TT n -> Bool
321pureTerm (App f a) = pureTerm f && pureTerm a
322pureTerm (Bind n b sc) = pureBinder b && pureTerm sc where
323 pureBinder (Hole _) = False
324 pureBinder (Guess _ _) = False
325 pureBinder (Let t v) = pureTerm t && pureTerm v
326 pureBinder t = pureTerm (binderTy t)
327pureTerm _ = True
329-- weaken a term by adding i to each de Bruijn index (i.e. lift it over i bindings)
331weakenTm :: Int -> TT n -> TT n
332weakenTm i t = wk i 0 t
333 where wk i min (V x) | x >= min = V (i + x)
334 wk i m (App f a) = App (wk i m f) (wk i m a)
335 wk i m (Bind x b sc) = Bind x (wkb i m b) (wk i (m + 1) sc)
336 wk i m t = t
337 wkb i m t = fmap (wk i m) t
339-- weaken an environment so that all the de Bruijn indices are correct according
340-- to the latest bound variable
342weakenEnv :: EnvTT n -> EnvTT n
343weakenEnv env = wk (length env - 1) env
344 where wk i [] = []
345 wk i ((n, b) : bs) = (n, weakenTmB i b) : wk (i - 1) bs
346 weakenTmB i (Let t v) = Let (weakenTm i t) (weakenTm i v)
347 weakenTmB i (Guess t v) = Guess (weakenTm i t) (weakenTm i v)
348 weakenTmB i t = t { binderTy = weakenTm i (binderTy t) }
350weakenTmEnv :: Int -> EnvTT n -> EnvTT n
351weakenTmEnv i = map (\ (n, b) -> (n, fmap (weakenTm i) b))