git.iko.soy/Idris-dev
on d66da21 help sign in
Idris-dev/src/Idris/AbsSyntaxTree.hs
1439 lines 54 kB history raw
1{-# LANGUAGE MultiParamTypeClasses, FlexibleInstances, DeriveFunctor,
2 TypeSynonymInstances, PatternGuards #-}
4module Idris.AbsSyntaxTree where
6import Core.TT
7import Core.Evaluate
8import Core.Elaborate hiding (Tactic(..))
9import Core.Typecheck
10import IRTS.Lang
11import IRTS.CodegenCommon
12import Util.Pretty
13import Util.DynamicLinker
15import Idris.Colours
17import Paths_idris
19import System.Console.Haskeline
20import System.IO
22import Control.Monad.Trans.State.Strict
23import Control.Monad.Trans.Error
25import Data.List
26import Data.Char
27import Data.Either
28import Data.Word (Word)
30import Debug.Trace
32data IOption = IOption { opt_logLevel :: Int,
33 opt_typecase :: Bool,
34 opt_typeintype :: Bool,
35 opt_coverage :: Bool,
36 opt_showimp :: Bool, -- ^^ show implicits
37 opt_errContext :: Bool,
38 opt_repl :: Bool,
39 opt_verbose :: Bool,
40 opt_nobanner :: Bool,
41 opt_quiet :: Bool,
42 opt_codegen :: Codegen,
43 opt_outputTy :: OutputType,
44 opt_ibcsubdir :: FilePath,
45 opt_importdirs :: [FilePath],
46 opt_triple :: String,
47 opt_cpu :: String,
48 opt_optLevel :: Word,
49 opt_cmdline :: [Opt] -- remember whole command line
50 }
51 deriving (Show, Eq)
53defaultOpts = IOption { opt_logLevel = 0
54 , opt_typecase = False
55 , opt_typeintype = False
56 , opt_coverage = True
57 , opt_showimp = False
58 , opt_errContext = False
59 , opt_repl = True
60 , opt_verbose = True
61 , opt_nobanner = False
62 , opt_quiet = False
63 , opt_codegen = ViaC
64 , opt_outputTy = Executable
65 , opt_ibcsubdir = ""
66 , opt_importdirs = []
67 , opt_triple = ""
68 , opt_cpu = ""
69 , opt_optLevel = 2
70 , opt_cmdline = []
71 }
73data LanguageExt = TypeProviders | ErrorReflection deriving (Show, Eq, Read, Ord)
75-- | The output mode in use
76data OutputMode = RawOutput | IdeSlave Integer deriving Show
78-- TODO: Add 'module data' to IState, which can be saved out and reloaded quickly (i.e
79-- without typechecking).
80-- This will include all the functions and data declarations, plus fixity declarations
81-- and syntax macros.
83-- | The global state used in the Idris monad
84data IState = IState {
85 tt_ctxt :: Context, -- ^ All the currently defined names and their terms
86 idris_constraints :: [(UConstraint, FC)],
87 -- ^ A list of universe constraints and their corresponding source locations
88 idris_infixes :: [FixDecl], -- ^ Currently defined infix operators
89 idris_implicits :: Ctxt [PArg],
90 idris_statics :: Ctxt [Bool],
91 idris_classes :: Ctxt ClassInfo,
92 idris_dsls :: Ctxt DSL,
93 idris_optimisation :: Ctxt OptInfo,
94 idris_datatypes :: Ctxt TypeInfo,
95 idris_namehints :: Ctxt [Name],
96 idris_patdefs :: Ctxt ([([Name], Term, Term)], [PTerm]), -- not exported
97 -- ^ list of lhs/rhs, and a list of missing clauses
98 idris_flags :: Ctxt [FnOpt],
99 idris_callgraph :: Ctxt CGInfo, -- name, args used in each pos
100 idris_calledgraph :: Ctxt [Name],
101 idris_docstrings :: Ctxt String,
102 idris_totcheck :: [(FC, Name)], -- names to check totality on
103 idris_defertotcheck :: [(FC, Name)], -- names to check at the end
104 idris_options :: IOption,
105 idris_name :: Int,
106 idris_lineapps :: [((FilePath, Int), PTerm)],
107 -- ^ Full application LHS on source line
108 idris_metavars :: [(Name, (Maybe Name, Int, Bool))], -- ^ The currently defined but not proven metavariables
109 idris_coercions :: [Name],
110 idris_transforms :: [(Term, Term)],
111 syntax_rules :: [Syntax],
112 syntax_keywords :: [String],
113 imported :: [FilePath], -- ^ The imported modules
114 idris_scprims :: [(Name, (Int, PrimFn))],
115 idris_objs :: [(Codegen, FilePath)],
116 idris_libs :: [(Codegen, String)],
117 idris_cgflags :: [(Codegen, String)],
118 idris_hdrs :: [(Codegen, String)],
119 proof_list :: [(Name, [String])],
120 errLine :: Maybe Int,
121 lastParse :: Maybe Name,
122 indent_stack :: [Int],
123 brace_stack :: [Maybe Int],
124 hide_list :: [(Name, Maybe Accessibility)],
125 default_access :: Accessibility,
126 default_total :: Bool,
127 ibc_write :: [IBCWrite],
128 compiled_so :: Maybe String,
129 idris_dynamic_libs :: [DynamicLib],
130 idris_language_extensions :: [LanguageExt],
131 idris_outputmode :: OutputMode,
132 idris_colourRepl :: Bool,
133 idris_colourTheme :: ColourTheme,
134 idris_outh :: Handle
135 }
137data SizeChange = Smaller | Same | Bigger | Unknown
138 deriving (Show, Eq)
139{-!
140deriving instance Binary SizeChange
141deriving instance NFData SizeChange
142!-}
144type SCGEntry = (Name, [Maybe (Int, SizeChange)])
146data CGInfo = CGInfo { argsdef :: [Name],
147 calls :: [(Name, [[Name]])],
148 scg :: [SCGEntry],
149 argsused :: [Name],
150 unusedpos :: [Int] }
151 deriving Show
152{-!
153deriving instance Binary CGInfo
154deriving instance NFData CGInfo
155!-}
157primDefs = [UN "unsafePerformPrimIO",
158 UN "mkLazyForeignPrim",
159 UN "mkForeignPrim",
160 UN "FalseElim"]
162-- information that needs writing for the current module's .ibc file
163data IBCWrite = IBCFix FixDecl
164 | IBCImp Name
165 | IBCStatic Name
166 | IBCClass Name
167 | IBCInstance Bool Name Name
168 | IBCDSL Name
169 | IBCData Name
170 | IBCOpt Name
171 | IBCSyntax Syntax
172 | IBCKeyword String
173 | IBCImport FilePath
174 | IBCObj Codegen FilePath
175 | IBCLib Codegen String
176 | IBCCGFlag Codegen String
177 | IBCDyLib String
178 | IBCHeader Codegen String
179 | IBCAccess Name Accessibility
180 | IBCTotal Name Totality
181 | IBCFlags Name [FnOpt]
182 | IBCTrans (Term, Term)
183 | IBCCG Name
184 | IBCDoc Name
185 | IBCCoercion Name
186 | IBCDef Name -- i.e. main context
187 | IBCNameHint (Name, Name)
188 | IBCLineApp FilePath Int PTerm
189 deriving Show
191idrisInit = IState initContext [] [] emptyContext emptyContext emptyContext
192 emptyContext emptyContext emptyContext emptyContext
193 emptyContext emptyContext emptyContext emptyContext
194 emptyContext
195 [] [] defaultOpts 6 [] [] [] [] [] [] [] [] [] [] [] []
196 [] Nothing Nothing [] [] [] Hidden False [] Nothing [] [] RawOutput
197 True defaultTheme stdout
199-- | The monad for the main REPL - reading and processing files and updating
200-- global state (hence the IO inner monad).
201--type Idris = WriterT [Either String (IO ())] (State IState a))
202type Idris = StateT IState (ErrorT Err IO)
204-- Commands in the REPL
206data Codegen = ViaC
207 | ViaJava
208 | ViaNode
209 | ViaJavaScript
210 | ViaLLVM
211 | Bytecode
212 deriving (Show, Eq)
214-- | REPL commands
215data Command = Quit
216 | Help
217 | Eval PTerm
218 | Check PTerm
219 | DocStr Name
220 | TotCheck Name
221 | Reload
222 | Load FilePath
223 | ChangeDirectory FilePath
224 | ModImport String
225 | Edit
226 | Compile Codegen String
227 | Execute
228 | ExecVal PTerm
229 | Metavars
230 | Prove Name
231 | AddProof (Maybe Name)
232 | RmProof Name
233 | ShowProof Name
234 | Proofs
235 | Universes
236 | LogLvl Int
237 | Spec PTerm
238 | HNF PTerm
239 | TestInline PTerm
240 | Defn Name
241 | Info Name
242 | Missing Name
243 | DynamicLink FilePath
244 | ListDynamic
245 | Pattelab PTerm
246 | DebugInfo Name
247 | Search PTerm
248 | CaseSplitAt Bool Int Name
249 | AddClauseFrom Bool Int Name
250 | AddProofClauseFrom Bool Int Name
251 | AddMissing Bool Int Name
252 | MakeWith Bool Int Name
253 | DoProofSearch Bool Int Name [Name]
254 | SetOpt Opt
255 | UnsetOpt Opt
256 | NOP
257 | SetColour ColourType IdrisColour
258 | ColourOn
259 | ColourOff
261data Opt = Filename String
262 | Ver
263 | Usage
264 | Quiet
265 | NoBanner
266 | ColourREPL Bool
267 | Ideslave
268 | ShowLibs
269 | ShowLibdir
270 | ShowIncs
271 | NoBasePkgs
272 | NoPrelude
273 | NoBuiltins -- only for the really primitive stuff!
274 | NoREPL
275 | OLogging Int
276 | Output String
277 | TypeCase
278 | TypeInType
279 | DefaultTotal
280 | DefaultPartial
281 | WarnPartial
282 | NoCoverage
283 | ErrContext
284 | ShowImpl
285 | Verbose
286 | IBCSubDir String
287 | ImportDir String
288 | PkgBuild String
289 | PkgInstall String
290 | PkgClean String
291 | WarnOnly
292 | Pkg String
293 | BCAsm String
294 | DumpDefun String
295 | DumpCases String
296 | UseCodegen Codegen
297 | OutputTy OutputType
298 | Extension LanguageExt
299 | InterpretScript String
300 | TargetTriple String
301 | TargetCPU String
302 | OptLevel Word
303 | Client String
304 deriving (Show, Eq)
306-- Parsed declarations
308data Fixity = Infixl { prec :: Int }
309 | Infixr { prec :: Int }
310 | InfixN { prec :: Int }
311 | PrefixN { prec :: Int }
312 deriving Eq
313{-!
314deriving instance Binary Fixity
315deriving instance NFData Fixity
316!-}
318instance Show Fixity where
319 show (Infixl i) = "infixl " ++ show i
320 show (Infixr i) = "infixr " ++ show i
321 show (InfixN i) = "infix " ++ show i
322 show (PrefixN i) = "prefix " ++ show i
324data FixDecl = Fix Fixity String
325 deriving Eq
327instance Show FixDecl where
328 show (Fix f s) = show f ++ " " ++ s
330{-!
331deriving instance Binary FixDecl
332deriving instance NFData FixDecl
333!-}
335instance Ord FixDecl where
336 compare (Fix x _) (Fix y _) = compare (prec x) (prec y)
339data Static = Static | Dynamic
340 deriving (Show, Eq)
341{-!
342deriving instance Binary Static
343deriving instance NFData Static
344!-}
346-- Mark bindings with their explicitness, and laziness
347data Plicity = Imp { plazy :: Bool,
348 pstatic :: Static,
349 pdocstr :: String,
350 pparam :: Bool }
351 | Exp { plazy :: Bool,
352 pstatic :: Static,
353 pdocstr :: String,
354 pparam :: Bool }
355 | Constraint { plazy :: Bool,
356 pstatic :: Static,
357 pdocstr :: String }
358 | TacImp { plazy :: Bool,
359 pstatic :: Static,
360 pscript :: PTerm,
361 pdocstr :: String }
362 deriving (Show, Eq)
364{-!
365deriving instance Binary Plicity
366deriving instance NFData Plicity
367!-}
369impl = Imp False Dynamic "" False
370expl = Exp False Dynamic "" False
371expl_param = Exp False Dynamic "" True
372constraint = Constraint False Dynamic ""
373tacimpl t = TacImp False Dynamic t ""
375data FnOpt = Inlinable -- always evaluate when simplifying
376 | TotalFn | PartialFn
377 | Coinductive | AssertTotal
378 | Dictionary -- type class dictionary, eval only when
379 -- a function argument, and further evaluation resutls
380 | Implicit -- implicit coercion
381 | CExport String -- export, with a C name
382 | Reflection -- a reflecting function, compile-time only
383 | Specialise [(Name, Maybe Int)] -- specialise it, freeze these names
384 deriving (Show, Eq)
385{-!
386deriving instance Binary FnOpt
387deriving instance NFData FnOpt
388!-}
390type FnOpts = [FnOpt]
392inlinable :: FnOpts -> Bool
393inlinable = elem Inlinable
395dictionary :: FnOpts -> Bool
396dictionary = elem Dictionary
399-- | Data declaration options
400data DataOpt = Codata -- Set if the the data-type is coinductive
401 | DefaultEliminator -- Set if an eliminator should be generated for data type
402 deriving (Show, Eq)
404type DataOpts = [DataOpt]
406-- | Top-level declarations such as compiler directives, definitions,
407-- datatypes and typeclasses.
408data PDecl' t
409 = PFix FC Fixity [String] -- ^ Fixity declaration
410 | PTy String SyntaxInfo FC FnOpts Name t -- ^ Type declaration
411 | PPostulate String SyntaxInfo FC FnOpts Name t -- ^ Postulate
412 | PClauses FC FnOpts Name [PClause' t] -- ^ Pattern clause
413 | PCAF FC Name t -- ^ Top level constant
414 | PData String SyntaxInfo FC DataOpts (PData' t) -- ^ Data declaration.
415 | PParams FC [(Name, t)] [PDecl' t] -- ^ Params block
416 | PNamespace String [PDecl' t] -- ^ New namespace
417 | PRecord String SyntaxInfo FC Name t String Name t -- ^ Record declaration
418 | PClass String SyntaxInfo FC
419 [t] -- constraints
420 Name
421 [(Name, t)] -- parameters
422 [PDecl' t] -- declarations
423 -- ^ Type class: arguments are documentation, syntax info, source location, constraints,
424 -- class name, parameters, method declarations
425 | PInstance SyntaxInfo FC [t] -- constraints
426 Name -- class
427 [t] -- parameters
428 t -- full instance type
429 (Maybe Name) -- explicit name
430 [PDecl' t]
431 -- ^ Instance declaration: arguments are syntax info, source location, constraints,
432 -- class name, parameters, full instance type, optional explicit name, and definitions
433 | PDSL Name (DSL' t) -- ^ DSL declaration
434 | PSyntax FC Syntax -- ^ Syntax definition
435 | PMutual FC [PDecl' t] -- ^ Mutual block
436 | PDirective (Idris ()) -- ^ Compiler directive. The parser inserts the corresponding action in the Idris monad.
437 | PProvider SyntaxInfo FC Name t t -- ^ Type provider. The first t is the type, the second is the term
438 | PTransform FC Bool t t -- ^ Source-to-source transformation rule. If
439 -- bool is True, lhs and rhs must be convertible
440 deriving Functor
441{-!
442deriving instance Binary PDecl'
443deriving instance NFData PDecl'
444!-}
446-- For elaborator state
447type ElabD a = Elab' [PDecl] a
449-- | One clause of a top-level definition. Term arguments to constructors are:
450--
451-- 1. The whole application (missing for PClauseR and PWithR because they're within a "with" clause)
452--
453-- 2. The list of extra 'with' patterns
454--
455-- 3. The right-hand side
456--
457-- 4. The where block (PDecl' t)
459data PClause' t = PClause FC Name t [t] t [PDecl' t] -- ^ A normal top-level definition.
460 | PWith FC Name t [t] t [PDecl' t]
461 | PClauseR FC [t] t [PDecl' t]
462 | PWithR FC [t] t [PDecl' t]
463 deriving Functor
464{-!
465deriving instance Binary PClause'
466deriving instance NFData PClause'
467!-}
469-- | Data declaration
470data PData' t = PDatadecl { d_name :: Name, -- ^ The name of the datatype
471 d_tcon :: t, -- ^ Type constructor
472 d_cons :: [(String, Name, t, FC)] -- ^ Constructors
473 }
474 -- ^ Data declaration
475 | PLaterdecl { d_name :: Name, d_tcon :: t }
476 -- ^ "Placeholder" for data whose constructors are defined later
477 deriving Functor
478{-!
479deriving instance Binary PData'
480deriving instance NFData PData'
481!-}
483-- Handy to get a free function for applying PTerm -> PTerm functions
484-- across a program, by deriving Functor
486type PDecl = PDecl' PTerm
487type PData = PData' PTerm
488type PClause = PClause' PTerm
490-- get all the names declared in a decl
492declared :: PDecl -> [Name]
493declared (PFix _ _ _) = []
494declared (PTy _ _ _ _ n t) = [n]
495declared (PPostulate _ _ _ _ n t) = [n]
496declared (PClauses _ _ n _) = [] -- not a declaration
497declared (PCAF _ n _) = [n]
498declared (PData _ _ _ _ (PDatadecl n _ ts)) = n : map fstt ts
499 where fstt (_, a, _, _) = a
500declared (PData _ _ _ _ (PLaterdecl n _)) = [n]
501declared (PParams _ _ ds) = concatMap declared ds
502declared (PNamespace _ ds) = concatMap declared ds
503declared (PRecord _ _ _ n _ _ c _) = [n, c]
504declared (PClass _ _ _ _ n _ ms) = n : concatMap declared ms
505declared (PInstance _ _ _ _ _ _ _ _) = []
506declared (PDSL n _) = [n]
507declared (PSyntax _ _) = []
508declared (PMutual _ ds) = concatMap declared ds
509declared (PDirective _) = []
511-- get the names declared, not counting nested parameter blocks
512tldeclared :: PDecl -> [Name]
513tldeclared (PFix _ _ _) = []
514tldeclared (PTy _ _ _ _ n t) = [n]
515tldeclared (PPostulate _ _ _ _ n t) = [n]
516tldeclared (PClauses _ _ n _) = [] -- not a declaration
517tldeclared (PRecord _ _ _ n _ _ c _) = [n, c]
518tldeclared (PData _ _ _ _ (PDatadecl n _ ts)) = n : map fstt ts
519 where fstt (_, a, _, _) = a
520tldeclared (PParams _ _ ds) = []
521tldeclared (PMutual _ ds) = concatMap tldeclared ds
522tldeclared (PNamespace _ ds) = concatMap tldeclared ds
523tldeclared (PClass _ _ _ _ n _ ms) = concatMap tldeclared ms
524tldeclared (PInstance _ _ _ _ _ _ _ _) = []
525tldeclared _ = []
527defined :: PDecl -> [Name]
528defined (PFix _ _ _) = []
529defined (PTy _ _ _ _ n t) = []
530defined (PPostulate _ _ _ _ n t) = []
531defined (PClauses _ _ n _) = [n] -- not a declaration
532defined (PCAF _ n _) = [n]
533defined (PData _ _ _ _ (PDatadecl n _ ts)) = n : map fstt ts
534 where fstt (_, a, _, _) = a
535defined (PData _ _ _ _ (PLaterdecl n _)) = []
536defined (PParams _ _ ds) = concatMap defined ds
537defined (PNamespace _ ds) = concatMap defined ds
538defined (PRecord _ _ _ n _ _ c _) = [n, c]
539defined (PClass _ _ _ _ n _ ms) = n : concatMap defined ms
540defined (PInstance _ _ _ _ _ _ _ _) = []
541defined (PDSL n _) = [n]
542defined (PSyntax _ _) = []
543defined (PMutual _ ds) = concatMap defined ds
544defined (PDirective _) = []
545--defined _ = []
547updateN :: [(Name, Name)] -> Name -> Name
548updateN ns n | Just n' <- lookup n ns = n'
549updateN _ n = n
551updateNs :: [(Name, Name)] -> PTerm -> PTerm
552updateNs [] t = t
553updateNs ns t = mapPT updateRef t
554 where updateRef (PRef fc f) = PRef fc (updateN ns f)
555 updateRef t = t
557-- updateDNs :: [(Name, Name)] -> PDecl -> PDecl
558-- updateDNs [] t = t
559-- updateDNs ns (PTy s f n t) | Just n' <- lookup n ns = PTy s f n' t
560-- updateDNs ns (PClauses f n c) | Just n' <- lookup n ns = PClauses f n' (map updateCNs c)
561-- where updateCNs ns (PClause n l ts r ds)
562-- = PClause (updateN ns n) (fmap (updateNs ns) l)
563-- (map (fmap (updateNs ns)) ts)
564-- (fmap (updateNs ns) r)
565-- (map (updateDNs ns) ds)
566-- updateDNs ns c = c
568-- | High level language terms
569data PTerm = PQuote Raw
570 | PRef FC Name
571 | PInferRef FC Name -- ^ A name to be defined later
572 | PPatvar FC Name
573 | PLam Name PTerm PTerm
574 | PPi Plicity Name PTerm PTerm
575 | PLet Name PTerm PTerm PTerm
576 | PTyped PTerm PTerm -- ^ Term with explicit type
577 | PApp FC PTerm [PArg]
578 | PAppBind FC PTerm [PArg] -- ^ implicitly bound application
579 | PMatchApp FC Name -- ^ Make an application by type matching
580 | PCase FC PTerm [(PTerm, PTerm)]
581 | PTrue FC
582 | PFalse FC
583 | PRefl FC PTerm
584 | PResolveTC FC
585 | PEq FC PTerm PTerm
586 | PRewrite FC PTerm PTerm (Maybe PTerm)
587 | PPair FC PTerm PTerm
588 | PDPair FC PTerm PTerm PTerm
589 | PAlternative Bool [PTerm] -- True if only one may work
590 | PHidden PTerm -- ^ Irrelevant or hidden pattern
591 | PType
592 | PGoal FC PTerm Name PTerm
593 | PConstant Const
594 | Placeholder
595 | PDoBlock [PDo]
596 | PIdiom FC PTerm
597 | PReturn FC
598 | PMetavar Name
599 | PProof [PTactic] -- ^ Proof script
600 | PTactics [PTactic] -- ^ As PProof, but no auto solving
601 | PElabError Err -- ^ Error to report on elaboration
602 | PImpossible -- ^ Special case for declaring when an LHS can't typecheck
603 | PCoerced PTerm -- ^ To mark a coerced argument, so as not to coerce twice
604 | PUnifyLog PTerm -- ^ dump a trace of unifications when building term
605 | PNoImplicits PTerm -- ^ never run implicit converions on the term
606 deriving Eq
609{-!
610deriving instance Binary PTerm
611deriving instance NFData PTerm
612!-}
614mapPT :: (PTerm -> PTerm) -> PTerm -> PTerm
615mapPT f t = f (mpt t) where
616 mpt (PLam n t s) = PLam n (mapPT f t) (mapPT f s)
617 mpt (PPi p n t s) = PPi p n (mapPT f t) (mapPT f s)
618 mpt (PLet n ty v s) = PLet n (mapPT f ty) (mapPT f v) (mapPT f s)
619 mpt (PRewrite fc t s g) = PRewrite fc (mapPT f t) (mapPT f s)
620 (fmap (mapPT f) g)
621 mpt (PApp fc t as) = PApp fc (mapPT f t) (map (fmap (mapPT f)) as)
622 mpt (PAppBind fc t as) = PAppBind fc (mapPT f t) (map (fmap (mapPT f)) as)
623 mpt (PCase fc c os) = PCase fc (mapPT f c) (map (pmap (mapPT f)) os)
624 mpt (PEq fc l r) = PEq fc (mapPT f l) (mapPT f r)
625 mpt (PTyped l r) = PTyped (mapPT f l) (mapPT f r)
626 mpt (PPair fc l r) = PPair fc (mapPT f l) (mapPT f r)
627 mpt (PDPair fc l t r) = PDPair fc (mapPT f l) (mapPT f t) (mapPT f r)
628 mpt (PAlternative a as) = PAlternative a (map (mapPT f) as)
629 mpt (PHidden t) = PHidden (mapPT f t)
630 mpt (PDoBlock ds) = PDoBlock (map (fmap (mapPT f)) ds)
631 mpt (PProof ts) = PProof (map (fmap (mapPT f)) ts)
632 mpt (PTactics ts) = PTactics (map (fmap (mapPT f)) ts)
633 mpt (PUnifyLog tm) = PUnifyLog (mapPT f tm)
634 mpt (PNoImplicits tm) = PNoImplicits (mapPT f tm)
635 mpt (PGoal fc r n sc) = PGoal fc (mapPT f r) n (mapPT f sc)
636 mpt x = x
639data PTactic' t = Intro [Name] | Intros | Focus Name
640 | Refine Name [Bool] | Rewrite t
641 | Equiv t
642 | MatchRefine Name
643 | LetTac Name t | LetTacTy Name t t
644 | Exact t | Compute | Trivial
645 | ProofSearch (Maybe Name) Name [Name]
646 | Solve
647 | Attack
648 | ProofState | ProofTerm | Undo
649 | Try (PTactic' t) (PTactic' t)
650 | TSeq (PTactic' t) (PTactic' t)
651 | ApplyTactic t -- see Language.Reflection module
652 | Reflect t
653 | Fill t
654 | GoalType String (PTactic' t)
655 | Qed | Abandon
656 deriving (Show, Eq, Functor)
657{-!
658deriving instance Binary PTactic'
659deriving instance NFData PTactic'
660!-}
662instance Sized a => Sized (PTactic' a) where
663 size (Intro nms) = 1 + size nms
664 size Intros = 1
665 size (Focus nm) = 1 + size nm
666 size (Refine nm bs) = 1 + size nm + length bs
667 size (Rewrite t) = 1 + size t
668 size (LetTac nm t) = 1 + size nm + size t
669 size (Exact t) = 1 + size t
670 size Compute = 1
671 size Trivial = 1
672 size Solve = 1
673 size Attack = 1
674 size ProofState = 1
675 size ProofTerm = 1
676 size Undo = 1
677 size (Try l r) = 1 + size l + size r
678 size (TSeq l r) = 1 + size l + size r
679 size (ApplyTactic t) = 1 + size t
680 size (Reflect t) = 1 + size t
681 size (Fill t) = 1 + size t
682 size Qed = 1
683 size Abandon = 1
685type PTactic = PTactic' PTerm
687data PDo' t = DoExp FC t
688 | DoBind FC Name t
689 | DoBindP FC t t
690 | DoLet FC Name t t
691 | DoLetP FC t t
692 deriving (Eq, Functor)
693{-!
694deriving instance Binary PDo'
695deriving instance NFData PDo'
696!-}
698instance Sized a => Sized (PDo' a) where
699 size (DoExp fc t) = 1 + size fc + size t
700 size (DoBind fc nm t) = 1 + size fc + size nm + size t
701 size (DoBindP fc l r) = 1 + size fc + size l + size r
702 size (DoLet fc nm l r) = 1 + size fc + size nm + size l + size r
703 size (DoLetP fc l r) = 1 + size fc + size l + size r
705type PDo = PDo' PTerm
707-- The priority gives a hint as to elaboration order. Best to elaborate
708-- things early which will help give a more concrete type to other
709-- variables, e.g. a before (interpTy a).
711data PArg' t = PImp { priority :: Int,
712 machine_inf :: Bool, -- true if the machine inferred it
713 lazyarg :: Bool, pname :: Name, getTm :: t,
714 pargdoc :: String }
715 | PExp { priority :: Int,
716 lazyarg :: Bool, getTm :: t,
717 pargdoc :: String }
718 | PConstraint { priority :: Int,
719 lazyarg :: Bool, getTm :: t,
720 pargdoc :: String }
721 | PTacImplicit { priority :: Int,
722 lazyarg :: Bool, pname :: Name,
723 getScript :: t,
724 getTm :: t,
725 pargdoc :: String }
726 deriving (Show, Eq, Functor)
728instance Sized a => Sized (PArg' a) where
729 size (PImp p _ l nm trm _) = 1 + size nm + size trm
730 size (PExp p l trm _) = 1 + size trm
731 size (PConstraint p l trm _) = 1 + size trm
732 size (PTacImplicit p l nm scr trm _) = 1 + size nm + size scr + size trm
734{-!
735deriving instance Binary PArg'
736deriving instance NFData PArg'
737!-}
739pimp n t mach = PImp 1 mach True n t ""
740pexp t = PExp 1 False t ""
741pconst t = PConstraint 1 False t ""
742ptacimp n s t = PTacImplicit 0 True n s t ""
744type PArg = PArg' PTerm
746-- Type class data
748data ClassInfo = CI { instanceName :: Name,
749 class_methods :: [(Name, (FnOpts, PTerm))],
750 class_defaults :: [(Name, (Name, PDecl))], -- method name -> default impl
751 class_params :: [Name],
752 class_instances :: [Name] }
753 deriving Show
754{-!
755deriving instance Binary ClassInfo
756deriving instance NFData ClassInfo
757!-}
759data OptInfo = Optimise { collapsible :: Bool,
760 isnewtype :: Bool,
761 forceable :: [Int], -- argument positions
762 recursive :: [Int] }
763 deriving Show
764{-!
765deriving instance Binary OptInfo
766deriving instance NFData OptInfo
767!-}
770data TypeInfo = TI { con_names :: [Name],
771 codata :: Bool,
772 param_pos :: [Int] }
773 deriving Show
774{-!
775deriving instance Binary TypeInfo
776deriving instance NFData TypeInfo
777!-}
779-- Syntactic sugar info
781data DSL' t = DSL { dsl_bind :: t,
782 dsl_return :: t,
783 dsl_apply :: t,
784 dsl_pure :: t,
785 dsl_var :: Maybe t,
786 index_first :: Maybe t,
787 index_next :: Maybe t,
788 dsl_lambda :: Maybe t,
789 dsl_let :: Maybe t
790 }
791 deriving (Show, Functor)
792{-!
793deriving instance Binary DSL'
794deriving instance NFData DSL'
795!-}
797type DSL = DSL' PTerm
799data SynContext = PatternSyntax | TermSyntax | AnySyntax
800 deriving Show
801{-!
802deriving instance Binary SynContext
803deriving instance NFData SynContext
804!-}
806data Syntax = Rule [SSymbol] PTerm SynContext
807 deriving Show
808{-!
809deriving instance Binary Syntax
810deriving instance NFData Syntax
811!-}
813data SSymbol = Keyword Name
814 | Symbol String
815 | Binding Name
816 | Expr Name
817 | SimpleExpr Name
818 deriving Show
819{-!
820deriving instance Binary SSymbol
821deriving instance NFData SSymbol
822!-}
824initDSL = DSL (PRef f (UN ">>="))
825 (PRef f (UN "return"))
826 (PRef f (UN "<$>"))
827 (PRef f (UN "pure"))
828 Nothing
829 Nothing
830 Nothing
831 Nothing
832 Nothing
833 where f = fileFC "(builtin)"
835data Using = UImplicit Name PTerm
836 | UConstraint Name [Name]
837 deriving (Show, Eq)
838{-!
839deriving instance Binary Using
840deriving instance NFData Using
841!-}
843data SyntaxInfo = Syn { using :: [Using],
844 syn_params :: [(Name, PTerm)],
845 syn_namespace :: [String],
846 no_imp :: [Name],
847 decoration :: Name -> Name,
848 inPattern :: Bool,
849 implicitAllowed :: Bool,
850 dsl_info :: DSL }
851 deriving Show
852{-!
853deriving instance NFData SyntaxInfo
854deriving instance Binary SyntaxInfo
855!-}
857defaultSyntax = Syn [] [] [] [] id False False initDSL
859expandNS :: SyntaxInfo -> Name -> Name
860expandNS syn n@(NS _ _) = n
861expandNS syn n = case syn_namespace syn of
862 [] -> n
863 xs -> NS n xs
866--- Pretty printing declarations and terms
868instance Show PTerm where
869 show tm = showImp Nothing False False tm
871instance Pretty PTerm where
872 pretty = prettyImp False
874instance Show PDecl where
875 show d = showDeclImp False d
877instance Show PClause where
878 show c = showCImp True c
880instance Show PData where
881 show d = showDImp False d
883showDecls :: Bool -> [PDecl] -> String
884showDecls _ [] = ""
885showDecls i (d:ds) = showDeclImp i d ++ "\n" ++ showDecls i ds
887showDeclImp _ (PFix _ f ops) = show f ++ " " ++ showSep ", " ops
888showDeclImp i (PTy _ _ _ _ n t) = "tydecl " ++ showCG n ++ " : " ++ showImp Nothing i False t
889showDeclImp i (PClauses _ _ n cs) = "pat " ++ showCG n ++ "\t" ++ showSep "\n\t" (map (showCImp i) cs)
890showDeclImp _ (PData _ _ _ _ d) = showDImp True d
891showDeclImp i (PParams _ ns ps) = "params {" ++ show ns ++ "\n" ++ showDecls i ps ++ "}\n"
892showDeclImp i (PNamespace n ps) = "namespace {" ++ n ++ "\n" ++ showDecls i ps ++ "}\n"
893showDeclImp _ (PSyntax _ syn) = "syntax " ++ show syn
894showDeclImp i (PClass _ _ _ cs n ps ds)
895 = "class " ++ show cs ++ " " ++ show n ++ " " ++ show ps ++ "\n" ++ showDecls i ds
896showDeclImp i (PInstance _ _ cs n _ t _ ds)
897 = "instance " ++ show cs ++ " " ++ show n ++ " " ++ show t ++ "\n" ++ showDecls i ds
898showDeclImp _ _ = "..."
899-- showDeclImp (PImport i) = "import " ++ i
902showCImp :: Bool -> PClause -> String
903showCImp impl (PClause _ n l ws r w)
904 = showImp Nothing impl False l ++ showWs ws ++ " = " ++ showImp Nothing impl False r
905 ++ " where " ++ show w
906 where
907 showWs [] = ""
908 showWs (x : xs) = " | " ++ showImp Nothing impl False x ++ showWs xs
909showCImp impl (PWith _ n l ws r w)
910 = showImp Nothing impl False l ++ showWs ws ++ " with " ++ showImp Nothing impl False r
911 ++ " { " ++ show w ++ " } "
912 where
913 showWs [] = ""
914 showWs (x : xs) = " | " ++ showImp Nothing impl False x ++ showWs xs
917showDImp :: Bool -> PData -> String
918showDImp impl (PDatadecl n ty cons)
919 = "data " ++ show n ++ " : " ++ showImp Nothing impl False ty ++ " where\n\t"
920 ++ showSep "\n\t| "
921 (map (\ (_, n, t, _) -> show n ++ " : " ++ showImp Nothing impl False t) cons)
923getImps :: [PArg] -> [(Name, PTerm)]
924getImps [] = []
925getImps (PImp _ _ _ n tm _ : xs) = (n, tm) : getImps xs
926getImps (_ : xs) = getImps xs
928getExps :: [PArg] -> [PTerm]
929getExps [] = []
930getExps (PExp _ _ tm _ : xs) = tm : getExps xs
931getExps (_ : xs) = getExps xs
933getConsts :: [PArg] -> [PTerm]
934getConsts [] = []
935getConsts (PConstraint _ _ tm _ : xs) = tm : getConsts xs
936getConsts (_ : xs) = getConsts xs
938getAll :: [PArg] -> [PTerm]
939getAll = map getTm
941-- | Pretty-print a high-level Idris term
942prettyImp :: Bool -- ^^ whether to show implicits
943 -> PTerm -- ^^ the term to pretty-print
944 -> Doc
945prettyImp impl = prettySe 10
946 where
947 prettySe p (PQuote r) =
948 if size r > breakingSize then
949 text "![" $$ pretty r <> text "]"
950 else
951 text "![" <> pretty r <> text "]"
952 prettySe p (PPatvar fc n) = pretty n
953 prettySe p (PRef fc n) =
954 if impl then
955 pretty n
956 else
957 prettyBasic n
958 where
959 prettyBasic n@(UN _) = pretty n
960 prettyBasic (MN _ s) = text s
961 prettyBasic (NS n s) = (foldr (<>) empty (intersperse (text ".") (map text $ reverse s))) <> prettyBasic n
962 prettyBasic (SN sn) = text (show sn)
963 prettySe p (PLam n ty sc) =
964 bracket p 2 $
965 if size sc > breakingSize then
966 text "λ" <> pretty n <+> text "=>" $+$ pretty sc
967 else
968 text "λ" <> pretty n <+> text "=>" <+> pretty sc
969 prettySe p (PLet n ty v sc) =
970 bracket p 2 $
971 if size sc > breakingSize then
972 text "let" <+> pretty n <+> text "=" <+> prettySe 10 v <+> text "in" $+$
973 nest nestingSize (prettySe 10 sc)
974 else
975 text "let" <+> pretty n <+> text "=" <+> prettySe 10 v <+> text "in" <+>
976 prettySe 10 sc
977 prettySe p (PPi (Exp l s _ _) n ty sc)
978 | n `elem` allNamesIn sc || impl =
979 let open = if l then text "|" <> lparen else lparen in
980 bracket p 2 $
981 if size sc > breakingSize then
982 open <> pretty n <+> colon <+> prettySe 10 ty <> rparen <+>
983 st <+> text "->" $+$ prettySe 10 sc
984 else
985 open <> pretty n <+> colon <+> prettySe 10 ty <> rparen <+>
986 st <+> text "->" <+> prettySe 10 sc
987 | otherwise =
988 bracket p 2 $
989 if size sc > breakingSize then
990 prettySe 0 ty <+> st <+> text "->" $+$ prettySe 10 sc
991 else
992 prettySe 0 ty <+> st <+> text "->" <+> prettySe 10 sc
993 where
994 st =
995 case s of
996 Static -> text "[static]"
997 _ -> empty
998 prettySe p (PPi (Imp l s _ _) n ty sc)
999 | impl =
1000 let open = if l then text "|" <> lbrace else lbrace in
1001 bracket p 2 $
1002 if size sc > breakingSize then
1003 open <> pretty n <+> colon <+> prettySe 10 ty <> rbrace <+>
1004 st <+> text "->" <+> prettySe 10 sc
1005 else
1006 open <> pretty n <+> colon <+> prettySe 10 ty <> rbrace <+>
1007 st <+> text "->" <+> prettySe 10 sc
1008 | otherwise = prettySe 10 sc
1009 where
1010 st =
1011 case s of
1012 Static -> text $ "[static]"
1013 _ -> empty
1014 prettySe p (PPi (Constraint _ _ _) n ty sc) =
1015 bracket p 2 $
1016 if size sc > breakingSize then
1017 prettySe 10 ty <+> text "=>" <+> prettySe 10 sc
1018 else
1019 prettySe 10 ty <+> text "=>" $+$ prettySe 10 sc
1020 prettySe p (PPi (TacImp _ _ s _) n ty sc) =
1021 bracket p 2 $
1022 if size sc > breakingSize then
1023 lbrace <> text "tacimp" <+> pretty n <+> colon <+> prettySe 10 ty <>
1024 rbrace <+> text "->" $+$ prettySe 10 sc
1025 else
1026 lbrace <> text "tacimp" <+> pretty n <+> colon <+> prettySe 10 ty <>
1027 rbrace <+> text "->" <+> prettySe 10 sc
1028 prettySe p (PApp _ (PRef _ f) [])
1029 | not impl = pretty f
1030 prettySe p (PAppBind _ (PRef _ f) [])
1031 | not impl = text "!" <+> pretty f
1032 prettySe p (PApp _ (PRef _ op@(UN (f:_))) args)
1033 | length (getExps args) == 2 && (not impl) && (not $ isAlpha f) =
1034 let [l, r] = getExps args in
1035 bracket p 1 $
1036 if size r > breakingSize then
1037 prettySe 1 l <+> pretty op $+$ prettySe 0 r
1038 else
1039 prettySe 1 l <+> pretty op <+> prettySe 0 r
1040 prettySe p (PApp _ f as) =
1041 let args = getExps as in
1042 bracket p 1 $
1043 prettySe 1 f <+>
1044 if impl then
1045 foldl' fS empty as
1046 -- foldr (<+>) empty $ map prettyArgS as
1047 else
1048 foldl' fSe empty args
1049 -- foldr (<+>) empty $ map prettyArgSe args
1050 where
1051 fS l r =
1052 if size r > breakingSize then
1053 l $+$ nest nestingSize (prettyArgS r)
1054 else
1055 l <+> prettyArgS r
1057 fSe l r =
1058 if size r > breakingSize then
1059 l $+$ nest nestingSize (prettyArgSe r)
1060 else
1061 l <+> prettyArgSe r
1062 prettySe p (PCase _ scr opts) =
1063 text "case" <+> prettySe 10 scr <+> text "of" $+$ nest nestingSize prettyBody
1064 where
1065 prettyBody = foldr ($$) empty $ intersperse (text "|") $ map sc opts
1067 sc (l, r) = prettySe 10 l <+> text "=>" <+> prettySe 10 r
1068 prettySe p (PHidden tm) = text "." <> prettySe 0 tm
1069 prettySe p (PRefl _ _) = text "refl"
1070 prettySe p (PResolveTC _) = text "resolvetc"
1071 prettySe p (PTrue _) = text "()"
1072 prettySe p (PFalse _) = text "_|_"
1073 prettySe p (PEq _ l r) =
1074 bracket p 2 $
1075 if size r > breakingSize then
1076 prettySe 10 l <+> text "=" $$ nest nestingSize (prettySe 10 r)
1077 else
1078 prettySe 10 l <+> text "=" <+> prettySe 10 r
1079 prettySe p (PRewrite _ l r _) =
1080 bracket p 2 $
1081 if size r > breakingSize then
1082 text "rewrite" <+> prettySe 10 l <+> text "in" $$ nest nestingSize (prettySe 10 r)
1083 else
1084 text "rewrite" <+> prettySe 10 l <+> text "in" <+> prettySe 10 r
1085 prettySe p (PTyped l r) =
1086 lparen <> prettySe 10 l <+> colon <+> prettySe 10 r <> rparen
1087 prettySe p (PPair _ l r) =
1088 if size r > breakingSize then
1089 lparen <> prettySe 10 l <> text "," $+$
1090 prettySe 10 r <> rparen
1091 else
1092 lparen <> prettySe 10 l <> text "," <+> prettySe 10 r <> rparen
1093 prettySe p (PDPair _ l t r) =
1094 if size r > breakingSize then
1095 lparen <> prettySe 10 l <+> text "**" $+$
1096 prettySe 10 r <> rparen
1097 else
1098 lparen <> prettySe 10 l <+> text "**" <+> prettySe 10 r <> rparen
1099 prettySe p (PAlternative a as) =
1100 lparen <> text "|" <> prettyAs <> text "|" <> rparen
1101 where
1102 prettyAs =
1103 foldr (\l -> \r -> l <+> text "," <+> r) empty $ map (prettySe 10) as
1104 prettySe p PType = text "Type"
1105 prettySe p (PConstant c) = pretty c
1106 -- XXX: add pretty for tactics
1107 prettySe p (PProof ts) =
1108 text "proof" <+> lbrace $+$ nest nestingSize (text . show $ ts) $+$ rbrace
1109 prettySe p (PTactics ts) =
1110 text "tactics" <+> lbrace $+$ nest nestingSize (text . show $ ts) $+$ rbrace
1111 prettySe p (PMetavar n) = text "?" <> pretty n
1112 prettySe p (PReturn f) = text "return"
1113 prettySe p PImpossible = text "impossible"
1114 prettySe p Placeholder = text "_"
1115 prettySe p (PDoBlock _) = text "do block pretty not implemented"
1116 prettySe p (PElabError s) = pretty s
1118 prettySe p _ = text "test"
1120 prettyArgS (PImp _ _ _ n tm _) = prettyArgSi (n, tm)
1121 prettyArgS (PExp _ _ tm _) = prettyArgSe tm
1122 prettyArgS (PConstraint _ _ tm _) = prettyArgSc tm
1123 prettyArgS (PTacImplicit _ _ n _ tm _) = prettyArgSti (n, tm)
1125 prettyArgSe arg = prettySe 0 arg
1126 prettyArgSi (n, val) = lbrace <> pretty n <+> text "=" <+> prettySe 10 val <> rbrace
1127 prettyArgSc val = lbrace <> lbrace <> prettySe 10 val <> rbrace <> rbrace
1128 prettyArgSti (n, val) = lbrace <> text "auto" <+> pretty n <+> text "=" <+> prettySe 10 val <> rbrace
1130 bracket outer inner doc
1131 | inner > outer = lparen <> doc <> rparen
1132 | otherwise = doc
1134-- | Show Idris name
1135showName :: Maybe IState -- ^^ the Idris state, for information about names and colours
1136 -> [(Name, Bool)] -- ^^ the bound variables and whether they're implicit
1137 -> Bool -- ^^ whether to show implicits
1138 -> Bool -- ^^ whether to colourise
1139 -> Name -- ^^ the term to show
1140 -> String
1141showName ist bnd impl colour n = case ist of
1142 Just i -> if colour then colourise n (idris_colourTheme i) else showbasic n
1143 Nothing -> showbasic n
1144 where name = if impl then show n else showbasic n
1145 showbasic n@(UN _) = showCG n
1146 showbasic (MN _ s) = s
1147 showbasic (NS n s) = showSep "." (reverse s) ++ "." ++ showbasic n
1148 showbasic (SN s) = show s
1149 fst3 (x, _, _) = x
1150 colourise n t = let ctxt' = fmap tt_ctxt ist in
1151 case ctxt' of
1152 Nothing -> name
1153 Just ctxt | Just impl <- lookup n bnd -> if impl then colouriseImplicit t name
1154 else colouriseBound t name
1155 | isDConName n ctxt -> colouriseData t name
1156 | isFnName n ctxt -> colouriseFun t name
1157 | isTConName n ctxt -> colouriseType t name
1158 -- The assumption is that if a name is not bound and does not exist in the
1159 -- global context, then we're somewhere in which implicit info has been lost
1160 -- (like error messages). Thus, unknown vars are colourised as implicits.
1161 | otherwise -> colouriseImplicit t name
1163-- | Show Idris term
1164showImp :: Maybe IState -- ^^ the Idris state, for information about identifiers and colours
1165 -> Bool -- ^^ whether to show implicits
1166 -> Bool -- ^^ whether to colourise
1167 -> PTerm -- ^^ the term to show
1168 -> String
1169showImp ist impl colour tm = se 10 [] tm where
1170 perhapsColourise :: (ColourTheme -> String -> String) -> String -> String
1171 perhapsColourise col str = case ist of
1172 Just i -> if colour then col (idris_colourTheme i) str else str
1173 Nothing -> str
1175 se :: Int -> [(Name, Bool)] -> PTerm -> String
1176 se p bnd (PQuote r) = "![" ++ show r ++ "]"
1177 se p bnd (PPatvar fc n) = if impl then show n ++ "[p]" else show n
1178 se p bnd (PInferRef fc n) = "!" ++ show n -- ++ "[" ++ show fc ++ "]"
1179 se p bnd e
1180 | Just str <- slist p bnd e = str
1181 | Just num <- snat p e = perhapsColourise colouriseData (show num)
1182 se p bnd (PRef fc n) = showName ist bnd impl colour n
1183 se p bnd (PLam n ty sc) = bracket p 2 $ "\\ " ++ perhapsColourise colouriseBound (show n) ++
1184 (if impl then " : " ++ se 10 bnd ty else "") ++ " => "
1185 ++ se 10 ((n, False):bnd) sc
1186 se p bnd (PLet n ty v sc) = bracket p 2 $ "let " ++ perhapsColourise colouriseBound (show n) ++
1187 " = " ++ se 10 bnd v ++
1188 " in " ++ se 10 ((n, False):bnd) sc
1189 se p bnd (PPi (Exp l s _ param) n ty sc)
1190 | n `elem` allNamesIn sc || impl
1191 = bracket p 2 $
1192 (if l then "|(" else "(") ++
1193 perhapsColourise colouriseBound (show n) ++ " : " ++ se 10 bnd ty ++
1194 ") " ++
1195 (if (impl && param) then "P" else "") ++
1196 st ++
1197 "-> " ++ se 10 ((n, False):bnd) sc
1198 | otherwise = bracket p 2 $ se 0 bnd ty ++ " " ++ st ++ "-> " ++ se 10 bnd sc
1199 where st = case s of
1200 Static -> "[static] "
1201 _ -> ""
1202 se p bnd (PPi (Imp l s _ _) n ty sc)
1203 | impl = bracket p 2 $ (if l then "|{" else "{") ++
1204 perhapsColourise colouriseBound (show n) ++ " : " ++ se 10 bnd ty ++
1205 "} " ++ st ++ "-> " ++ se 10 ((n, True):bnd) sc
1206 | otherwise = se 10 ((n, True):bnd) sc
1207 where st = case s of
1208 Static -> "[static] "
1209 _ -> ""
1210 se p bnd (PPi (Constraint _ _ _) n ty sc)
1211 = bracket p 2 $ se 10 bnd ty ++ " => " ++ se 10 bnd sc
1212 se p bnd (PPi (TacImp _ _ s _) n ty sc)
1213 = bracket p 2 $
1214 "{tacimp " ++ (perhapsColourise colouriseBound (show n)) ++ " : " ++ se 10 bnd ty ++ "} -> " ++
1215 se 10 ((n, False):bnd) sc
1216 se p bnd (PMatchApp _ f) = "match " ++ show f
1217 se p bnd (PApp _ hd@(PRef _ f) [])
1218 | not impl = se p bnd hd
1219 se p bnd (PAppBind _ hd@(PRef _ f) [])
1220 | not impl = "!" ++ se p bnd hd
1221 se p bnd (PApp _ op@(PRef _ (UN (f:_))) args)
1222 | length (getExps args) == 2 && not impl && not (isAlpha f)
1223 = let [l, r] = getExps args in
1224 bracket p 1 $ se 1 bnd l ++ " " ++ se p bnd op ++ " " ++ se 0 bnd r
1225 se p bnd (PApp _ f as)
1226 = -- let args = getExps as in
1227 bracket p 1 $ se 1 bnd f ++
1228 if impl then concatMap (sArg bnd) as
1229 else concatMap (suiArg impl bnd) as
1230 se p bnd (PAppBind _ f as)
1231 = let args = getExps as in
1232 "!" ++ (bracket p 1 $ se 1 bnd f ++ if impl then concatMap (sArg bnd) as
1233 else concatMap (seArg bnd) args)
1234 se p bnd (PCase _ scr opts) = "case " ++ se 10 bnd scr ++ " of " ++ showSep " | " (map sc opts)
1235 where sc (l, r) = se 10 bnd l ++ " => " ++ se 10 bnd r
1236 se p bnd (PHidden tm) = "." ++ se 0 bnd tm
1237 se p bnd (PRefl _ t)
1238 | not impl = perhapsColourise colouriseData "refl"
1239 | otherwise = perhapsColourise colouriseData $ "refl {" ++ se 10 bnd t ++ "}"
1240 se p bnd (PResolveTC _) = "resolvetc"
1241 se p bnd (PTrue _) = perhapsColourise colouriseType "()"
1242 se p bnd (PFalse _) = perhapsColourise colouriseType "_|_"
1243 se p bnd (PEq _ l r) = bracket p 2 $ se 10 bnd l ++ perhapsColourise colouriseType " = " ++ se 10 bnd r
1244 se p bnd (PRewrite _ l r _) = bracket p 2 $ "rewrite " ++ se 10 bnd l ++ " in " ++ se 10 bnd r
1245 se p bnd (PTyped l r) = "(" ++ se 10 bnd l ++ " : " ++ se 10 bnd r ++ ")"
1246 se p bnd (PPair _ l r) = "(" ++ se 10 bnd l ++ ", " ++ se 10 bnd r ++ ")"
1247 se p bnd (PDPair _ l t r) = "(" ++ se 10 bnd l ++ " ** " ++ se 10 bnd r ++ ")"
1248 se p bnd (PAlternative a as) = "(|" ++ showSep " , " (map (se 10 bnd) as) ++ "|)"
1249 se p bnd PType = perhapsColourise colouriseType "Type"
1250 se p bnd (PConstant c) = perhapsColourise (cfun c) (show c)
1251 where cfun (AType _) = colouriseType
1252 cfun StrType = colouriseType
1253 cfun PtrType = colouriseType
1254 cfun VoidType = colouriseType
1255 cfun _ = colouriseData
1256 se p bnd (PProof ts) = "proof { " ++ show ts ++ "}"
1257 se p bnd (PTactics ts) = "tactics { " ++ show ts ++ "}"
1258 se p bnd (PMetavar n) = "?" ++ show n
1259 se p bnd (PReturn f) = "return"
1260 se p bnd PImpossible = "impossible"
1261 se p bnd Placeholder = "_"
1262 se p bnd (PDoBlock _) = "do block show not implemented"
1263 se p bnd (PElabError s) = show s
1264 se p bnd (PCoerced t) = se p bnd t
1265 se p bnd (PUnifyLog t) = "%unifyLog " ++ se p bnd t
1266 se p bnd (PNoImplicits t) = "%noimplicit " ++ se p bnd t
1267-- se p bnd x = "Not implemented"
1269 slist' p bnd (PApp _ (PRef _ nil) _)
1270 | not impl && nsroot nil == UN "Nil" = Just []
1271 slist' p bnd (PApp _ (PRef _ cons) args)
1272 | nsroot cons == UN "::",
1273 (PExp {getTm=tl}):(PExp {getTm=hd}):imps <- reverse args,
1274 all isImp imps,
1275 Just tl' <- slist' p bnd tl
1276 = Just (hd:tl')
1277 where
1278 isImp (PImp {}) = True
1279 isImp _ = False
1280 slist' _ _ _ = Nothing
1282 slist p bnd e | Just es <- slist' p bnd e = Just $
1283 case es of [] -> "[]"
1284 [x] -> "[" ++ se p bnd x ++ "]"
1285 xs -> "[" ++ intercalate "," (map (se p bnd ) xs) ++ "]"
1286 slist _ _ _ = Nothing
1288 -- since Prelude is always imported, S & Z are unqualified iff they're the
1289 -- Nat ones.
1290 snat p (PRef _ o)
1291 | show o == (natns++"Z") || show o == "Z" = Just 0
1292 snat p (PApp _ s [PExp {getTm=n}])
1293 | show s == (natns++"S") || show s == "S",
1294 Just n' <- snat p n
1295 = Just $ 1 + n'
1296 snat _ _ = Nothing
1298 natns = "Prelude.Nat."
1300 sArg bnd (PImp _ _ _ n tm _) = siArg bnd (n, tm)
1301 sArg bnd (PExp _ _ tm _) = seArg bnd tm
1302 sArg bnd (PConstraint _ _ tm _) = scArg bnd tm
1303 sArg bnd (PTacImplicit _ _ n _ tm _) = stiArg bnd (n, tm)
1305 -- show argument, implicits given by the user also shown
1306 suiArg impl bnd (PImp _ mi _ n tm _)
1307 | impl || not mi = siArg bnd (n, tm)
1308 suiArg impl bnd (PExp _ _ tm _) = seArg bnd tm
1309 suiArg impl bnd _ = ""
1311 seArg bnd arg = " " ++ se 0 bnd arg
1312 siArg bnd (n, val) =
1313 let n' = show n
1314 val' = se 10 bnd val in
1315 if (n' == val')
1316 then " {" ++ n' ++ "}"
1317 else " {" ++ n' ++ " = " ++ val' ++ "}"
1318 scArg bnd val = " {{" ++ se 10 bnd val ++ "}}"
1319 stiArg bnd (n, val) = " {auto " ++ show n ++ " = " ++ se 10 bnd val ++ "}"
1321 bracket outer inner str | inner > outer = "(" ++ str ++ ")"
1322 | otherwise = str
1325instance Sized PTerm where
1326 size (PQuote rawTerm) = size rawTerm
1327 size (PRef fc name) = size name
1328 size (PLam name ty bdy) = 1 + size ty + size bdy
1329 size (PPi plicity name ty bdy) = 1 + size ty + size bdy
1330 size (PLet name ty def bdy) = 1 + size ty + size def + size bdy
1331 size (PTyped trm ty) = 1 + size trm + size ty
1332 size (PApp fc name args) = 1 + size args
1333 size (PAppBind fc name args) = 1 + size args
1334 size (PCase fc trm bdy) = 1 + size trm + size bdy
1335 size (PTrue fc) = 1
1336 size (PFalse fc) = 1
1337 size (PRefl fc _) = 1
1338 size (PResolveTC fc) = 1
1339 size (PEq fc left right) = 1 + size left + size right
1340 size (PRewrite fc left right _) = 1 + size left + size right
1341 size (PPair fc left right) = 1 + size left + size right
1342 size (PDPair fs left ty right) = 1 + size left + size ty + size right
1343 size (PAlternative a alts) = 1 + size alts
1344 size (PHidden hidden) = size hidden
1345 size (PUnifyLog tm) = size tm
1346 size (PNoImplicits tm) = size tm
1347 size PType = 1
1348 size (PConstant const) = 1 + size const
1349 size Placeholder = 1
1350 size (PDoBlock dos) = 1 + size dos
1351 size (PIdiom fc term) = 1 + size term
1352 size (PReturn fc) = 1
1353 size (PMetavar name) = 1
1354 size (PProof tactics) = size tactics
1355 size (PElabError err) = size err
1356 size PImpossible = 1
1358getPArity :: PTerm -> Int
1359getPArity (PPi _ _ _ sc) = 1 + getPArity sc
1360getPArity _ = 0
1362-- Return all names, free or globally bound, in the given term.
1364allNamesIn :: PTerm -> [Name]
1365allNamesIn tm = nub $ ni [] tm
1366 where
1367 ni env (PRef _ n)
1368 | not (n `elem` env) = [n]
1369 ni env (PApp _ f as) = ni env f ++ concatMap (ni env) (map getTm as)
1370 ni env (PAppBind _ f as) = ni env f ++ concatMap (ni env) (map getTm as)
1371 ni env (PCase _ c os) = ni env c ++ concatMap (ni env) (map snd os)
1372 ni env (PLam n ty sc) = ni env ty ++ ni (n:env) sc
1373 ni env (PPi _ n ty sc) = ni env ty ++ ni (n:env) sc
1374 ni env (PHidden tm) = ni env tm
1375 ni env (PEq _ l r) = ni env l ++ ni env r
1376 ni env (PRewrite _ l r _) = ni env l ++ ni env r
1377 ni env (PTyped l r) = ni env l ++ ni env r
1378 ni env (PPair _ l r) = ni env l ++ ni env r
1379 ni env (PDPair _ (PRef _ n) t r) = ni env t ++ ni (n:env) r
1380 ni env (PDPair _ l t r) = ni env l ++ ni env t ++ ni env r
1381 ni env (PAlternative a ls) = concatMap (ni env) ls
1382 ni env (PUnifyLog tm) = ni env tm
1383 ni env (PNoImplicits tm) = ni env tm
1384 ni env _ = []
1386-- Return names which are free in the given term.
1388namesIn :: [(Name, PTerm)] -> IState -> PTerm -> [Name]
1389namesIn uvars ist tm = nub $ ni [] tm
1390 where
1391 ni env (PRef _ n)
1392 | not (n `elem` env)
1393 = case lookupTy n (tt_ctxt ist) of
1394 [] -> [n]
1395 _ -> if n `elem` (map fst uvars) then [n] else []
1396 ni env (PApp _ f as) = ni env f ++ concatMap (ni env) (map getTm as)
1397 ni env (PAppBind _ f as) = ni env f ++ concatMap (ni env) (map getTm as)
1398 ni env (PCase _ c os) = ni env c ++ concatMap (ni env) (map snd os)
1399 ni env (PLam n ty sc) = ni env ty ++ ni (n:env) sc
1400 ni env (PPi _ n ty sc) = ni env ty ++ ni (n:env) sc
1401 ni env (PEq _ l r) = ni env l ++ ni env r
1402 ni env (PRewrite _ l r _) = ni env l ++ ni env r
1403 ni env (PTyped l r) = ni env l ++ ni env r
1404 ni env (PPair _ l r) = ni env l ++ ni env r
1405 ni env (PDPair _ (PRef _ n) t r) = ni env t ++ ni (n:env) r
1406 ni env (PDPair _ l t r) = ni env l ++ ni env t ++ ni env r
1407 ni env (PAlternative a as) = concatMap (ni env) as
1408 ni env (PHidden tm) = ni env tm
1409 ni env (PUnifyLog tm) = ni env tm
1410 ni env (PNoImplicits tm) = ni env tm
1411 ni env _ = []
1413-- Return which of the given names are used in the given term.
1415usedNamesIn :: [Name] -> IState -> PTerm -> [Name]
1416usedNamesIn vars ist tm = nub $ ni [] tm
1417 where
1418 ni env (PRef _ n)
1419 | n `elem` vars && not (n `elem` env)
1420 = case lookupTy n (tt_ctxt ist) of
1421 [] -> [n]
1422 _ -> []
1423 ni env (PApp _ f as) = ni env f ++ concatMap (ni env) (map getTm as)
1424 ni env (PAppBind _ f as) = ni env f ++ concatMap (ni env) (map getTm as)
1425 ni env (PCase _ c os) = ni env c ++ concatMap (ni env) (map snd os)
1426 ni env (PLam n ty sc) = ni env ty ++ ni (n:env) sc
1427 ni env (PPi _ n ty sc) = ni env ty ++ ni (n:env) sc
1428 ni env (PEq _ l r) = ni env l ++ ni env r
1429 ni env (PRewrite _ l r _) = ni env l ++ ni env r
1430 ni env (PTyped l r) = ni env l ++ ni env r
1431 ni env (PPair _ l r) = ni env l ++ ni env r
1432 ni env (PDPair _ (PRef _ n) t r) = ni env t ++ ni (n:env) r
1433 ni env (PDPair _ l t r) = ni env l ++ ni env t ++ ni env r
1434 ni env (PAlternative a as) = concatMap (ni env) as
1435 ni env (PHidden tm) = ni env tm
1436 ni env (PUnifyLog tm) = ni env tm
1437 ni env (PNoImplicits tm) = ni env tm
1438 ni env _ = []