1******************************
2New Foreign Function Interface
3******************************
5.. sectionauthor:: Edwin Brady
7Ever since Idris has had multiple backends compiling to different
8target languages on potentially different platforms, we have had the
9problem that the foreign function interface (FFI) was written under
10the assumption of compiling to C. As a result, it has been hard to
11write generic code for multiple targets, or even to be sure that if
12code compiles that it will run on the expected target.
14As of 0.9.17, Idris will have a new foreign function interface (FFI)
15which is aware of multiple targets. Users who are working with the
16default code generator can happily continue writing programs as before
17with no changes, but if you are writing bindings for an external
18library, writing a back end, or working with a non-C back end, there
19are some things you will need to be aware of, which this page
22The ``IO'`` monad, and ``main``
23===============================
25The ``IO`` monad exists as before, but is now specific to the C
26backend (or, more precisely, any backend whose foreign function calls
27are compatible with C.) Additionally, there is now an ``IO'`` monad,
28which is parameterised over a FFI descriptor:
32 data IO' : (lang : FFI) -> Type -> Type
34The Prelude defines two FFI descriptors which are imported
35automatically, for C and JavaScript/Node, and defines ``IO`` to use
36the C FFI and ``JS_IO`` to use the JavaScript FFI:
47 JS_IO a = IO' FFI_JS a
49As before, the entry point to an Idris program is ``main``, but the
50type of ``main`` can now be any implementation of ``IO'``, e.g. the
51following are both valid:
58The FFI descriptor includes details about which types can be
59marshalled between the foreign language and Idris, and the "target" of
60a foreign function call (typically just a String representation of the
61function's name, but potentially something more complicated such as an
62external library file or even a URL).
67An FFI descriptor is a record containing a predicate which holds when
68a type can be marshalled, and the type of the target of a foreign
75 ffi_types : Type -> Type
82 ||| Supported C integer types
84 data C_IntTypes : Type -> Type where
85 C_IntChar : C_IntTypes Char
86 C_IntNative : C_IntTypes Int
87 C_IntBits8 : C_IntTypes Bits8
88 C_IntBits16 : C_IntTypes Bits16
89 C_IntBits32 : C_IntTypes Bits32
90 C_IntBits64 : C_IntTypes Bits64
92 ||| Supported C function types
94 data C_FnTypes : Type -> Type where
95 C_Fn : C_Types s -> C_FnTypes t -> C_FnTypes (s -> t)
96 C_FnIO : C_Types t -> C_FnTypes (IO' FFI_C t)
97 C_FnBase : C_Types t -> C_FnTypes t
99 ||| Supported C foreign types
101 data C_Types : Type -> Type where
102 C_Str : C_Types String
103 C_Float : C_Types Double
105 C_MPtr : C_Types ManagedPtr
107 C_Any : C_Types (Raw a)
108 C_FnT : C_FnTypes t -> C_Types (CFnPtr t)
109 C_IntT : C_IntTypes i -> C_Types i
111 ||| A descriptor for the C FFI. See the constructors of `C_Types`
112 ||| and `C_IntTypes` for the concrete types that are available.
116 FFI_C = MkFFI C_Types String String
121To call a foreign function, the ``foreign`` function is used. For
126 do_fopen : String -> String -> IO Ptr
128 = foreign FFI_C "fileOpen" (String -> String -> IO Ptr) f m
130The ``foreign`` function takes an FFI description, a function name (the
131type is given by the ``ffi_fn`` field of ``FFI_C`` here), and a function
132type, which gives the expected types of the remaining arguments. Here,
133we're calling an external function ``fileOpen`` which takes, in the C, a
134``char*`` file name, a ``char*`` mode, and returns a file pointer. It is
135the job of the C back end to convert Idris ``String`` to C ``char*``
138The argument types and return type given here must be present in the
139``fn_types`` predicate of the ``FFI_C`` description for the foreign
142**Note** The arguments to ``foreign`` *must* be known at compile time,
143because the foreign calls are generated statically. The ``%inline``
144directive on a function can be used to give hints to help this, for
145example a shorthand for calling external JavaScript functions:
150 jscall : (fname : String) -> (ty : Type) ->
151 {auto fty : FTy FFI_JS [] ty} -> ty
152 jscall fname ty = foreign FFI_JS fname ty
156It is possible to pass an Idris function to a C function taking a function
157pointer by using ``CFnPtr`` in the function type. The Idris function is passed
158to ``MkCFnPtr`` in the arguments. The example below shows declaring the C standard
159library function ``qsort`` which takes a pointer to a comparison function.
163 myComparer : Ptr -> Ptr -> Int
166 qsort : Ptr -> Int -> Int -> IO ()
167 qsort data elems elsize = foreign FFI_C "qsort"
168 (Ptr -> Int -> Int -> CFnPtr (Ptr -> Ptr -> Int) -> IO ())
169 data elems elsize (MkCFnPtr myComparer)
171There are a few limitations to callbacks in the C FFI. The foreign function can't
172take the function to make a callback of as an argument. This will give a
177 -- This does not work
178 example : (Int -> ()) -> IO ()
179 example f = foreign FFI_C "callbacker" (CFnPtr (Int -> ()) -> IO ()) f
181The other big limitation is that it doesn't support IO functions. Use
182``unsafePerformIO`` to wrap them (i.e. to make an IO function usable as a callback, change the return type
183from IOr to r, and change the = do to = unsafePerformIO $ do).
185There are two special function names:
186``%wrapper`` returns the function pointer that wraps an Idris function. This
187is useful if the function pointer isn't taken by a C function directly but
188should be inserted into a data structure. A foreign declaration using
189``%wrapper`` must return ``IO Ptr``.
193 -- this returns the C function pointer to a qsort comparer
194 example_wrapper : IO Ptr
195 example_wrapper = foreign FFI_C "%wrapper" (CFnPtr (Ptr -> Ptr -> Int) -> IO Ptr)
196 (MkCFnPtr myComparer)
198``%dynamic`` calls a C function pointer with some arguments. This is useful if
199a C function returns or data structure contains a C function pointer, for example
200structs of function pointers are common in object-oriented C such as in COM or the
201Linux kernel. The function type contains an extra ``Ptr`` at the start for the
202function pointer. ``%dynamic`` can be seen as a pseudo-function that calls the
203function in the first argument, passing the remaining arguments to it.
207 -- we have a pointer to a function with the signature int f(int), call it
208 example_dynamic : Ptr -> Int -> IO Int
209 example_dynamic fn x = foreign FFI_C "%dynamic" (Ptr -> Int -> IO Int) fn x
211If the foreign name is prefixed by a ``&``, it is treated as a pointer to the
212global variable with the following name. The type must be just ``IO Ptr``.
216 -- access the global variable errno
218 errno = foreign FFI_C "&errno" (IO Ptr)
220If the foreign name is prefixed by a ``#``, the name is pasted in literally. This is
221useful to access constants that are preprocessor definitions (like ``INT_MAX``).
225 %include C "limits.h"
227 -- access the preprocessor definition INT_MAX
229 intMax = foreign FFI_C "#INT_MAX" (IO Int)
234For more complicated interactions with C (such as reading and setting fields
235of a C struct), there is a module CFFI available in the contrib package.
240Idris has two heaps where objects can be allocated:
242+--------------------------------------+---------------------------------------+
244+======================================+=======================================+
245| Cheney-collected | Mark-and-sweep-collected |
246+--------------------------------------+---------------------------------------+
247| Garbage collections touches only | Garbage collection has to traverse |
248| live objects. | all registered items. |
249+--------------------------------------+---------------------------------------+
250| Ideal for FP-style rapid allocation | Ideal for C-style allocation of a few |
251| of lots of small short-lived pieces | big buffers. |
252| of memory, such as data constructors.| |
253+--------------------------------------+---------------------------------------+
254| Finalizers are impossible to support | Items have finalizers that are called |
255| reasonably. | on deallocation. |
256+--------------------------------------+---------------------------------------+
257| Data is copied all the time (when | Copying does not happen. |
258| collecting garbage, modifying data, | |
259| registering managed pointers, etc.) | |
260+--------------------------------------+---------------------------------------+
261| Contains objects of various types. | Contains C heap items: ``(void *)`` |
262| | pointers with finalizers. A finalizer |
263| | is a routine that deallocates the |
264| | resources associated with the item. |
265+--------------------------------------+---------------------------------------+
266| Fixed set of object types. | The data pointer may point |
267| | to anything, as long as the finalizer |
268| | cleans up correctly. |
269+--------------------------------------+---------------------------------------+
270| Not suitable for C resources and | Suitable for C resources and arbitrary|
271| arbitrary pointers. | pointers. |
272+--------------------------------------+---------------------------------------+
273| Values form a compact memory block. | Items are kept in a linked list. |
274+--------------------------------------+---------------------------------------+
275| Any Idris value, most notably | Items represented by the |
276| ``ManagedPtr``. | Idris type ``CData``. |
277+--------------------------------------+---------------------------------------+
278| Data of ``ManagedPtr`` allocated | Data allocated in C, pointer copied |
279| in C, buffer then copied into the FP | into the C heap. |
281+--------------------------------------+---------------------------------------+
282| Allocation and reallocation not | Allocated and reallocate freely in C, |
283| possible from C code (without having | registering the allocated items |
284| a reference to the VM). Everything | in the FFI. |
285| is copied instead. | |
286+--------------------------------------+---------------------------------------+
288The FP heap is the primary heap. It may contain values of type ``CData``,
289which are references to items in the C heap. A C heap item contains
290a ``(void *)`` pointer and the corresponding finalizer. Once a C heap item
291is no longer referenced from the FP heap, it is marked as unused and
292the next GC sweep will call its finalizer and deallocate it.
294There is no Idris interface for ``CData`` other than its type and FFI.
299* Although not enforced in code, ``CData`` is meant to be opaque
300 and non-RTS code (such as libraries or C bindings) should
301 access only its ``(void *)`` field called ``data``.
303* Feel free to mutate both the pointer ``data`` (eg. after calling ``realloc``)
304 and the memory it points to. However, keep in mind
305 that this must not break Idris's referential transparency.
307* **WARNING!** If you call ``cdata_allocate`` or ``cdata_manage``,
308 the resulting ``CData`` object *must* be returned from your
309 FFI function so that it is inserted in the C heap by the RTS.
310 Otherwise the memory will be leaked.
314 some_allocating_fun : Int -> IO CData
315 some_allocating_fun i = foreign FFI_C "some_allocating_fun" (Int -> IO CData) i
317 other_fun : CData -> Int -> IO Int
318 other_fun cd i = foreign FFI_C "other_fun" (CData -> Int -> IO Int) cd i
322 #include "idris_rts.h"
324 static void finalizer(void * data)
326 MyStruct * ptr = (MyStruct *) data;
327 free_something(ptr->something);
331 CData some_allocating_fun(int arg)
333 void * data = (void *) malloc(...);
335 return cdata_manage(data, finalizer);
338 int other_fun(CData cd, int arg)
340 int result = foo(cd->data);
347In order to write bindings to external libraries, the details of how
348``foreign`` works are unnecessary --- you simply need to know that
349``foreign`` takes an FFI descriptor, the function name, and its
350type. It is instructive to look a little deeper, however:
352The type of ``foreign`` is as follows:
356 foreign : (ffi : FFI)
357 -> (fname : ffi_fn f)
359 -> {auto fty : FTy ffi [] ty}
362The important argument here is the implicit ``fty``, which contains a
363proof (``FTy``) that the given type is valid according to the FFI
368 data FTy : FFI -> List Type -> Type -> Type where
369 FRet : ffi_types f t -> FTy f xs (IO' f t)
370 FFun : ffi_types f s -> FTy f (s :: xs) t -> FTy f xs (s -> t)
372Notice that this uses the ``ffi_types`` field of the FFI descriptor
373--- these arguments to ``FRet`` and ``FFun`` give explicit proofs that
374the type is valid in this FFI. For example, the above ``do_fopen``
375builds the following implicit proof as the ``fty`` argument to
380 FFun C_Str (FFun C_Str (FRet C_Ptr))
382Compiling foreign calls
383=======================
385(This section assumes some knowledge of the Idris internals.)
387When writing a back end, we now need to know how to compile
388``foreign``. We'll skip the details here of how a ``foreign`` call
389reaches the intermediate representation (the IR), though you can look
390in ``IO.idr`` in the ``prelude`` package to see a bit more detail ---
391a ``foreign`` call is implemented by the primitive function
392``mkForeignPrim``. The important part of the IR as defined in
393``Lang.hs`` is the following constructor:
398 | LForeign FDesc -- Function descriptor
399 FDesc -- Return type descriptor
402So, a ``foreign`` call appears in the IR as the ``LForeign``
403constructor, which takes a function descriptor (of a type given by the
404``ffi_fn`` field in the FFI descriptor), a return type descriptor
405(given by an application of ``FTy``), and a list of arguments with
406type descriptors (also given by an application of ``FTy``).
408An ``FDesc`` describes an application of a name to some arguments, and
409is really just a simplified subset of an ``LExp``:
413 data FDesc = FCon Name
418There are corresponding structures in the lower level IRs, such as the
419defunctionalised, simplified and bytecode forms.
421Our ``do_fopen`` example above arrives in the ``LExp`` form as:
425 LForeign (FStr "fileOpen") (FCon (sUN "C_Ptr"))
426 [(FCon (sUN "C_Str"), f), (FCon (sUN "C_Str"), m)]
428(Assuming that ``f`` and ``m`` stand for the ``LExp`` representations
429of the arguments.) This information should be enough for any back end
430to marshal the arguments and return value appropriately.
434 When processing ``FDesc``, be aware that there may be implicit
435 arguments, which have not been erased. For example, ``C_IntT`` has
436 an implicit argument ``i``, so will appear in an ``FDesc`` as
437 something of the form ``FApp (sUN "C_IntT") [i, t]`` where ``i`` is
438 the implicit argument (which can be ignored) and ``t`` is the
439 descriptor of the integer type. See ``CodegenC.hs``, specifically
440 the function ``toFType``, to see how this works in practice.
442JavaScript FFI descriptor
443=========================
445The JavaScript FFI descriptor is a little more complex, because the
446JavaScript FFI supports marshalling functions. It is defined as
452 data JsFn t = MkJsFn t
454 data JS_IntTypes : Type -> Type where
455 JS_IntChar : JS_IntTypes Char
456 JS_IntNative : JS_IntTypes Int
458 data JS_FnTypes : Type -> Type where
459 JS_Fn : JS_Types s -> JS_FnTypes t -> JS_FnTypes (s -> t)
460 JS_FnIO : JS_Types t -> JS_FnTypes (IO' l t)
461 JS_FnBase : JS_Types t -> JS_FnTypes t
463 data JS_Types : Type -> Type where
464 JS_Str : JS_Types String
465 JS_Float : JS_Types Double
466 JS_Ptr : JS_Types Ptr
467 JS_Unit : JS_Types ()
468 JS_FnT : JS_FnTypes a -> JS_Types (JsFn a)
469 JS_IntT : JS_IntTypes i -> JS_Types i
471The reason for wrapping function types in a ``JsFn`` is to help the
472proof search when building ``FTy``. We hope to improve proof search
473eventually, but for the moment it works much more reliably if the
474indices are disjoint! An example of using this appears in `IdrisScript
475<https://github.com/idris-hackers/IdrisScript>`__ when setting
480 setTimeout : (() -> JS_IO ()) -> (millis : Int) -> JS_IO Timeout
481 setTimeout f millis = do
482 timeout <- jscall "setTimeout(%0, %1)"
483 (JsFn (() -> JS_IO ()) -> Int -> JS_IO Ptr)
485 pure $ MkTimeout timeout
keysesc to close
- j k
- move down, up
- enter
- open
- esc
- back, or up a level
- 1 2 3 4
- readme, files, commits, refs
- /
- filter
- y
- copy the clone command
- c
- compare the chosen commit with another (or shift-click both)
- ?
- show or hide this list