git.iko.soy/Idris-dev
on ec87a69 help sign in
Idris-dev/src/Core/TT.hs
368 lines 11 kB history raw
1{-# LANGUAGE MultiParamTypeClasses, FunctionalDependencies, DeriveFunctor #-}
3module Core.TT where
5import Control.Monad.State
6import Debug.Trace
7import qualified Data.Map as Map
9{- The language has:
10 * Full dependent types
11 * A hierarchy of universes, with cumulativity: Set : Set1, Set1 : Set2, ...
12 * Pattern matching letrec binding
13 * (primitive types defined externally)
15 Some technical stuff:
16 * Typechecker is kept as simple as possible
17 - no unification, just a checker for incomplete terms.
18 * We have a simple collection of tactics which we use to elaborate source
19 programs with implicit syntax into fully explicit terms.
20-}
22data Option = SetInSet
23 | CheckConv
24 deriving Eq
26data FC = FC { fc_fname :: String,
27 fc_line :: Int }
28 deriving Eq
30instance Show FC where
31 show (FC f l) = f ++ ":" ++ show l
33data Err = Msg String
34 | CantUnify Term Term Err
35 | At FC Err
36 deriving Eq
38instance Show Err where
39 show (Msg s) = s
41data TC a = OK a
42 | Error Err
43 deriving (Eq, Functor)
45instance Show a => Show (TC a) where
46 show (OK x) = show x
47 show (Error str) = "Error: " ++ show str
49-- at some point, this instance should also carry type checking options
50-- (e.g. Set:Set)
52instance Monad TC where
53 return = OK
54 x >>= k = case x of
55 OK v -> k v
56 Error e -> Error e
57 fail e = Error (Msg e)
59tfail :: Err -> TC a
60tfail e = Error e
62trun :: FC -> TC a -> TC a
63trun fc (OK a) = OK a
64trun fc (Error e) = Error (At fc e)
66instance MonadPlus TC where
67 mzero = fail "Unknown error"
68 (OK x) `mplus` _ = OK x
69 _ `mplus` (OK y) = OK y
70 err `mplus` _ = err
72discard :: Monad m => m a -> m ()
73discard f = f >> return ()
75showSep :: String -> [String] -> String
76showSep sep [] = ""
77showSep sep [x] = x
78showSep sep (x:xs) = x ++ sep ++ showSep sep xs
80-- RAW TERMS ----------------------------------------------------------------
82-- Names are hierarchies of strings, describing scope (so no danger of
83-- duplicate names, but need to be careful on lookup).
84-- Also MN for machine chosen names
86data Name = UN [String]
87 | MN Int String
88 deriving (Eq, Ord)
90instance Show Name where
91 show (UN [n]) = n
92 show (UN (n:ns)) = show (UN [n]) ++ "." ++ show (UN ns)
93 show (MN i s) = "{" ++ s ++ show i ++ "}"
96-- Contexts allow us to map names to things
97-- TODO: Namespaces and ambiguous names
99type Ctxt a = Map.Map Name a
100emptyContext = Map.empty
102addDef :: Name -> a -> Ctxt a -> Ctxt a
103addDef = Map.insert
105lookupCtxt :: Name -> Ctxt a -> Maybe a
106lookupCtxt = Map.lookup
108toAlist :: Ctxt a -> [(Name, a)]
109toAlist = Map.toList
111addAlist :: [(Name, a)] -> Ctxt a -> Ctxt a
112addAlist [] ctxt = ctxt
113addAlist ((n, tm) : ds) ctxt = addDef n tm (addAlist ds ctxt)
115data Const = I Int | Fl Double | Ch Char | Str String
116 | IType | FlType | ChType | StrType | PtrType
117 deriving Eq
119data Raw = Var Name
120 | RBind Name (Binder Raw) Raw
121 | RApp Raw Raw
122 | RSet Int
123 | RConstant Const
124 deriving Show
126data Binder b = Lam { binderTy :: b }
127 | Pi { binderTy :: b }
128 | Let { binderTy :: b,
129 binderVal :: b }
130 | NLet { binderTy :: b,
131 binderVal :: b }
132 | Hole { binderTy :: b}
133 | GHole { binderTy :: b}
134 | Guess { binderTy :: b,
135 binderVal :: b }
136 | PVar { binderTy :: b }
137 | PVTy { binderTy :: b }
138 deriving (Show, Eq, Functor)
140raw_apply :: Raw -> [Raw] -> Raw
141raw_apply f [] = f
142raw_apply f (a : as) = raw_apply (RApp f a) as
144data RawFun = RawFun { rtype :: Raw,
145 rval :: Raw
146 }
147 deriving Show
149data RawDatatype = RDatatype Name Raw [(Name, Raw)]
150 deriving Show
152data RDef = RFunction RawFun
153 | RConst Raw
154 | RData RawDatatype
155 deriving Show
157type RProgram = [(Name, RDef)]
159-- WELL TYPED TERMS ---------------------------------------------------------
161data NameType = Bound | Ref | DCon Int Int | TCon Int
162 deriving (Show, Eq)
164data TT n = P NameType n (TT n) -- embed type
165 | V Int
166 | Bind n (Binder (TT n)) (TT n)
167 | App (TT n) (TT n) -- function, function type, arg
168 | Constant Const
169 | Set Int
170 deriving Functor
172type EnvTT n = [(n, Binder (TT n))]
174data Datatype n = Data { d_typename :: n,
175 d_type :: (TT n),
176 d_cons :: [(n, TT n)] }
177 deriving (Show, Functor, Eq)
179instance Eq n => Eq (TT n) where
180 (==) (P xt x _) (P yt y _) = xt == yt && x == y
181 (==) (V x) (V y) = x == y
182 (==) (Bind _ xb xs) (Bind _ yb ys) = xb == yb && xs == ys
183 (==) (App fx ax) (App fy ay) = fx == fy && ax == ay
184 (==) (Set x) (Set y) = x == y
185 (==) (Constant x) (Constant y) = x == y
186 (==) _ _ = False
188-- A few handy operations on well typed terms:
190instantiate :: TT n -> TT n -> TT n
191instantiate e = subst 0 where
192 subst i (V x) | i == x = e
193 subst i (Bind x b sc) = Bind x (fmap (subst i) b) (subst (i+1) sc)
194 subst i (App f a) = App (subst i f) (subst i a)
195 subst i t = t
197pToV :: Eq n => n -> TT n -> TT n
198pToV n = pToV' n 0
199pToV' n i (P _ x _) | n == x = V i
200pToV' n i (Bind x b sc)
201 | n == x = Bind x (fmap (pToV' n i) b) sc
202 | otherwise = Bind x (fmap (pToV' n i) b) (pToV' n (i+1) sc)
203pToV' n i (App f a) = App (pToV' n i f) (pToV' n i a)
204pToV' n i t = t
206-- Convert several names. First in the list comes out as V 0
207pToVs :: Eq n => [n] -> TT n -> TT n
208pToVs ns tm = pToVs' ns tm 0 where
209 pToVs' [] tm i = tm
210 pToVs' (n:ns) tm i = pToV' n i (pToVs' ns tm (i+1))
212vToP :: TT n -> TT n
213vToP = vToP' [] where
214 vToP' env (V i) = let (n, b) = (env !! i) in
215 P Bound n (binderTy b)
216 vToP' env (Bind n b sc) = let b' = fmap (vToP' env) b in
217 Bind n b' (vToP' ((n, b'):env) sc)
218 vToP' env (App f a) = App (vToP' env f) (vToP' env a)
219 vToP' env t = t
221finalise :: Eq n => TT n -> TT n
222finalise (Bind x b sc) = Bind x (fmap finalise b) (pToV x (finalise sc))
223finalise (App f a) = App (finalise f) (finalise a)
224finalise t = t
226subst :: Eq n => n -> TT n -> TT n -> TT n
227subst n v tm = instantiate v (pToV n tm)
229substNames :: Eq n => [(n, TT n)] -> TT n -> TT n
230substNames [] t = t
231substNames ((n, tm) : xs) t = subst n tm (substNames xs t)
233-- Returns true if V 0 and bound name n do not occur in the term
235noOccurrence :: Eq n => n -> TT n -> Bool
236noOccurrence n t = no' 0 t
237 where
238 no' i (V x) = not (i == x)
239 no' i (P Bound x _) = not (n == x)
240 no' i (Bind n b sc) = noB' i b && no' (i+1) sc
241 where noB' i (Let t v) = no' i t && no' i v
242 noB' i (Guess t v) = no' i t && no' i v
243 noB' i b = no' i (binderTy b)
244 no' i (App f a) = no' i f && no' i a
245 no' i _ = True
247-- Return the arity of a (normalised) type
249arity :: TT n -> Int
250arity (Bind n (Pi t) sc) = 1 + arity sc
251arity _ = 0
253-- deconstruct an application; returns the function and a list of arguments
255unApply :: TT n -> (TT n, [TT n])
256unApply t = ua [] t where
257 ua args (App f a) = ua (a:args) f
258 ua args t = (t, args)
260mkApp :: TT n -> [TT n] -> TT n
261mkApp f [] = f
262mkApp f (a:as) = mkApp (App f a) as
264forget :: TT Name -> Raw
265forget tm = fe [] tm
266 where
267 fe env (P _ n _) = Var n
268 fe env (V i) = Var (env !! i)
269 fe env (Bind n b sc) = RBind n (fmap (fe env) b)
270 (fe (n:env) sc)
271 fe env (App f a) = RApp (fe env f) (fe env a)
272 fe env (Constant c)
273 = RConstant c
274 fe env (Set i) = RSet i
276type Term = TT Name
277type Type = Term
279type Env = EnvTT Name
281-- an environment with de Bruijn indices 'normalised' so that they all refer to
282-- this environment
284newtype WkEnvTT n = Wk (EnvTT n)
285type WkEnv = WkEnvTT Name
287instance (Eq n, Show n) => Show (TT n) where
288 show t = showEnv [] t
290instance Show Const where
291 show (I i) = show i
292 show (Fl f) = show f
293 show (Ch c) = show c
294 show (Str s) = show s
295 show IType = "Int"
296 show FlType = "Float"
297 show ChType = "Char"
298 show StrType = "String"
299 show PtrType = "Ptr"
301showEnv env t = showEnv' env t False
302showEnvDbg env t = showEnv' env t True
304showEnv' env t dbg = se 10 env t where
305 se p env (P nt n t) = show n
306 ++ if dbg then "{" ++ show nt ++ " : " ++ se 10 env t ++ "}" else ""
307 se p env (V i) | i < length env = (show $ fst $ env!!i) ++
308 if dbg then "{" ++ show i ++ "}" else ""
309 | otherwise = "!!V " ++ show i ++ "!!"
310 se p env (Bind n b@(Pi t) sc)
311 | noOccurrence n sc && not dbg = bracket p 2 $ se 1 env t ++ " -> " ++ se 10 ((n,b):env) sc
312 se p env (Bind n b sc) = bracket p 2 $ sb env n b ++ se 10 ((n,b):env) sc
313 se p env (App f a) = bracket p 1 $ se 1 env f ++ " " ++ se 0 env a
314 se p env (Constant c) = show c
315 se p env (Set i) = "Set" ++ show i
317 sb env n (Lam t) = showb env "\\ " " => " n t
318 sb env n (Hole t) = showb env "? " ". " n t
319 sb env n (GHole t) = showb env "?defer " ". " n t
320 sb env n (Pi t) = showb env "(" ") -> " n t
321 sb env n (PVar t) = showb env "pat " ". " n t
322 sb env n (PVTy t) = showb env "pty " ". " n t
323 sb env n (Let t v) = showbv env "let " " in " n t v
324 sb env n (Guess t v) = showbv env "?? " " in " n t v
326 showb env op sc n t = op ++ show n ++ " : " ++ se 10 env t ++ sc
327 showbv env op sc n t v = op ++ show n ++ " : " ++ se 10 env t ++ " = " ++
328 se 10 env v ++ sc
330 bracket outer inner str | inner > outer = "(" ++ str ++ ")"
331 | otherwise = str
333-- Check whether a term has any holes in it - impure if so
335pureTerm :: TT n -> Bool
336pureTerm (App f a) = pureTerm f && pureTerm a
337pureTerm (Bind n b sc) = pureBinder b && pureTerm sc where
338 pureBinder (Hole _) = False
339 pureBinder (Guess _ _) = False
340 pureBinder (Let t v) = pureTerm t && pureTerm v
341 pureBinder t = pureTerm (binderTy t)
342pureTerm _ = True
344-- weaken a term by adding i to each de Bruijn index (i.e. lift it over i bindings)
346weakenTm :: Int -> TT n -> TT n
347weakenTm i t = wk i 0 t
348 where wk i min (V x) | x >= min = V (i + x)
349 wk i m (App f a) = App (wk i m f) (wk i m a)
350 wk i m (Bind x b sc) = Bind x (wkb i m b) (wk i (m + 1) sc)
351 wk i m t = t
352 wkb i m t = fmap (wk i m) t
354-- weaken an environment so that all the de Bruijn indices are correct according
355-- to the latest bound variable
357weakenEnv :: EnvTT n -> EnvTT n
358weakenEnv env = wk (length env - 1) env
359 where wk i [] = []
360 wk i ((n, b) : bs) = (n, weakenTmB i b) : wk (i - 1) bs
361 weakenTmB i (Let t v) = Let (weakenTm i t) (weakenTm i v)
362 weakenTmB i (Guess t v) = Guess (weakenTm i t) (weakenTm i v)
363 weakenTmB i t = t { binderTy = weakenTm i (binderTy t) }
365weakenTmEnv :: Int -> EnvTT n -> EnvTT n
366weakenTmEnv i = map (\ (n, b) -> (n, fmap (weakenTm i) b))