git.iko.soy/Idris-dev
on b894841 help sign in
Idris-dev/src/Core/TT.hs
798 lines 26 kB history raw
1{-# LANGUAGE MultiParamTypeClasses, FunctionalDependencies, DeriveFunctor #-}
3module Core.TT where
5import Control.Monad.State
6import Debug.Trace
7import qualified Data.Map as Map
8import Data.Char
9import Data.List
10import qualified Data.Binary as B
11import Data.Binary hiding (get, put)
13import Util.Pretty hiding (Str)
15{- The language has:
16 * Full dependent types
17 * A hierarchy of universes, with cumulativity: Set : Set1, Set1 : Set2, ...
18 * Pattern matching letrec binding
19 * (primitive types defined externally)
21 Some technical stuff:
22 * Typechecker is kept as simple as possible
23 - no unification, just a checker for incomplete terms.
24 * We have a simple collection of tactics which we use to elaborate source
25 programs with implicit syntax into fully explicit terms.
26-}
28data Option = SetInSet
29 | CheckConv
30 deriving Eq
32data FC = FC { fc_fname :: String,
33 fc_line :: Int }
34 deriving Eq
35{-!
36deriving instance Binary FC
37!-}
39instance Sized FC where
40 size (FC f l) = 1 + length f
42instance Show FC where
43 show (FC f l) = f ++ ":" ++ show l
45data Err = Msg String
46 | InternalMsg String
47 | CantUnify Bool Term Term Err [(Name, Type)] Int
48 -- Int is 'score' - how much we did unify
49 -- Bool indicates recoverability, True indicates more info may make
50 -- unification succeed
51 | InfiniteUnify Name Term [(Name, Type)]
52 | CantConvert Term Term [(Name, Type)]
53 | NoSuchVariable Name
54 | NoTypeDecl Name
55 | NotInjective Term Term Term
56 | CantResolve Term
57 | CantResolveAlts [String]
58 | IncompleteTerm Term
59 | UniverseError
60 | ProgramLineComment
61 | Inaccessible Name
62 | At FC Err
63 deriving Eq
65instance Sized Err where
66 size (Msg msg) = length msg
67 size (InternalMsg msg) = length msg
68 size (CantUnify _ left right err _ score) = size left + size right + size err
69 size (InfiniteUnify _ right _) = size right
70 size (CantConvert left right _) = size left + size right
71 size (NoSuchVariable name) = size name
72 size (NoTypeDecl name) = size name
73 size (NotInjective l c r) = size l + size c + size r
74 size (CantResolve trm) = size trm
75 size (CantResolveAlts _) = 1
76 size (IncompleteTerm trm) = size trm
77 size UniverseError = 1
78 size ProgramLineComment = 1
79 size (At fc err) = size fc + size err
80 size (Inaccessible _) = 1
82score :: Err -> Int
83score (CantUnify _ _ _ m _ s) = s + score m
84score (CantResolve _) = 20
85score (NoSuchVariable _) = 1000
86score _ = 0
88instance Show Err where
89 show (Msg s) = s
90 show (InternalMsg s) = "Internal error: " ++ show s
91 show (CantUnify _ l r e sc i) = "CantUnify " ++ show l ++ " " ++ show r ++ " "
92 ++ show e ++ " in " ++ show sc ++ " " ++ show i
93 show (Inaccessible n) = show n ++ " is not an accessible pattern variable"
94 show _ = "Error"
96instance Pretty Err where
97 pretty (Msg m) = text m
98 pretty (CantUnify _ l r e _ i) =
99 if size l + size r > breakingSize then
100 text "Cannot unify" <+> colon $$
101 nest nestingSize (pretty l <+> text "and" <+> pretty r) $$
102 nest nestingSize (text "where" <+> pretty e <+> text "with" <+> (text . show $ i))
103 else
104 text "Cannot unify" <+> colon <+> pretty l <+> text "and" <+> pretty r $$
105 nest nestingSize (text "where" <+> pretty e <+> text "with" <+> (text . show $ i))
106 pretty _ = text "Error"
108data TC a = OK a
109 | Error Err
110 deriving (Eq, Functor)
112instance Pretty a => Pretty (TC a) where
113 pretty (OK ok) = pretty ok
114 pretty (Error err) =
115 if size err > breakingSize then
116 text "Error" <+> colon $$ (nest nestingSize $ pretty err)
117 else
118 text "Error" <+> colon <+> pretty err
120instance Show a => Show (TC a) where
121 show (OK x) = show x
122 show (Error str) = "Error: " ++ show str
124-- at some point, this instance should also carry type checking options
125-- (e.g. Set:Set)
127instance Monad TC where
128 return = OK
129 x >>= k = case x of
130 OK v -> k v
131 Error e -> Error e
132 fail e = Error (InternalMsg e)
134tfail :: Err -> TC a
135tfail e = Error e
137trun :: FC -> TC a -> TC a
138trun fc (OK a) = OK a
139trun fc (Error e) = Error (At fc e)
141instance MonadPlus TC where
142 mzero = fail "Unknown error"
143 (OK x) `mplus` _ = OK x
144 _ `mplus` (OK y) = OK y
145 err `mplus` _ = err
147discard :: Monad m => m a -> m ()
148discard f = f >> return ()
150showSep :: String -> [String] -> String
151showSep sep [] = ""
152showSep sep [x] = x
153showSep sep (x:xs) = x ++ sep ++ showSep sep xs
155pmap f (x, y) = (f x, f y)
157traceWhen True msg a = trace msg a
158traceWhen False _ a = a
160-- RAW TERMS ----------------------------------------------------------------
162-- Names are hierarchies of strings, describing scope (so no danger of
163-- duplicate names, but need to be careful on lookup).
164-- Also MN for machine chosen names
166data Name = UN String
167 | NS Name [String] -- root, namespaces
168 | MN Int String
169 | NErased -- name of somethng which is never used in scope
170 deriving (Eq, Ord)
171{-!
172deriving instance Binary Name
173!-}
175instance Sized Name where
176 size (UN n) = 1
177 size (NS n els) = 1 + length els
178 size (MN i n) = 1
179 size NErased = 1
181instance Pretty Name where
182 pretty (UN n) = text n
183 pretty (NS n s) = pretty n
184 pretty (MN i s) = lbrace <+> text s <+> (text . show $ i) <+> rbrace
186instance Show Name where
187 show (UN n) = n
188 show (NS n s) = showSep "." (reverse s) ++ "." ++ show n
189 show (MN i s) = "{" ++ s ++ show i ++ "}"
190 show NErased = "_"
192-- Contexts allow us to map names to things. A root name maps to a collection
193-- of things in different namespaces with that name.
195type Ctxt a = Map.Map Name (Map.Map Name a)
196emptyContext = Map.empty
198nsroot (NS n _) = n
199nsroot n = n
201addDef :: Name -> a -> Ctxt a -> Ctxt a
202addDef n v ctxt = case Map.lookup (nsroot n) ctxt of
203 Nothing -> Map.insert (nsroot n)
204 (Map.insert n v Map.empty) ctxt
205 Just xs -> Map.insert (nsroot n)
206 (Map.insert n v xs) ctxt
208{- lookup a name in the context, given an optional namespace.
209 The name (n) may itself have a (partial) namespace given.
211 Rules for resolution:
212 - if an explicit namespace is given, return the names which match it. If none
213 match, return all names.
214 - if the name has has explicit namespace given, return the names which match it
215 and ignore the given namespace.
216 - otherwise, return all names.
218-}
220lookupCtxtName :: Maybe [String] -> Name -> Ctxt a -> [(Name, a)]
221lookupCtxtName nspace n ctxt = case Map.lookup (nsroot n) ctxt of
222 Just xs -> filterNS (Map.toList xs)
223 Nothing -> []
224 where
225 filterNS [] = []
226 filterNS ((found, v) : xs)
227 | nsmatch n found = (found, v) : filterNS xs
228 | otherwise = filterNS xs
230 nsmatch (NS n ns) (NS p ps) = ns `isPrefixOf` ps
231 nsmatch (NS _ _) _ = False
232 nsmatch looking found = True
234lookupCtxt :: Maybe [String] -> Name -> Ctxt a -> [a]
235lookupCtxt ns n ctxt = map snd (lookupCtxtName ns n ctxt)
237updateDef :: Name -> (a -> a) -> Ctxt a -> Ctxt a
238updateDef n f ctxt
239 = let ds = lookupCtxtName Nothing n ctxt in
240 foldr (\ (n, t) c -> addDef n (f t) c) ctxt ds
242toAlist :: Ctxt a -> [(Name, a)]
243toAlist ctxt = let allns = map snd (Map.toList ctxt) in
244 concat (map (Map.toList) allns)
246addAlist :: Show a => [(Name, a)] -> Ctxt a -> Ctxt a
247addAlist [] ctxt = ctxt
248addAlist ((n, tm) : ds) ctxt = addDef n tm (addAlist ds ctxt)
250data Const = I Int | BI Integer | Fl Double | Ch Char | Str String
251 | IType | BIType | FlType | ChType | StrType
252 | PtrType | VoidType | Forgot
253 deriving (Eq, Ord)
254{-!
255deriving instance Binary Const
256!-}
258instance Sized Const where
259 size _ = 1
261instance Pretty Const where
262 pretty (I i) = text . show $ i
263 pretty (BI i) = text . show $ i
264 pretty (Fl f) = text . show $ f
265 pretty (Ch c) = text . show $ c
266 pretty (Str s) = text s
267 pretty IType = text "Int"
268 pretty BIType = text "BigInt"
269 pretty FlType = text "Float"
270 pretty ChType = text "Char"
271 pretty StrType = text "String"
272 pretty PtrType = text "Ptr"
273 pretty VoidType = text "Void"
274 pretty Forgot = text "Forgot"
276data Raw = Var Name
277 | RBind Name (Binder Raw) Raw
278 | RApp Raw Raw
279 | RSet
280 | RForce Raw
281 | RConstant Const
282 deriving (Show, Eq)
284instance Sized Raw where
285 size (Var name) = 1
286 size (RBind name bind right) = 1 + size bind + size right
287 size (RApp left right) = 1 + size left + size right
288 size RSet = 1
289 size (RForce raw) = 1 + size raw
290 size (RConstant const) = size const
292instance Pretty Raw where
293 pretty = text . show
295{-!
296deriving instance Binary Raw
297!-}
299data Binder b = Lam { binderTy :: b }
300 | Pi { binderTy :: b }
301 | Let { binderTy :: b,
302 binderVal :: b }
303 | NLet { binderTy :: b,
304 binderVal :: b }
305 | Hole { binderTy :: b}
306 | GHole { binderTy :: b}
307 | Guess { binderTy :: b,
308 binderVal :: b }
309 | PVar { binderTy :: b }
310 | PVTy { binderTy :: b }
311 deriving (Show, Eq, Ord, Functor)
312{-!
313deriving instance Binary Binder
314!-}
316instance Sized a => Sized (Binder a) where
317 size (Lam ty) = 1 + size ty
318 size (Pi ty) = 1 + size ty
319 size (Let ty val) = 1 + size ty + size val
320 size (NLet ty val) = 1 + size ty + size val
321 size (Hole ty) = 1 + size ty
322 size (GHole ty) = 1 + size ty
323 size (Guess ty val) = 1 + size ty + size val
324 size (PVar ty) = 1 + size ty
325 size (PVTy ty) = 1 + size ty
327fmapMB :: Monad m => (a -> m b) -> Binder a -> m (Binder b)
328fmapMB f (Let t v) = liftM2 Let (f t) (f v)
329fmapMB f (NLet t v) = liftM2 NLet (f t) (f v)
330fmapMB f (Guess t v) = liftM2 Guess (f t) (f v)
331fmapMB f (Lam t) = liftM Lam (f t)
332fmapMB f (Pi t) = liftM Pi (f t)
333fmapMB f (Hole t) = liftM Hole (f t)
334fmapMB f (GHole t) = liftM GHole (f t)
335fmapMB f (PVar t) = liftM PVar (f t)
336fmapMB f (PVTy t) = liftM PVTy (f t)
338raw_apply :: Raw -> [Raw] -> Raw
339raw_apply f [] = f
340raw_apply f (a : as) = raw_apply (RApp f a) as
342raw_unapply :: Raw -> (Raw, [Raw])
343raw_unapply t = ua [] t where
344 ua args (RApp f a) = ua (a:args) f
345 ua args t = (t, args)
347data RawFun = RawFun { rtype :: Raw,
348 rval :: Raw
349 }
350 deriving Show
352data RawDatatype = RDatatype Name Raw [(Name, Raw)]
353 deriving Show
355data RDef = RFunction RawFun
356 | RConst Raw
357 | RData RawDatatype
358 deriving Show
360type RProgram = [(Name, RDef)]
362-- WELL TYPED TERMS ---------------------------------------------------------
364data UExp = UVar Int -- universe variable
365 | UVal Int -- explicit universe level
366 deriving (Eq, Ord)
368instance Sized UExp where
369 size _ = 1
371-- We assume that universe levels have been checked, so anything external
372-- can just have the same universe variable and we won't get any new
373-- cycles.
375instance Binary UExp where
376 put x = return ()
377 get = return (UVar (-1))
379instance Show UExp where
380 show (UVar x) | x < 26 = [toEnum (x + fromEnum 'a')]
381 | otherwise = toEnum ((x `mod` 26) + fromEnum 'a') : show (x `div` 26)
382 show (UVal x) = show x
383-- show (UMax l r) = "max(" ++ show l ++ ", " ++ show r ++")"
385data UConstraint = ULT UExp UExp
386 | ULE UExp UExp
387 deriving Eq
389instance Show UConstraint where
390 show (ULT x y) = show x ++ " < " ++ show y
391 show (ULE x y) = show x ++ " <= " ++ show y
393type UCs = (Int, [UConstraint])
395data NameType = Bound | Ref | DCon Int Int | TCon Int Int
396 deriving (Show, Ord)
397{-!
398deriving instance Binary NameType
399!-}
401instance Sized NameType where
402 size _ = 1
404instance Pretty NameType where
405 pretty = text . show
407instance Eq NameType where
408 Bound == Bound = True
409 Ref == Ref = True
410 DCon _ a == DCon _ b = (a == b) -- ignore tag
411 TCon _ a == TCon _ b = (a == b) -- ignore tag
412 _ == _ = False
414data TT n = P NameType n (TT n) -- embed type
415 | V Int
416 | Bind n (Binder (TT n)) (TT n)
417 | App (TT n) (TT n) -- function, function type, arg
418 | Constant Const
419 | Proj (TT n) Int -- argument projection; runtime only
420 | Erased
421 | Impossible -- special case for totality checking
422 | Set UExp
423 deriving (Ord, Functor)
424{-!
425deriving instance Binary TT
426!-}
428class TermSize a where
429 termsize :: a -> Int
431instance TermSize a => TermSize [a] where
432 termsize [] = 0
433 termsize (x : xs) = termsize x + termsize xs
435instance TermSize (TT a) where
436 termsize (P _ _ _) = 1
437 termsize (V _) = 1
438 termsize (Bind n (Let t v) sc) = termsize v + termsize sc
439 termsize (App f a) = termsize f + termsize a
440 termsize _ = 1
442instance Sized a => Sized (TT a) where
443 size (P name n trm) = 1 + size name + size n + size trm
444 size (V v) = 1
445 size (Bind nm binder bdy) = 1 + size nm + size binder + size bdy
446 size (App l r) = 1 + size l + size r
447 size (Constant c) = size c
448 size Erased = 1
449 size (Set u) = 1 + size u
451instance Pretty a => Pretty (TT a) where
452 pretty _ = text "test"
454type EnvTT n = [(n, Binder (TT n))]
456data Datatype n = Data { d_typename :: n,
457 d_typetag :: Int,
458 d_type :: (TT n),
459 d_cons :: [(n, TT n)] }
460 deriving (Show, Functor, Eq)
462instance Eq n => Eq (TT n) where
463 (==) (P xt x _) (P yt y _) = xt == yt && x == y
464 (==) (V x) (V y) = x == y
465 (==) (Bind _ xb xs) (Bind _ yb ys) = xb == yb && xs == ys
466 (==) (App fx ax) (App fy ay) = fx == fy && ax == ay
467 (==) (Set _) (Set _) = True -- deal with constraints later
468 (==) (Constant x) (Constant y) = x == y
469 (==) (Proj x i) (Proj y j) = x == y && i == j
470 (==) Erased _ = True
471 (==) _ Erased = True
472 (==) _ _ = False
474-- A few handy operations on well typed terms:
476isInjective :: TT n -> Bool
477isInjective (P (DCon _ _) _ _) = True
478isInjective (P (TCon _ _) _ _) = True
479isInjective (Constant _) = True
480isInjective (Set x) = True
481isInjective (Bind _ (Pi _) sc) = True
482isInjective (App f a) = isInjective f
483isInjective _ = False
485-- Count the number of instances of a de Bruijn index in a term
486vinstances :: Int -> TT n -> Int
487vinstances i (V x) | i == x = 1
488vinstances i (App f a) = vinstances i f + vinstances i a
489vinstances i (Bind x b sc) = instancesB b + vinstances (i + 1) sc
490 where instancesB (Let t v) = vinstances i v
491 instancesB _ = 0
492vinstances i t = 0
494instantiate :: TT n -> TT n -> TT n
495instantiate e = subst 0 where
496 subst i (V x) | i == x = e
497 subst i (Bind x b sc) = Bind x (fmap (subst i) b) (subst (i+1) sc)
498 subst i (App f a) = App (subst i f) (subst i a)
499 subst i (Proj x idx) = Proj (subst i x) idx
500 subst i t = t
502pToV :: Eq n => n -> TT n -> TT n
503pToV n = pToV' n 0
504pToV' n i (P _ x _) | n == x = V i
505pToV' n i (Bind x b sc)
506 | n == x = Bind x (fmap (pToV' n i) b) sc
507 | otherwise = Bind x (fmap (pToV' n i) b) (pToV' n (i+1) sc)
508pToV' n i (App f a) = App (pToV' n i f) (pToV' n i a)
509pToV' n i (Proj t idx) = Proj (pToV' n i t) idx
510pToV' n i t = t
512-- Convert several names. First in the list comes out as V 0
513pToVs :: Eq n => [n] -> TT n -> TT n
514pToVs ns tm = pToVs' ns tm 0 where
515 pToVs' [] tm i = tm
516 pToVs' (n:ns) tm i = pToV' n i (pToVs' ns tm (i+1))
518vToP :: TT n -> TT n
519vToP = vToP' [] where
520 vToP' env (V i) = let (n, b) = (env !! i) in
521 P Bound n (binderTy b)
522 vToP' env (Bind n b sc) = let b' = fmap (vToP' env) b in
523 Bind n b' (vToP' ((n, b'):env) sc)
524 vToP' env (App f a) = App (vToP' env f) (vToP' env a)
525 vToP' env t = t
527finalise :: Eq n => TT n -> TT n
528finalise (Bind x b sc) = Bind x (fmap finalise b) (pToV x (finalise sc))
529finalise (App f a) = App (finalise f) (finalise a)
530finalise t = t
532subst :: Eq n => n -> TT n -> TT n -> TT n
533subst n v tm = instantiate v (pToV n tm)
535substNames :: Eq n => [(n, TT n)] -> TT n -> TT n
536substNames [] t = t
537substNames ((n, tm) : xs) t = subst n tm (substNames xs t)
539-- Returns true if V 0 and bound name n do not occur in the term
541noOccurrence :: Eq n => n -> TT n -> Bool
542noOccurrence n t = no' 0 t
543 where
544 no' i (V x) = not (i == x)
545 no' i (P Bound x _) = not (n == x)
546 no' i (Bind n b sc) = noB' i b && no' (i+1) sc
547 where noB' i (Let t v) = no' i t && no' i v
548 noB' i (Guess t v) = no' i t && no' i v
549 noB' i b = no' i (binderTy b)
550 no' i (App f a) = no' i f && no' i a
551 no' i (Proj x _) = no' i x
552 no' i _ = True
554-- Returns all names used free in the term
556freeNames :: Eq n => TT n -> [n]
557freeNames (P _ n _) = [n]
558freeNames (Bind n (Let t v) sc) = nub $ freeNames v ++ (freeNames sc \\ [n])
559 ++ freeNames t
560freeNames (Bind n b sc) = nub $ freeNames (binderTy b) ++ (freeNames sc \\ [n])
561freeNames (App f a) = nub $ freeNames f ++ freeNames a
562freeNames (Proj x i) = nub $ freeNames x
563freeNames _ = []
565-- Return the arity of a (normalised) type
567arity :: TT n -> Int
568arity (Bind n (Pi t) sc) = 1 + arity sc
569arity _ = 0
571-- deconstruct an application; returns the function and a list of arguments
573unApply :: TT n -> (TT n, [TT n])
574unApply t = ua [] t where
575 ua args (App f a) = ua (a:args) f
576 ua args t = (t, args)
578mkApp :: TT n -> [TT n] -> TT n
579mkApp f [] = f
580mkApp f (a:as) = mkApp (App f a) as
582forget :: TT Name -> Raw
583forget tm = fe [] tm
584 where
585 fe env (P _ n _) = Var n
586 fe env (V i) = Var (env !! i)
587 fe env (Bind n b sc) = RBind n (fmap (fe env) b)
588 (fe (n:env) sc)
589 fe env (App f a) = RApp (fe env f) (fe env a)
590 fe env (Constant c)
591 = RConstant c
592 fe env (Set i) = RSet
593 fe env Erased = RConstant Forgot
595bindAll :: [(n, Binder (TT n))] -> TT n -> TT n
596bindAll [] t =t
597bindAll ((n, b) : bs) t = Bind n b (bindAll bs t)
599bindTyArgs :: (TT n -> Binder (TT n)) -> [(n, TT n)] -> TT n -> TT n
600bindTyArgs b xs = bindAll (map (\ (n, ty) -> (n, b ty)) xs)
602getArgTys :: TT n -> [(n, TT n)]
603getArgTys (Bind n (Pi t) sc) = (n, t) : getArgTys sc
604getArgTys _ = []
606getRetTy :: TT n -> TT n
607getRetTy (Bind n (PVar _) sc) = getRetTy sc
608getRetTy (Bind n (PVTy _) sc) = getRetTy sc
609getRetTy (Bind n (Pi _) sc) = getRetTy sc
610getRetTy sc = sc
612uniqueName :: Name -> [Name] -> Name
613uniqueName n hs | n `elem` hs = uniqueName (nextName n) hs
614 | otherwise = n
616nextName (NS x s) = NS (nextName x) s
617nextName (MN i n) = MN (i+1) n
618nextName (UN x) = let (num', nm') = span isDigit (reverse x)
619 nm = reverse nm'
620 num = readN (reverse num') in
621 UN (nm ++ show (num+1))
622 where
623 readN "" = 0
624 readN x = read x
626type Term = TT Name
627type Type = Term
629type Env = EnvTT Name
631-- an environment with de Bruijn indices 'normalised' so that they all refer to
632-- this environment
634newtype WkEnvTT n = Wk (EnvTT n)
635type WkEnv = WkEnvTT Name
637instance (Eq n, Show n) => Show (TT n) where
638 show t = showEnv [] t
640instance Show Const where
641 show (I i) = show i
642 show (BI i) = show i ++ "L"
643 show (Fl f) = show f
644 show (Ch c) = show c
645 show (Str s) = show s
646 show IType = "Int"
647 show BIType = "Integer"
648 show FlType = "Float"
649 show ChType = "Char"
650 show StrType = "String"
651 show PtrType = "Ptr"
652 show VoidType = "Void"
654showEnv env t = showEnv' env t False
655showEnvDbg env t = showEnv' env t True
657prettyEnv env t = prettyEnv' env t False
658 where
659 prettyEnv' env t dbg = prettySe 10 env t dbg
661 bracket outer inner p
662 | inner > outer = lparen <> p <> rparen
663 | otherwise = p
665 prettySe p env (P nt n t) debug =
666 pretty n <+>
667 if debug then
668 lbrack <+> pretty nt <+> colon <+> prettySe 10 env t debug <+> rbrack
669 else
670 empty
671 prettySe p env (V i) debug
672 | i < length env =
673 if debug then
674 text . show . fst $ env!!i
675 else
676 lbrack <+> text (show i) <+> rbrack
677 | otherwise = text "unbound" <+> text (show i) <+> text "!"
678 prettySe p env (Bind n b@(Pi t) sc) debug
679 | noOccurrence n sc && not debug =
680 bracket p 2 $ prettySb env n b debug <> prettySe 10 ((n, b):env) sc debug
681 prettySe p env (Bind n b sc) debug =
682 bracket p 2 $ prettySb env n b debug <> prettySe 10 ((n, b):env) sc debug
683 prettySe p env (App f a) debug =
684 bracket p 1 $ prettySe 1 env f debug <+> prettySe 0 env a debug
685 prettySe p env (Proj x i) debug =
686 prettySe 1 env x debug <+> text ("!" ++ show i)
687 prettySe p env (Constant c) debug = pretty c
688 prettySe p env Erased debug = text "[_]"
689 prettySe p env (Set i) debug = text "Set" <+> (text . show $ i)
691 prettySb env n (Lam t) = prettyB env "λ" "=>" n t
692 prettySb env n (Hole t) = prettyB env "?defer" "." n t
693 prettySb env n (Pi t) = prettyB env "(" ") ->" n t
694 prettySb env n (PVar t) = prettyB env "pat" "." n t
695 prettySb env n (PVTy t) = prettyB env "pty" "." n t
696 prettySb env n (Let t v) = prettyBv env "let" "in" n t v
697 prettySb env n (Guess t v) = prettyBv env "??" "in" n t v
699 prettyB env op sc n t debug =
700 text op <> pretty n <+> colon <+> prettySe 10 env t debug <> text sc
702 prettyBv env op sc n t v debug =
703 text op <> pretty n <+> colon <+> prettySe 10 env t debug <+> text "=" <+>
704 prettySe 10 env v debug <> text sc
707showEnv' env t dbg = se 10 env t where
708 se p env (P nt n t) = show n
709 ++ if dbg then "{" ++ show nt ++ " : " ++ se 10 env t ++ "}" else ""
710 se p env (V i) | i < length env = (show $ fst $ env!!i) ++
711 if dbg then "{" ++ show i ++ "}" else ""
712 | otherwise = "!!V " ++ show i ++ "!!"
713 se p env (Bind n b@(Pi t) sc)
714 | noOccurrence n sc && not dbg = bracket p 2 $ se 1 env t ++ " -> " ++ se 10 ((n,b):env) sc
715 se p env (Bind n b sc) = bracket p 2 $ sb env n b ++ se 10 ((n,b):env) sc
716 se p env (App f a) = bracket p 1 $ se 1 env f ++ " " ++ se 0 env a
717 se p env (Proj x i) = se 1 env x ++ "!" ++ show i
718 se p env (Constant c) = show c
719 se p env Erased = "[__]"
720 se p env Impossible = "[impossible]"
721 se p env (Set i) = "Set " ++ show i
723 sb env n (Lam t) = showb env "\\ " " => " n t
724 sb env n (Hole t) = showb env "? " ". " n t
725 sb env n (GHole t) = showb env "?defer " ". " n t
726 sb env n (Pi t) = showb env "(" ") -> " n t
727 sb env n (PVar t) = showb env "pat " ". " n t
728 sb env n (PVTy t) = showb env "pty " ". " n t
729 sb env n (Let t v) = showbv env "let " " in " n t v
730 sb env n (Guess t v) = showbv env "?? " " in " n t v
732 showb env op sc n t = op ++ show n ++ " : " ++ se 10 env t ++ sc
733 showbv env op sc n t v = op ++ show n ++ " : " ++ se 10 env t ++ " = " ++
734 se 10 env v ++ sc
736 bracket outer inner str | inner > outer = "(" ++ str ++ ")"
737 | otherwise = str
739-- Check whether a term has any holes in it - impure if so
741pureTerm :: TT n -> Bool
742pureTerm (App f a) = pureTerm f && pureTerm a
743pureTerm (Bind n b sc) = pureBinder b && pureTerm sc where
744 pureBinder (Hole _) = False
745 pureBinder (Guess _ _) = False
746 pureBinder (Let t v) = pureTerm t && pureTerm v
747 pureBinder t = pureTerm (binderTy t)
748pureTerm _ = True
750-- weaken a term by adding i to each de Bruijn index (i.e. lift it over i bindings)
752weakenTm :: Int -> TT n -> TT n
753weakenTm i t = wk i 0 t
754 where wk i min (V x) | x >= min = V (i + x)
755 wk i m (App f a) = App (wk i m f) (wk i m a)
756 wk i m (Bind x b sc) = Bind x (wkb i m b) (wk i (m + 1) sc)
757 wk i m t = t
758 wkb i m t = fmap (wk i m) t
760-- weaken an environment so that all the de Bruijn indices are correct according
761-- to the latest bound variable
763weakenEnv :: EnvTT n -> EnvTT n
764weakenEnv env = wk (length env - 1) env
765 where wk i [] = []
766 wk i ((n, b) : bs) = (n, weakenTmB i b) : wk (i - 1) bs
767 weakenTmB i (Let t v) = Let (weakenTm i t) (weakenTm i v)
768 weakenTmB i (Guess t v) = Guess (weakenTm i t) (weakenTm i v)
769 weakenTmB i t = t { binderTy = weakenTm i (binderTy t) }
771weakenTmEnv :: Int -> EnvTT n -> EnvTT n
772weakenTmEnv i = map (\ (n, b) -> (n, fmap (weakenTm i) b))
774orderPats :: Term -> Term
775orderPats tm = op [] tm
776 where
777 op ps (Bind n (PVar t) sc) = op ((n, t) : ps) sc
778 op ps sc = bindAll (map (\ (n, t) -> (n, PVar t)) (sortP ps)) sc
780 sortP ps = pick [] (reverse ps)
782 namesIn (P _ n _) = [n]
783 namesIn (Bind n b t) = nub $ nb b ++ (namesIn t \\ [n])
784 where nb (Let t v) = nub (namesIn t) ++ nub (namesIn v)
785 nb (Guess t v) = nub (namesIn t) ++ nub (namesIn v)
786 nb t = namesIn (binderTy t)
787 namesIn (App f a) = nub (namesIn f ++ namesIn a)
788 namesIn _ = []
790 pick acc [] = reverse acc
791 pick acc ((n, t) : ps) = pick (insert n t acc) ps
793 insert n t [] = [(n, t)]
794 insert n t ((n',t') : ps)
795 | n `elem` (namesIn t' ++ concatMap namesIn (map snd ps))
796 = (n', t') : insert n t ps
797 | otherwise = (n,t):(n',t'):ps