git.iko.soy/Idris-dev
on ed85b4e help sign in
Idris-dev/src/Core/CaseTree.hs
445 lines 17 kB history raw
1{-# LANGUAGE PatternGuards, DeriveFunctor #-}
3module Core.CaseTree(CaseDef(..), SC, SC'(..), CaseAlt, CaseAlt'(..),
4 Phase(..), CaseTree,
5 simpleCase, small, namesUsed, findCalls, findUsedArgs) where
7import Core.TT
9import Control.Monad.State
10import Data.Maybe
11import Data.List hiding (partition)
12import Debug.Trace
14data CaseDef = CaseDef [Name] SC [Term]
15 deriving Show
17data SC' t = Case Name [CaseAlt' t] -- invariant: lowest tags first
18 | ProjCase t [CaseAlt' t] -- special case for projections
19 | STerm t
20 | UnmatchedCase String -- error message
21 | ImpossibleCase -- already checked to be impossible
22 deriving (Eq, Ord, Functor)
23{-!
24deriving instance Binary SC
25!-}
27type SC = SC' Term
29data CaseAlt' t = ConCase Name Int [Name] (SC' t)
30 | ConstCase Const (SC' t)
31 | DefaultCase (SC' t)
32 deriving (Show, Eq, Ord, Functor)
33{-!
34deriving instance Binary CaseAlt
35!-}
37type CaseAlt = CaseAlt' Term
39instance Show t => Show (SC' t) where
40 show sc = show' 1 sc
41 where
42 show' i (Case n alts) = "case " ++ show n ++ " of\n" ++ indent i ++
43 showSep ("\n" ++ indent i) (map (showA i) alts)
44 show' i (ProjCase tm alts) = "case " ++ show tm ++ " of " ++
45 showSep ("\n" ++ indent i) (map (showA i) alts)
46 show' i (STerm tm) = show tm
47 show' i (UnmatchedCase str) = "error " ++ show str
48 show' i ImpossibleCase = "impossible"
50 indent i = concat $ take i (repeat " ")
52 showA i (ConCase n t args sc)
53 = show n ++ "(" ++ showSep (", ") (map show args) ++ ") => "
54 ++ show' (i+1) sc
55 showA i (ConstCase t sc)
56 = show t ++ " => " ++ show' (i+1) sc
57 showA i (DefaultCase sc)
58 = "_ => " ++ show' (i+1) sc
61type CaseTree = SC
62type Clause = ([Pat], (Term, Term))
63type CS = ([Term], Int)
65instance TermSize SC where
66 termsize n (Case n' as) = termsize n as
67 termsize n (STerm t) = termsize n t
68 termsize n _ = 1
70instance TermSize CaseAlt where
71 termsize n (ConCase _ _ _ s) = termsize n s
72 termsize n (ConstCase _ s) = termsize n s
73 termsize n (DefaultCase s) = termsize n s
75-- simple terms can be inlined trivially - good for primitives in particular
76-- To avoid duplicating work, don't inline something which uses one
77-- of its arguments in more than one place
79small :: Name -> [Name] -> SC -> Bool
80small n args t = let as = findAllUsedArgs t args in
81 length as == length (nub as) && termsize n t < 50
83namesUsed :: SC -> [Name]
84namesUsed sc = nub $ nu' [] sc where
85 nu' ps (Case n alts) = nub (concatMap (nua ps) alts) \\ [n]
86 nu' ps (ProjCase t alts) = nub $ (nut ps t ++
87 (concatMap (nua ps) alts))
88 nu' ps (STerm t) = nub $ nut ps t
89 nu' ps _ = []
91 nua ps (ConCase n i args sc) = nub (nu' (ps ++ args) sc) \\ args
92 nua ps (ConstCase _ sc) = nu' ps sc
93 nua ps (DefaultCase sc) = nu' ps sc
95 nut ps (P _ n _) | n `elem` ps = []
96 | otherwise = [n]
97 nut ps (App f a) = nut ps f ++ nut ps a
98 nut ps (Proj t _) = nut ps t
99 nut ps (Bind n (Let t v) sc) = nut ps v ++ nut (n:ps) sc
100 nut ps (Bind n b sc) = nut (n:ps) sc
101 nut ps _ = []
103-- Return all called functions, and which arguments are used in each argument position
104-- for the call, in order to help reduce compilation time, and trace all unused
105-- arguments
107findCalls :: SC -> [Name] -> [(Name, [[Name]])]
108findCalls sc topargs = nub $ nu' topargs sc where
109 nu' ps (Case n alts) = nub (concatMap (nua (n : ps)) alts)
110 nu' ps (ProjCase t alts) = nub (nut ps t ++ concatMap (nua ps) alts)
111 nu' ps (STerm t) = nub $ nut ps t
112 nu' ps _ = []
114 nua ps (ConCase n i args sc) = nub (nu' (ps ++ args) sc)
115 nua ps (ConstCase _ sc) = nu' ps sc
116 nua ps (DefaultCase sc) = nu' ps sc
118 nut ps (P Ref n _) | n `elem` ps = []
119 | otherwise = [(n, [])] -- tmp
120 nut ps fn@(App f a)
121 | (P Ref n _, args) <- unApply fn
122 = if n `elem` ps then nut ps f ++ nut ps a
123 else [(n, map argNames args)] ++ concatMap (nut ps) args
124 | otherwise = nut ps f ++ nut ps a
125 nut ps (Bind n (Let t v) sc) = nut ps v ++ nut (n:ps) sc
126 nut ps (Proj t _) = nut ps t
127 nut ps (Bind n b sc) = nut (n:ps) sc
128 nut ps _ = []
130 argNames tm = let ns = directUse tm in
131 filter (\x -> x `elem` ns) topargs
133-- Find names which are used directly (i.e. not in a function call) in a term
135directUse :: Eq n => TT n -> [n]
136directUse (P _ n _) = [n]
137directUse (Bind n (Let t v) sc) = nub $ directUse v ++ (directUse sc \\ [n])
138 ++ directUse t
139directUse (Bind n b sc) = nub $ directUse (binderTy b) ++ (directUse sc \\ [n])
140directUse fn@(App f a)
141 | (P Ref n _, args) <- unApply fn = [] -- need to know what n does with them
142 | otherwise = nub $ directUse f ++ directUse a
143directUse (Proj x i) = nub $ directUse x
144directUse _ = []
146-- Find all directly used arguments (i.e. used but not in function calls)
148findUsedArgs :: SC -> [Name] -> [Name]
149findUsedArgs sc topargs = nub (findAllUsedArgs sc topargs)
151findAllUsedArgs sc topargs = filter (\x -> x `elem` topargs) (nu' sc) where
152 nu' (Case n alts) = n : concatMap nua alts
153 nu' (ProjCase t alts) = directUse t ++ concatMap nua alts
154 nu' (STerm t) = directUse t
155 nu' _ = []
157 nua (ConCase n i args sc) = nu' sc
158 nua (ConstCase _ sc) = nu' sc
159 nua (DefaultCase sc) = nu' sc
161data Phase = CompileTime | RunTime
162 deriving (Show, Eq)
164-- Generate a simple case tree
165-- Work Right to Left
167simpleCase :: Bool -> Bool -> Phase -> FC -> [([Name], Term, Term)] ->
168 TC CaseDef
169simpleCase tc cover phase fc []
170 = return $ CaseDef [] (UnmatchedCase "No pattern clauses") []
171simpleCase tc cover phase fc cs
172 = let proj = phase == RunTime
173 pats = map (\ (avs, l, r) ->
174 (avs, rev phase (toPats tc l), (l, r))) cs
175 chkPats = mapM chkAccessible pats in
176 case chkPats of
177 OK pats ->
178 let numargs = length (fst (head pats))
179 ns = take numargs args
180 (tree, st) = runState
181 (match (rev phase ns) pats (defaultCase cover)) ([], numargs)
182 t = CaseDef ns (prune proj (depatt ns tree)) (fst st) in
183 if proj then return (stripLambdas t) else return t
184 Error err -> Error (At fc err)
185 where args = map (\i -> MN i "e") [0..]
186 defaultCase True = STerm Erased
187 defaultCase False = UnmatchedCase "Error"
189 chkAccessible (avs, l, c)
190 | phase == RunTime = return (l, c)
191 | otherwise = do mapM_ (acc l) avs
192 return (l, c)
194 acc [] n = Error (Inaccessible n)
195 acc (PV x : xs) n | x == n = OK ()
196 acc (PCon _ _ ps : xs) n = acc (ps ++ xs) n
197 acc (_ : xs) n = acc xs n
199-- right to left gives more chance of discriminating on interesting arguments
200-- rather than indices which are likely to be repeated.
201-- rev CompileTime = id
202rev _ = reverse
204data Pat = PCon Name Int [Pat]
205 | PConst Const
206 | PV Name
207 | PAny
208 deriving Show
210-- If there are repeated variables, take the *last* one (could be name shadowing
211-- in a where clause, so take the most recent).
213toPats :: Bool -> Term -> [Pat]
214toPats tc f = reverse (toPat tc (getArgs f)) where
215 getArgs (App f a) = a : getArgs f
216 getArgs _ = []
218toPat :: Bool -> [Term] -> [Pat]
219toPat tc tms = evalState (mapM (\x -> toPat' x []) tms) []
220 where
221 toPat' (P (DCon t a) n _) args = do args' <- mapM (\x -> toPat' x []) args
222 return $ PCon n t args'
223 -- Typecase
224 toPat' (P (TCon t a) n _) args | tc
225 = do args' <- mapM (\x -> toPat' x []) args
226 return $ PCon n t args'
227 toPat' (Constant IType) [] | tc = return $ PCon (UN "Int") 1 []
228 toPat' (Constant FlType) [] | tc = return $ PCon (UN "Float") 2 []
229 toPat' (Constant ChType) [] | tc = return $ PCon (UN "Char") 3 []
230 toPat' (Constant StrType) [] | tc = return $ PCon (UN "String") 4 []
231 toPat' (Constant PtrType) [] | tc = return $ PCon (UN "Ptr") 5 []
232 toPat' (Constant BIType) [] | tc = return $ PCon (UN "Integer") 6 []
233 toPat' (Constant W8Type) [] | tc = return $ PCon (UN "Word8") 7 []
234 toPat' (Constant W16Type) [] | tc = return $ PCon (UN "Word16") 8 []
236 toPat' (P Bound n _) [] = do ns <- get
237 if n `elem` ns
238 then return PAny
239 else do put (n : ns)
240 return (PV n)
241 toPat' (App f a) args = toPat' f (a : args)
242 toPat' (Constant x) [] = return $ PConst x
243 toPat' _ _ = return PAny
246data Partition = Cons [Clause]
247 | Vars [Clause]
248 deriving Show
250isVarPat (PV _ : ps , _) = True
251isVarPat (PAny : ps , _) = True
252isVarPat _ = False
254isConPat (PCon _ _ _ : ps, _) = True
255isConPat (PConst _ : ps, _) = True
256isConPat _ = False
258partition :: [Clause] -> [Partition]
259partition [] = []
260partition ms@(m : _)
261 | isVarPat m = let (vars, rest) = span isVarPat ms in
262 Vars vars : partition rest
263 | isConPat m = let (cons, rest) = span isConPat ms in
264 Cons cons : partition rest
265partition xs = error $ "Partition " ++ show xs
267match :: [Name] -> [Clause] -> SC -- error case
268 -> State CS SC
269match [] (([], ret) : xs) err
270 = do (ts, v) <- get
271 put (ts ++ (map (fst.snd) xs), v)
272 case snd ret of
273 Impossible -> return ImpossibleCase
274 tm -> return $ STerm tm -- run out of arguments
275match vs cs err = do let ps = partition cs
276 cs <- mixture vs ps err
277 return cs
279mixture :: [Name] -> [Partition] -> SC -> State CS SC
280mixture vs [] err = return err
281mixture vs (Cons ms : ps) err = do fallthrough <- mixture vs ps err
282 conRule vs ms fallthrough
283mixture vs (Vars ms : ps) err = do fallthrough <- mixture vs ps err
284 varRule vs ms fallthrough
286data ConType = CName Name Int -- named constructor
287 | CConst Const -- constant, not implemented yet
289data Group = ConGroup ConType -- Constructor
290 [([Pat], Clause)] -- arguments and rest of alternative
292conRule :: [Name] -> [Clause] -> SC -> State CS SC
293conRule (v:vs) cs err = do groups <- groupCons cs
294 caseGroups (v:vs) groups err
296caseGroups :: [Name] -> [Group] -> SC -> State CS SC
297caseGroups (v:vs) gs err = do g <- altGroups gs
298 return $ Case v (sort g)
299 where
300 altGroups [] = return [DefaultCase err]
301 altGroups (ConGroup (CName n i) args : cs)
302 = do g <- altGroup n i args
303 rest <- altGroups cs
304 return (g : rest)
305 altGroups (ConGroup (CConst c) args : cs)
306 = do g <- altConstGroup c args
307 rest <- altGroups cs
308 return (g : rest)
310 altGroup n i gs = do (newArgs, nextCs) <- argsToAlt gs
311 matchCs <- match (newArgs ++ vs) nextCs err
312 return $ ConCase n i newArgs matchCs
313 altConstGroup n gs = do (_, nextCs) <- argsToAlt gs
314 matchCs <- match vs nextCs err
315 return $ ConstCase n matchCs
317argsToAlt :: [([Pat], Clause)] -> State CS ([Name], [Clause])
318argsToAlt [] = return ([], [])
319argsToAlt rs@((r, m) : rest)
320 = do newArgs <- getNewVars r
321 return (newArgs, addRs rs)
322 where
323 getNewVars [] = return []
324 getNewVars ((PV n) : ns) = do v <- getVar
325 nsv <- getNewVars ns
326 return (v : nsv)
327 getNewVars (_ : ns) = do v <- getVar
328 nsv <- getNewVars ns
329 return (v : nsv)
330 addRs [] = []
331 addRs ((r, (ps, res)) : rs) = ((r++ps, res) : addRs rs)
333 uniq i (UN n) = MN i n
334 uniq i n = n
336getVar :: State CS Name
337getVar = do (t, v) <- get; put (t, v+1); return (MN v "e")
339groupCons :: [Clause] -> State CS [Group]
340groupCons cs = gc [] cs
341 where
342 gc acc [] = return acc
343 gc acc ((p : ps, res) : cs) =
344 do acc' <- addGroup p ps res acc
345 gc acc' cs
346 addGroup p ps res acc = case p of
347 PCon con i args -> return $ addg con i args (ps, res) acc
348 PConst cval -> return $ addConG cval (ps, res) acc
349 pat -> fail $ show pat ++ " is not a constructor or constant (can't happen)"
351 addg con i conargs res [] = [ConGroup (CName con i) [(conargs, res)]]
352 addg con i conargs res (g@(ConGroup (CName n j) cs):gs)
353 | i == j = ConGroup (CName n i) (cs ++ [(conargs, res)]) : gs
354 | otherwise = g : addg con i conargs res gs
356 addConG con res [] = [ConGroup (CConst con) [([], res)]]
357 addConG con res (g@(ConGroup (CConst n) cs) : gs)
358 | con == n = ConGroup (CConst n) (cs ++ [([], res)]) : gs
359 | otherwise = g : addConG con res gs
361varRule :: [Name] -> [Clause] -> SC -> State CS SC
362varRule (v : vs) alts err =
363 do let alts' = map (repVar v) alts
364 match vs alts' err
365 where
366 repVar v (PV p : ps , (lhs, res)) = (ps, (lhs, subst p (P Bound v Erased) res))
367 repVar v (PAny : ps , res) = (ps, res)
369-- fix: case e of S k -> f (S k) ==> case e of S k -> f e
370depatt :: [Name] -> SC -> SC
371depatt ns tm = dp [] tm
372 where
373 dp ms (STerm tm) = STerm (applyMaps ms tm)
374 dp ms (Case x alts) = Case x (map (dpa ms x) alts)
375 dp ms sc = sc
377 dpa ms x (ConCase n i args sc)
378 = ConCase n i args (dp ((x, (n, args)) : ms) sc)
379 dpa ms x (ConstCase c sc) = ConstCase c (dp ms sc)
380 dpa ms x (DefaultCase sc) = DefaultCase (dp ms sc)
382 applyMaps ms f@(App _ _)
383 | (P nt cn pty, args) <- unApply f
384 = let args' = map (applyMaps ms) args in
385 applyMap ms nt cn pty args'
386 where
387 applyMap [] nt cn pty args' = mkApp (P nt cn pty) args'
388 applyMap ((x, (n, args)) : ms) nt cn pty args'
389 | and ((length args == length args') :
390 (n == cn) : zipWith same args args') = P Ref x Erased
391 | otherwise = applyMap ms nt cn pty args'
392 same n (P _ n' _) = n == n'
393 same _ _ = False
394 applyMaps ms (App f a) = App (applyMaps ms f) (applyMaps ms a)
395 applyMaps ms t = t
397prune :: Bool -> -- ^ Convert single branches to projections (only useful at runtime)
398 SC -> SC
399prune proj (Case n alts)
400 = let alts' = filter notErased (map pruneAlt alts) in
401 case alts' of
402 [] -> ImpossibleCase
403 as@[ConCase cn i args sc] -> if proj then mkProj n 0 args sc
404 else Case n as
405 as -> Case n as
406 where pruneAlt (ConCase cn i ns sc) = ConCase cn i ns (prune proj sc)
407 pruneAlt (ConstCase c sc) = ConstCase c (prune proj sc)
408 pruneAlt (DefaultCase sc) = DefaultCase (prune proj sc)
410 notErased (DefaultCase (STerm Erased)) = False
411 notErased (DefaultCase ImpossibleCase) = False
412 notErased _ = True
414 mkProj n i [] sc = sc
415 mkProj n i (x : xs) sc = mkProj n (i + 1) xs (projRep x n i sc)
417 projRep :: Name -> Name -> Int -> SC -> SC
418 projRep arg n i (Case x alts)
419 | x == arg = ProjCase (Proj (P Bound n Erased) i)
420 (map (projRepAlt arg n i) alts)
421 | otherwise = Case x (map (projRepAlt arg n i) alts)
422 projRep arg n i (ProjCase t alts)
423 = ProjCase (projRepTm arg n i t) (map (projRepAlt arg n i) alts)
424 projRep arg n i (STerm t) = STerm (projRepTm arg n i t)
425 projRep arg n i c = c -- unmatched
427 projRepAlt arg n i (ConCase cn t args rhs)
428 = ConCase cn t args (projRep arg n i rhs)
429 projRepAlt arg n i (ConstCase t rhs)
430 = ConstCase t (projRep arg n i rhs)
431 projRepAlt arg n i (DefaultCase rhs)
432 = DefaultCase (projRep arg n i rhs)
434 projRepTm arg n i t = subst arg (Proj (P Bound n Erased) i) t
436prune _ t = t
438stripLambdas :: CaseDef -> CaseDef
439stripLambdas (CaseDef ns (STerm (Bind x (Lam _) sc)) tm)
440 = stripLambdas (CaseDef (ns ++ [x]) (STerm (instantiate (P Bound x Erased) sc)) tm)
441stripLambdas x = x