git.iko.soy/Idris-dev
on e530718 help sign in
Idris-dev/src/Core/TT.hs
433 lines 14 kB history raw
1{-# LANGUAGE MultiParamTypeClasses, FunctionalDependencies, DeriveFunctor #-}
3module Core.TT where
5import Control.Monad.State
6import Debug.Trace
7import qualified Data.Map as Map
8import Data.Char
9import Data.List
11{- The language has:
12 * Full dependent types
13 * A hierarchy of universes, with cumulativity: Set : Set1, Set1 : Set2, ...
14 * Pattern matching letrec binding
15 * (primitive types defined externally)
17 Some technical stuff:
18 * Typechecker is kept as simple as possible
19 - no unification, just a checker for incomplete terms.
20 * We have a simple collection of tactics which we use to elaborate source
21 programs with implicit syntax into fully explicit terms.
22-}
24data Option = SetInSet
25 | CheckConv
26 deriving Eq
28data FC = FC { fc_fname :: String,
29 fc_line :: Int }
30 deriving Eq
32instance Show FC where
33 show (FC f l) = f ++ ":" ++ show l
35data Err = Msg String
36 | CantUnify Term Term Err
37 | At FC Err
38 deriving Eq
40instance Show Err where
41 show (Msg s) = s
43data TC a = OK a
44 | Error Err
45 deriving (Eq, Functor)
47instance Show a => Show (TC a) where
48 show (OK x) = show x
49 show (Error str) = "Error: " ++ show str
51-- at some point, this instance should also carry type checking options
52-- (e.g. Set:Set)
54instance Monad TC where
55 return = OK
56 x >>= k = case x of
57 OK v -> k v
58 Error e -> Error e
59 fail e = Error (Msg e)
61tfail :: Err -> TC a
62tfail e = Error e
64trun :: FC -> TC a -> TC a
65trun fc (OK a) = OK a
66trun fc (Error e) = Error (At fc e)
68instance MonadPlus TC where
69 mzero = fail "Unknown error"
70 (OK x) `mplus` _ = OK x
71 _ `mplus` (OK y) = OK y
72 err `mplus` _ = err
74discard :: Monad m => m a -> m ()
75discard f = f >> return ()
77showSep :: String -> [String] -> String
78showSep sep [] = ""
79showSep sep [x] = x
80showSep sep (x:xs) = x ++ sep ++ showSep sep xs
82traceWhen True msg a = trace msg a
83traceWhen False _ a = a
85-- RAW TERMS ----------------------------------------------------------------
87-- Names are hierarchies of strings, describing scope (so no danger of
88-- duplicate names, but need to be careful on lookup).
89-- Also MN for machine chosen names
91data Name = UN [String]
92 | MN Int String
93 deriving (Eq, Ord)
95instance Show Name where
96 show (UN [n]) = n
97 show (UN (n:ns)) = show (UN [n]) ++ "." ++ show (UN ns)
98 show (MN i s) = "{" ++ s ++ show i ++ "}"
101-- Contexts allow us to map names to things
102-- TODO: Namespaces and ambiguous names
104type Ctxt a = Map.Map Name a
105emptyContext = Map.empty
107addDef :: Name -> a -> Ctxt a -> Ctxt a
108addDef = Map.insert
110lookupCtxt :: Name -> Ctxt a -> Maybe a
111lookupCtxt = Map.lookup
113toAlist :: Ctxt a -> [(Name, a)]
114toAlist = Map.toList
116addAlist :: [(Name, a)] -> Ctxt a -> Ctxt a
117addAlist [] ctxt = ctxt
118addAlist ((n, tm) : ds) ctxt = addDef n tm (addAlist ds ctxt)
120data Const = I Int | Fl Double | Ch Char | Str String
121 | IType | FlType | ChType | StrType | PtrType
122 deriving Eq
124data Raw = Var Name
125 | RBind Name (Binder Raw) Raw
126 | RApp Raw Raw
127 | RSet Int
128 | RConstant Const
129 deriving (Show, Eq)
131data Binder b = Lam { binderTy :: b }
132 | Pi { binderTy :: b }
133 | Let { binderTy :: b,
134 binderVal :: b }
135 | NLet { binderTy :: b,
136 binderVal :: b }
137 | Hole { binderTy :: b}
138 | GHole { binderTy :: b}
139 | Guess { binderTy :: b,
140 binderVal :: b }
141 | PVar { binderTy :: b }
142 | PVTy { binderTy :: b }
143 deriving (Show, Eq, Functor)
145fmapMB :: Monad m => (a -> m b) -> Binder a -> m (Binder b)
146fmapMB f (Let t v) = liftM2 Let (f t) (f v)
147fmapMB f (NLet t v) = liftM2 NLet (f t) (f v)
148fmapMB f (Guess t v) = liftM2 Guess (f t) (f v)
149fmapMB f (Lam t) = liftM Lam (f t)
150fmapMB f (Pi t) = liftM Pi (f t)
151fmapMB f (Hole t) = liftM Hole (f t)
152fmapMB f (GHole t) = liftM GHole (f t)
153fmapMB f (PVar t) = liftM PVar (f t)
154fmapMB f (PVTy t) = liftM PVTy (f t)
156raw_apply :: Raw -> [Raw] -> Raw
157raw_apply f [] = f
158raw_apply f (a : as) = raw_apply (RApp f a) as
160data RawFun = RawFun { rtype :: Raw,
161 rval :: Raw
162 }
163 deriving Show
165data RawDatatype = RDatatype Name Raw [(Name, Raw)]
166 deriving Show
168data RDef = RFunction RawFun
169 | RConst Raw
170 | RData RawDatatype
171 deriving Show
173type RProgram = [(Name, RDef)]
175-- WELL TYPED TERMS ---------------------------------------------------------
177data NameType = Bound | Ref | DCon Int Int | TCon Int Int
178 deriving (Show, Eq)
180data TT n = P NameType n (TT n) -- embed type
181 | V Int
182 | Bind n (Binder (TT n)) (TT n)
183 | App (TT n) (TT n) -- function, function type, arg
184 | Constant Const
185 | Set Int
186 deriving Functor
188type EnvTT n = [(n, Binder (TT n))]
190data Datatype n = Data { d_typename :: n,
191 d_typetag :: Int,
192 d_type :: (TT n),
193 d_cons :: [(n, TT n)] }
194 deriving (Show, Functor, Eq)
196instance Eq n => Eq (TT n) where
197 (==) (P xt x _) (P yt y _) = xt == yt && x == y
198 (==) (V x) (V y) = x == y
199 (==) (Bind _ xb xs) (Bind _ yb ys) = xb == yb && xs == ys
200 (==) (App fx ax) (App fy ay) = fx == fy && ax == ay
201 (==) (Set x) (Set y) = x == y
202 (==) (Constant x) (Constant y) = x == y
203 (==) _ _ = False
205-- A few handy operations on well typed terms:
207instantiate :: TT n -> TT n -> TT n
208instantiate e = subst 0 where
209 subst i (V x) | i == x = e
210 subst i (Bind x b sc) = Bind x (fmap (subst i) b) (subst (i+1) sc)
211 subst i (App f a) = App (subst i f) (subst i a)
212 subst i t = t
214pToV :: Eq n => n -> TT n -> TT n
215pToV n = pToV' n 0
216pToV' n i (P _ x _) | n == x = V i
217pToV' n i (Bind x b sc)
218 | n == x = Bind x (fmap (pToV' n i) b) sc
219 | otherwise = Bind x (fmap (pToV' n i) b) (pToV' n (i+1) sc)
220pToV' n i (App f a) = App (pToV' n i f) (pToV' n i a)
221pToV' n i t = t
223-- Convert several names. First in the list comes out as V 0
224pToVs :: Eq n => [n] -> TT n -> TT n
225pToVs ns tm = pToVs' ns tm 0 where
226 pToVs' [] tm i = tm
227 pToVs' (n:ns) tm i = pToV' n i (pToVs' ns tm (i+1))
229vToP :: TT n -> TT n
230vToP = vToP' [] where
231 vToP' env (V i) = let (n, b) = (env !! i) in
232 P Bound n (binderTy b)
233 vToP' env (Bind n b sc) = let b' = fmap (vToP' env) b in
234 Bind n b' (vToP' ((n, b'):env) sc)
235 vToP' env (App f a) = App (vToP' env f) (vToP' env a)
236 vToP' env t = t
238finalise :: Eq n => TT n -> TT n
239finalise (Bind x b sc) = Bind x (fmap finalise b) (pToV x (finalise sc))
240finalise (App f a) = App (finalise f) (finalise a)
241finalise t = t
243subst :: Eq n => n -> TT n -> TT n -> TT n
244subst n v tm = instantiate v (pToV n tm)
246substNames :: Eq n => [(n, TT n)] -> TT n -> TT n
247substNames [] t = t
248substNames ((n, tm) : xs) t = subst n tm (substNames xs t)
250-- Returns true if V 0 and bound name n do not occur in the term
252noOccurrence :: Eq n => n -> TT n -> Bool
253noOccurrence n t = no' 0 t
254 where
255 no' i (V x) = not (i == x)
256 no' i (P Bound x _) = not (n == x)
257 no' i (Bind n b sc) = noB' i b && no' (i+1) sc
258 where noB' i (Let t v) = no' i t && no' i v
259 noB' i (Guess t v) = no' i t && no' i v
260 noB' i b = no' i (binderTy b)
261 no' i (App f a) = no' i f && no' i a
262 no' i _ = True
264-- Return the arity of a (normalised) type
266arity :: TT n -> Int
267arity (Bind n (Pi t) sc) = 1 + arity sc
268arity _ = 0
270-- deconstruct an application; returns the function and a list of arguments
272unApply :: TT n -> (TT n, [TT n])
273unApply t = ua [] t where
274 ua args (App f a) = ua (a:args) f
275 ua args t = (t, args)
277mkApp :: TT n -> [TT n] -> TT n
278mkApp f [] = f
279mkApp f (a:as) = mkApp (App f a) as
281forget :: TT Name -> Raw
282forget tm = fe [] tm
283 where
284 fe env (P _ n _) = Var n
285 fe env (V i) = Var (env !! i)
286 fe env (Bind n b sc) = RBind n (fmap (fe env) b)
287 (fe (n:env) sc)
288 fe env (App f a) = RApp (fe env f) (fe env a)
289 fe env (Constant c)
290 = RConstant c
291 fe env (Set i) = RSet i
293bindAll :: [(n, Binder (TT n))] -> TT n -> TT n
294bindAll [] t =t
295bindAll ((n, b) : bs) t = Bind n b (bindAll bs t)
297bindTyArgs :: (TT n -> Binder (TT n)) -> [(n, TT n)] -> TT n -> TT n
298bindTyArgs b xs = bindAll (map (\ (n, ty) -> (n, b ty)) xs)
300getArgTys :: TT n -> [(n, TT n)]
301getArgTys (Bind n (Pi t) sc) = (n, t) : getArgTys sc
302getArgTys _ = []
304uniqueName :: Name -> [Name] -> Name
305uniqueName n hs | n `elem` hs = uniqueName (nextName n) hs
306 | otherwise = n
308nextName (MN i n) = MN (i+1) n
309nextName (UN (x:xs)) = let (num', nm') = span isDigit (reverse x)
310 nm = reverse nm'
311 num = readN (reverse num') in
312 UN ((nm ++ show (num+1)) : xs)
313 where
314 readN "" = 0
315 readN x = read x
317type Term = TT Name
318type Type = Term
320type Env = EnvTT Name
322-- an environment with de Bruijn indices 'normalised' so that they all refer to
323-- this environment
325newtype WkEnvTT n = Wk (EnvTT n)
326type WkEnv = WkEnvTT Name
328instance (Eq n, Show n) => Show (TT n) where
329 show t = showEnv [] t
331instance Show Const where
332 show (I i) = show i
333 show (Fl f) = show f
334 show (Ch c) = show c
335 show (Str s) = show s
336 show IType = "Int"
337 show FlType = "Float"
338 show ChType = "Char"
339 show StrType = "String"
340 show PtrType = "Ptr"
342showEnv env t = showEnv' env t False
343showEnvDbg env t = showEnv' env t True
345showEnv' env t dbg = se 10 env t where
346 se p env (P nt n t) = show n
347 -- ++ if dbg then "{" ++ show nt ++ " : " ++ se 10 env t ++ "}" else ""
348 se p env (V i) | i < length env = (show $ fst $ env!!i) ++
349 if dbg then "{" ++ show i ++ "}" else ""
350 | otherwise = "!!V " ++ show i ++ "!!"
351 se p env (Bind n b@(Pi t) sc)
352 | noOccurrence n sc && not dbg = bracket p 2 $ se 1 env t ++ " -> " ++ se 10 ((n,b):env) sc
353 se p env (Bind n b sc) = bracket p 2 $ sb env n b ++ se 10 ((n,b):env) sc
354 se p env (App f a) = bracket p 1 $ se 1 env f ++ " " ++ se 0 env a
355 se p env (Constant c) = show c
356 se p env (Set i) = "Set" ++ show i
358 sb env n (Lam t) = showb env "\\ " " => " n t
359 sb env n (Hole t) = showb env "? " ". " n t
360 sb env n (GHole t) = showb env "?defer " ". " n t
361 sb env n (Pi t) = showb env "(" ") -> " n t
362 sb env n (PVar t) = showb env "pat " ". " n t
363 sb env n (PVTy t) = showb env "pty " ". " n t
364 sb env n (Let t v) = showbv env "let " " in " n t v
365 sb env n (Guess t v) = showbv env "?? " " in " n t v
367 showb env op sc n t = op ++ show n ++ " : " ++ se 10 env t ++ sc
368 showbv env op sc n t v = op ++ show n ++ " : " ++ se 10 env t ++ " = " ++
369 se 10 env v ++ sc
371 bracket outer inner str | inner > outer = "(" ++ str ++ ")"
372 | otherwise = str
374-- Check whether a term has any holes in it - impure if so
376pureTerm :: TT n -> Bool
377pureTerm (App f a) = pureTerm f && pureTerm a
378pureTerm (Bind n b sc) = pureBinder b && pureTerm sc where
379 pureBinder (Hole _) = False
380 pureBinder (Guess _ _) = False
381 pureBinder (Let t v) = pureTerm t && pureTerm v
382 pureBinder t = pureTerm (binderTy t)
383pureTerm _ = True
385-- weaken a term by adding i to each de Bruijn index (i.e. lift it over i bindings)
387weakenTm :: Int -> TT n -> TT n
388weakenTm i t = wk i 0 t
389 where wk i min (V x) | x >= min = V (i + x)
390 wk i m (App f a) = App (wk i m f) (wk i m a)
391 wk i m (Bind x b sc) = Bind x (wkb i m b) (wk i (m + 1) sc)
392 wk i m t = t
393 wkb i m t = fmap (wk i m) t
395-- weaken an environment so that all the de Bruijn indices are correct according
396-- to the latest bound variable
398weakenEnv :: EnvTT n -> EnvTT n
399weakenEnv env = wk (length env - 1) env
400 where wk i [] = []
401 wk i ((n, b) : bs) = (n, weakenTmB i b) : wk (i - 1) bs
402 weakenTmB i (Let t v) = Let (weakenTm i t) (weakenTm i v)
403 weakenTmB i (Guess t v) = Guess (weakenTm i t) (weakenTm i v)
404 weakenTmB i t = t { binderTy = weakenTm i (binderTy t) }
406weakenTmEnv :: Int -> EnvTT n -> EnvTT n
407weakenTmEnv i = map (\ (n, b) -> (n, fmap (weakenTm i) b))
409orderPats :: Term -> Term
410orderPats tm = op [] tm
411 where
412 op ps (Bind n (PVar t) sc) = op ((n, t) : ps) sc
413 op ps sc = bindAll (map (\ (n, t) -> (n, PVar t)) (sortP ps)) sc
415 sortP ps = pick [] (reverse ps)
417 namesIn (P _ n _) = [n]
418 namesIn (Bind n b t) = nub $ nb b ++ (namesIn t \\ [n])
419 where nb (Let t v) = nub (namesIn t) ++ nub (namesIn v)
420 nb (Guess t v) = nub (namesIn t) ++ nub (namesIn v)
421 nb t = namesIn (binderTy t)
422 namesIn (App f a) = nub (namesIn f ++ namesIn a)
423 namesIn _ = []
425 pick acc [] = reverse acc
426 pick acc ((n, t) : ps) = pick (insert n t acc) ps
428 insert n t [] = [(n, t)]
429 insert n t ((n',t') : ps)
430 | n `elem` (namesIn t' ++ concatMap namesIn (map snd ps))
431 = (n', t') : insert n t ps
432 | otherwise = (n,t):(n',t'):ps