git.iko.soy/Idris-dev
on be2d7fa help sign in
Idris-dev/src/Core/TT.hs
436 lines 14 kB history raw
1{-# LANGUAGE MultiParamTypeClasses, FunctionalDependencies, DeriveFunctor #-}
3module Core.TT where
5import Control.Monad.State
6import Debug.Trace
7import qualified Data.Map as Map
8import Data.Char
9import Data.List
11{- The language has:
12 * Full dependent types
13 * A hierarchy of universes, with cumulativity: Set : Set1, Set1 : Set2, ...
14 * Pattern matching letrec binding
15 * (primitive types defined externally)
17 Some technical stuff:
18 * Typechecker is kept as simple as possible
19 - no unification, just a checker for incomplete terms.
20 * We have a simple collection of tactics which we use to elaborate source
21 programs with implicit syntax into fully explicit terms.
22-}
24data Option = SetInSet
25 | CheckConv
26 deriving Eq
28data FC = FC { fc_fname :: String,
29 fc_line :: Int }
30 deriving Eq
32instance Show FC where
33 show (FC f l) = f ++ ":" ++ show l
35data Err = Msg String
36 | CantUnify Term Term Err
37 | At FC Err
38 deriving Eq
40instance Show Err where
41 show (Msg s) = s
43data TC a = OK a
44 | Error Err
45 deriving (Eq, Functor)
47instance Show a => Show (TC a) where
48 show (OK x) = show x
49 show (Error str) = "Error: " ++ show str
51-- at some point, this instance should also carry type checking options
52-- (e.g. Set:Set)
54instance Monad TC where
55 return = OK
56 x >>= k = case x of
57 OK v -> k v
58 Error e -> Error e
59 fail e = Error (Msg e)
61tfail :: Err -> TC a
62tfail e = Error e
64trun :: FC -> TC a -> TC a
65trun fc (OK a) = OK a
66trun fc (Error e) = Error (At fc e)
68instance MonadPlus TC where
69 mzero = fail "Unknown error"
70 (OK x) `mplus` _ = OK x
71 _ `mplus` (OK y) = OK y
72 err `mplus` _ = err
74discard :: Monad m => m a -> m ()
75discard f = f >> return ()
77showSep :: String -> [String] -> String
78showSep sep [] = ""
79showSep sep [x] = x
80showSep sep (x:xs) = x ++ sep ++ showSep sep xs
82traceWhen True msg a = trace msg a
83traceWhen False _ a = a
85-- RAW TERMS ----------------------------------------------------------------
87-- Names are hierarchies of strings, describing scope (so no danger of
88-- duplicate names, but need to be careful on lookup).
89-- Also MN for machine chosen names
91data Name = UN [String]
92 | MN Int String
93 deriving (Eq, Ord)
95instance Show Name where
96 show (UN [n]) = n
97 show (UN (n:ns)) = show (UN [n]) ++ "." ++ show (UN ns)
98 show (MN i s) = "{" ++ s ++ show i ++ "}"
101-- Contexts allow us to map names to things
102-- TODO: Namespaces and ambiguous names
104type Ctxt a = Map.Map Name a
105emptyContext = Map.empty
107addDef :: Name -> a -> Ctxt a -> Ctxt a
108addDef = Map.insert
110lookupCtxt :: Name -> Ctxt a -> Maybe a
111lookupCtxt = Map.lookup
113toAlist :: Ctxt a -> [(Name, a)]
114toAlist = Map.toList
116addAlist :: [(Name, a)] -> Ctxt a -> Ctxt a
117addAlist [] ctxt = ctxt
118addAlist ((n, tm) : ds) ctxt = addDef n tm (addAlist ds ctxt)
120data Const = I Int | BI Integer | Fl Double | Ch Char | Str String
121 | IType | BIType | FlType | ChType | StrType
122 | PtrType
123 deriving Eq
125data Raw = Var Name
126 | RBind Name (Binder Raw) Raw
127 | RApp Raw Raw
128 | RSet Int
129 | RConstant Const
130 deriving (Show, Eq)
132data Binder b = Lam { binderTy :: b }
133 | Pi { binderTy :: b }
134 | Let { binderTy :: b,
135 binderVal :: b }
136 | NLet { binderTy :: b,
137 binderVal :: b }
138 | Hole { binderTy :: b}
139 | GHole { binderTy :: b}
140 | Guess { binderTy :: b,
141 binderVal :: b }
142 | PVar { binderTy :: b }
143 | PVTy { binderTy :: b }
144 deriving (Show, Eq, Functor)
146fmapMB :: Monad m => (a -> m b) -> Binder a -> m (Binder b)
147fmapMB f (Let t v) = liftM2 Let (f t) (f v)
148fmapMB f (NLet t v) = liftM2 NLet (f t) (f v)
149fmapMB f (Guess t v) = liftM2 Guess (f t) (f v)
150fmapMB f (Lam t) = liftM Lam (f t)
151fmapMB f (Pi t) = liftM Pi (f t)
152fmapMB f (Hole t) = liftM Hole (f t)
153fmapMB f (GHole t) = liftM GHole (f t)
154fmapMB f (PVar t) = liftM PVar (f t)
155fmapMB f (PVTy t) = liftM PVTy (f t)
157raw_apply :: Raw -> [Raw] -> Raw
158raw_apply f [] = f
159raw_apply f (a : as) = raw_apply (RApp f a) as
161data RawFun = RawFun { rtype :: Raw,
162 rval :: Raw
163 }
164 deriving Show
166data RawDatatype = RDatatype Name Raw [(Name, Raw)]
167 deriving Show
169data RDef = RFunction RawFun
170 | RConst Raw
171 | RData RawDatatype
172 deriving Show
174type RProgram = [(Name, RDef)]
176-- WELL TYPED TERMS ---------------------------------------------------------
178data NameType = Bound | Ref | DCon Int Int | TCon Int Int
179 deriving (Show, Eq)
181data TT n = P NameType n (TT n) -- embed type
182 | V Int
183 | Bind n (Binder (TT n)) (TT n)
184 | App (TT n) (TT n) -- function, function type, arg
185 | Constant Const
186 | Set Int
187 deriving Functor
189type EnvTT n = [(n, Binder (TT n))]
191data Datatype n = Data { d_typename :: n,
192 d_typetag :: Int,
193 d_type :: (TT n),
194 d_cons :: [(n, TT n)] }
195 deriving (Show, Functor, Eq)
197instance Eq n => Eq (TT n) where
198 (==) (P xt x _) (P yt y _) = xt == yt && x == y
199 (==) (V x) (V y) = x == y
200 (==) (Bind _ xb xs) (Bind _ yb ys) = xb == yb && xs == ys
201 (==) (App fx ax) (App fy ay) = fx == fy && ax == ay
202 (==) (Set x) (Set y) = x == y
203 (==) (Constant x) (Constant y) = x == y
204 (==) _ _ = False
206-- A few handy operations on well typed terms:
208instantiate :: TT n -> TT n -> TT n
209instantiate e = subst 0 where
210 subst i (V x) | i == x = e
211 subst i (Bind x b sc) = Bind x (fmap (subst i) b) (subst (i+1) sc)
212 subst i (App f a) = App (subst i f) (subst i a)
213 subst i t = t
215pToV :: Eq n => n -> TT n -> TT n
216pToV n = pToV' n 0
217pToV' n i (P _ x _) | n == x = V i
218pToV' n i (Bind x b sc)
219 | n == x = Bind x (fmap (pToV' n i) b) sc
220 | otherwise = Bind x (fmap (pToV' n i) b) (pToV' n (i+1) sc)
221pToV' n i (App f a) = App (pToV' n i f) (pToV' n i a)
222pToV' n i t = t
224-- Convert several names. First in the list comes out as V 0
225pToVs :: Eq n => [n] -> TT n -> TT n
226pToVs ns tm = pToVs' ns tm 0 where
227 pToVs' [] tm i = tm
228 pToVs' (n:ns) tm i = pToV' n i (pToVs' ns tm (i+1))
230vToP :: TT n -> TT n
231vToP = vToP' [] where
232 vToP' env (V i) = let (n, b) = (env !! i) in
233 P Bound n (binderTy b)
234 vToP' env (Bind n b sc) = let b' = fmap (vToP' env) b in
235 Bind n b' (vToP' ((n, b'):env) sc)
236 vToP' env (App f a) = App (vToP' env f) (vToP' env a)
237 vToP' env t = t
239finalise :: Eq n => TT n -> TT n
240finalise (Bind x b sc) = Bind x (fmap finalise b) (pToV x (finalise sc))
241finalise (App f a) = App (finalise f) (finalise a)
242finalise t = t
244subst :: Eq n => n -> TT n -> TT n -> TT n
245subst n v tm = instantiate v (pToV n tm)
247substNames :: Eq n => [(n, TT n)] -> TT n -> TT n
248substNames [] t = t
249substNames ((n, tm) : xs) t = subst n tm (substNames xs t)
251-- Returns true if V 0 and bound name n do not occur in the term
253noOccurrence :: Eq n => n -> TT n -> Bool
254noOccurrence n t = no' 0 t
255 where
256 no' i (V x) = not (i == x)
257 no' i (P Bound x _) = not (n == x)
258 no' i (Bind n b sc) = noB' i b && no' (i+1) sc
259 where noB' i (Let t v) = no' i t && no' i v
260 noB' i (Guess t v) = no' i t && no' i v
261 noB' i b = no' i (binderTy b)
262 no' i (App f a) = no' i f && no' i a
263 no' i _ = True
265-- Return the arity of a (normalised) type
267arity :: TT n -> Int
268arity (Bind n (Pi t) sc) = 1 + arity sc
269arity _ = 0
271-- deconstruct an application; returns the function and a list of arguments
273unApply :: TT n -> (TT n, [TT n])
274unApply t = ua [] t where
275 ua args (App f a) = ua (a:args) f
276 ua args t = (t, args)
278mkApp :: TT n -> [TT n] -> TT n
279mkApp f [] = f
280mkApp f (a:as) = mkApp (App f a) as
282forget :: TT Name -> Raw
283forget tm = fe [] tm
284 where
285 fe env (P _ n _) = Var n
286 fe env (V i) = Var (env !! i)
287 fe env (Bind n b sc) = RBind n (fmap (fe env) b)
288 (fe (n:env) sc)
289 fe env (App f a) = RApp (fe env f) (fe env a)
290 fe env (Constant c)
291 = RConstant c
292 fe env (Set i) = RSet i
294bindAll :: [(n, Binder (TT n))] -> TT n -> TT n
295bindAll [] t =t
296bindAll ((n, b) : bs) t = Bind n b (bindAll bs t)
298bindTyArgs :: (TT n -> Binder (TT n)) -> [(n, TT n)] -> TT n -> TT n
299bindTyArgs b xs = bindAll (map (\ (n, ty) -> (n, b ty)) xs)
301getArgTys :: TT n -> [(n, TT n)]
302getArgTys (Bind n (Pi t) sc) = (n, t) : getArgTys sc
303getArgTys _ = []
305uniqueName :: Name -> [Name] -> Name
306uniqueName n hs | n `elem` hs = uniqueName (nextName n) hs
307 | otherwise = n
309nextName (MN i n) = MN (i+1) n
310nextName (UN (x:xs)) = let (num', nm') = span isDigit (reverse x)
311 nm = reverse nm'
312 num = readN (reverse num') in
313 UN ((nm ++ show (num+1)) : xs)
314 where
315 readN "" = 0
316 readN x = read x
318type Term = TT Name
319type Type = Term
321type Env = EnvTT Name
323-- an environment with de Bruijn indices 'normalised' so that they all refer to
324-- this environment
326newtype WkEnvTT n = Wk (EnvTT n)
327type WkEnv = WkEnvTT Name
329instance (Eq n, Show n) => Show (TT n) where
330 show t = showEnv [] t
332instance Show Const where
333 show (I i) = show i
334 show (BI i) = show i ++ "L"
335 show (Fl f) = show f
336 show (Ch c) = show c
337 show (Str s) = show s
338 show IType = "Int"
339 show BIType = "Integer"
340 show FlType = "Float"
341 show ChType = "Char"
342 show StrType = "String"
343 show PtrType = "Ptr"
345showEnv env t = showEnv' env t False
346showEnvDbg env t = showEnv' env t True
348showEnv' env t dbg = se 10 env t where
349 se p env (P nt n t) = show n
350 -- ++ if dbg then "{" ++ show nt ++ " : " ++ se 10 env t ++ "}" else ""
351 se p env (V i) | i < length env = (show $ fst $ env!!i) ++
352 if dbg then "{" ++ show i ++ "}" else ""
353 | otherwise = "!!V " ++ show i ++ "!!"
354 se p env (Bind n b@(Pi t) sc)
355 | noOccurrence n sc && not dbg = bracket p 2 $ se 1 env t ++ " -> " ++ se 10 ((n,b):env) sc
356 se p env (Bind n b sc) = bracket p 2 $ sb env n b ++ se 10 ((n,b):env) sc
357 se p env (App f a) = bracket p 1 $ se 1 env f ++ " " ++ se 0 env a
358 se p env (Constant c) = show c
359 se p env (Set i) = "Set" ++ show i
361 sb env n (Lam t) = showb env "\\ " " => " n t
362 sb env n (Hole t) = showb env "? " ". " n t
363 sb env n (GHole t) = showb env "?defer " ". " n t
364 sb env n (Pi t) = showb env "(" ") -> " n t
365 sb env n (PVar t) = showb env "pat " ". " n t
366 sb env n (PVTy t) = showb env "pty " ". " n t
367 sb env n (Let t v) = showbv env "let " " in " n t v
368 sb env n (Guess t v) = showbv env "?? " " in " n t v
370 showb env op sc n t = op ++ show n ++ " : " ++ se 10 env t ++ sc
371 showbv env op sc n t v = op ++ show n ++ " : " ++ se 10 env t ++ " = " ++
372 se 10 env v ++ sc
374 bracket outer inner str | inner > outer = "(" ++ str ++ ")"
375 | otherwise = str
377-- Check whether a term has any holes in it - impure if so
379pureTerm :: TT n -> Bool
380pureTerm (App f a) = pureTerm f && pureTerm a
381pureTerm (Bind n b sc) = pureBinder b && pureTerm sc where
382 pureBinder (Hole _) = False
383 pureBinder (Guess _ _) = False
384 pureBinder (Let t v) = pureTerm t && pureTerm v
385 pureBinder t = pureTerm (binderTy t)
386pureTerm _ = True
388-- weaken a term by adding i to each de Bruijn index (i.e. lift it over i bindings)
390weakenTm :: Int -> TT n -> TT n
391weakenTm i t = wk i 0 t
392 where wk i min (V x) | x >= min = V (i + x)
393 wk i m (App f a) = App (wk i m f) (wk i m a)
394 wk i m (Bind x b sc) = Bind x (wkb i m b) (wk i (m + 1) sc)
395 wk i m t = t
396 wkb i m t = fmap (wk i m) t
398-- weaken an environment so that all the de Bruijn indices are correct according
399-- to the latest bound variable
401weakenEnv :: EnvTT n -> EnvTT n
402weakenEnv env = wk (length env - 1) env
403 where wk i [] = []
404 wk i ((n, b) : bs) = (n, weakenTmB i b) : wk (i - 1) bs
405 weakenTmB i (Let t v) = Let (weakenTm i t) (weakenTm i v)
406 weakenTmB i (Guess t v) = Guess (weakenTm i t) (weakenTm i v)
407 weakenTmB i t = t { binderTy = weakenTm i (binderTy t) }
409weakenTmEnv :: Int -> EnvTT n -> EnvTT n
410weakenTmEnv i = map (\ (n, b) -> (n, fmap (weakenTm i) b))
412orderPats :: Term -> Term
413orderPats tm = op [] tm
414 where
415 op ps (Bind n (PVar t) sc) = op ((n, t) : ps) sc
416 op ps sc = bindAll (map (\ (n, t) -> (n, PVar t)) (sortP ps)) sc
418 sortP ps = pick [] (reverse ps)
420 namesIn (P _ n _) = [n]
421 namesIn (Bind n b t) = nub $ nb b ++ (namesIn t \\ [n])
422 where nb (Let t v) = nub (namesIn t) ++ nub (namesIn v)
423 nb (Guess t v) = nub (namesIn t) ++ nub (namesIn v)
424 nb t = namesIn (binderTy t)
425 namesIn (App f a) = nub (namesIn f ++ namesIn a)
426 namesIn _ = []
428 pick acc [] = reverse acc
429 pick acc ((n, t) : ps) = pick (insert n t acc) ps
431 insert n t [] = [(n, t)]
432 insert n t ((n',t') : ps)
433 | n `elem` (namesIn t' ++ concatMap namesIn (map snd ps))
434 = (n', t') : insert n t ps
435 | otherwise = (n,t):(n',t'):ps