git.iko.soy/Idris-dev
on f0f566f help sign in
Idris-dev/src/IRTS/Compiler.hs
792 lines 29 kB history raw
1{-|
2Module : IRTS.Compiler
3Description : Coordinates the compilation process.
5License : BSD3
6Maintainer : The Idris Community.
7-}
8{-# LANGUAGE CPP, FlexibleContexts, PatternGuards, TypeSynonymInstances, NamedFieldPuns, MultiWayIf #-}
10module IRTS.Compiler(compile, generate) where
12import Idris.AbsSyntax
13import Idris.ASTUtils
14import Idris.Core.CaseTree
15import Idris.Core.Evaluate
16import Idris.Core.TT
17import Idris.Erasure
18import Idris.Error
19import Idris.Options
20import Idris.Output
21import IRTS.CodegenC
22import IRTS.CodegenCommon
23import IRTS.Defunctionalise
24import IRTS.DumpBC
25import IRTS.Exports
26import IRTS.Inliner
27import IRTS.LangOpts
28import IRTS.Portable
29import IRTS.Simplified
31import Prelude hiding (id, (.))
33import Control.Category
34import Control.Monad.State
35import Data.List
36import Data.Maybe (maybe)
37import qualified Data.Map as M
38import Data.Ord
39import qualified Data.Set as S
40import System.Directory
41import System.Exit
42import System.IO
43import System.Process
45-- | Compile to simplified forms and return CodegenInfo
46compile :: Codegen -> FilePath -> Maybe Term -> Idris CodegenInfo
47compile codegen f mtm = do
48 logCodeGen 1 "Compiling Output."
49 iReport 2 "Compiling Output."
50 checkMVs -- check for undefined metavariables
51 checkTotality -- refuse to compile if there are totality problems
52 exports <- findExports
53 let rootNames = case mtm of
54 Nothing -> []
55 Just t -> freeNames t
57 logCodeGen 1 "Running Erasure Analysis"
58 iReport 3 "Running Erasure Analysis"
59 reachableNames <- performUsageAnalysis
60 (rootNames ++ getExpNames exports)
61 maindef <- case mtm of
62 Nothing -> return []
63 Just tm -> do md <- irMain tm
64 logCodeGen 1 $ "MAIN: " ++ show md
65 return [(sMN 0 "runMain", md)]
66 objs <- getObjectFiles codegen
67 libs <- getLibs codegen
68 flags <- getFlags codegen
69 hdrs <- getHdrs codegen
70 impdirs <- rankedImportDirs f
71 ttDeclarations <- getDeclarations reachableNames
72 defsIn <- mkDecls reachableNames
73 -- if no 'main term' given, generate interface files
74 let iface = case mtm of
75 Nothing -> True
76 Just _ -> False
78 let defs = defsIn ++ maindef
80 -- Inlined top level LDecl made here
81 let defsInlined = inlineAll defs
82 let defsUniq = map (allocUnique (addAlist defsInlined emptyContext))
83 defsInlined
85 logCodeGen 1 "Inlining"
87 dumpCases <- getDumpCases
88 case dumpCases of
89 Nothing -> return ()
90 Just f -> runIO $ writeFile f (showCaseTrees defsUniq)
92 let (nexttag, tagged) = addTags 65536 (liftAll defsInlined)
93 let ctxtIn = addAlist tagged emptyContext
95 logCodeGen 1 "Defunctionalising"
96 iReport 3 "Defunctionalising"
97 let defuns_in = defunctionalise nexttag ctxtIn
98 logCodeGen 5 $ show defuns_in
99 logCodeGen 1 "Inlining"
100 iReport 3 "Inlining"
101 let defuns = inline defuns_in
102 logCodeGen 5 $ show defuns
103 logCodeGen 1 "Resolving variables for CG"
105 let checked = simplifyDefs defuns (toAlist defuns)
106 outty <- outputTy
107 dumpDefun <- getDumpDefun
108 case dumpDefun of
109 Nothing -> return ()
110 Just f -> runIO $ writeFile f (dumpDefuns defuns)
111 triple <- Idris.AbsSyntax.targetTriple
112 cpu <- Idris.AbsSyntax.targetCPU
113 logCodeGen 1 "Generating Code."
114 iReport 2 "Generating Code."
115 case checked of
116 OK c -> do return $ CodegenInfo f outty triple cpu
117 hdrs impdirs objs libs flags
118 NONE c (toAlist defuns)
119 tagged iface exports
120 ttDeclarations
121 Error e -> ierror e
122 where checkMVs = do i <- getIState
123 case map fst (idris_metavars i) \\ primDefs of
124 [] -> return ()
125 ms -> do iputStrLn $ "WARNING: There are incomplete holes:\n " ++ show ms
126 iputStrLn "\nEvaluation of any of these will crash at run time."
127 return ()
128 checkTotality = do i <- getIState
129 case idris_totcheckfail i of
130 [] -> return ()
131 ((fc, msg):fs) -> ierror . At fc . Msg $ "Cannot compile:\n " ++ msg
133generate :: Codegen -> FilePath -> CodegenInfo -> IO ()
134generate codegen mainmod ir
135 = case codegen of
136 -- Built-in code generators (FIXME: lift these out!)
137 Via _ "c" -> codegenC ir
138 -- Any external code generator
139 Via fm cg -> do input <- case fm of
140 IBCFormat -> return mainmod
141 JSONFormat -> do
142 tempdir <- getTemporaryDirectory
143 (fn, h) <- openTempFile tempdir "idris-cg.json"
144 writePortable h ir
145 hClose h
146 return fn
147 let cmd = "idris-codegen-" ++ cg
148 args = [input, "-o", outputFile ir] ++ compilerFlags ir
149 exit <- rawSystem cmd (if interfaces ir then "--interface" : args else args)
150 when (exit /= ExitSuccess) $
151 putStrLn ("FAILURE: " ++ show cmd ++ " " ++ show args)
152 Bytecode -> dumpBC (simpleDecls ir) (outputFile ir)
154irMain :: TT Name -> Idris LDecl
155irMain tm = do
156 i <- irTerm (sMN 0 "runMain") M.empty [] tm
157 return $ LFun [] (sMN 0 "runMain") [] (LForce i)
159mkDecls :: [Name] -> Idris [(Name, LDecl)]
160mkDecls used
161 = do i <- getIState
162 let ds = filter (\(n, d) -> n `elem` used || isCon d) $ ctxtAlist (tt_ctxt i)
163 decls <- mapM build ds
164 return decls
166getDeclarations :: [Name] -> Idris ([(Name, TTDecl)])
167getDeclarations used
168 = do i <- getIState
169 let ds = filter (\(n, (d,_,_,_,_,_)) -> n `elem` used || isCon d) $ ((toAlist . definitions . tt_ctxt) i)
170 return ds
172showCaseTrees :: [(Name, LDecl)] -> String
173showCaseTrees = showSep "\n\n" . map showCT . sortBy (comparing defnRank)
174 where
175 showCT (n, LFun opts f args lexp)
176 = showOpts ++
177 show n ++ " " ++ showSep " " (map show args) ++ " =\n\t"
178 ++ show lexp
179 where
180 showOpts | Inline `elem` opts = "%inline "
181 | otherwise = ""
182 showCT (n, LConstructor c t a) = "data " ++ show n ++ " " ++ show a
184 defnRank :: (Name, LDecl) -> String
185 defnRank (n, LFun _ _ _ _) = "1" ++ nameRank n
186 defnRank (n, LConstructor _ _ _) = "2" ++ nameRank n
188 nameRank :: Name -> String
189 nameRank (UN s) = "1" ++ show s
190 nameRank (MN i s) = "2" ++ show s ++ show i
191 nameRank (NS n ns) = "3" ++ concatMap show (reverse ns) ++ nameRank n
192 nameRank (SN sn) = "4" ++ snRank sn
193 nameRank n = "5" ++ show n
195 snRank :: SpecialName -> String
196 snRank (WhereN i n n') = "1" ++ nameRank n' ++ nameRank n ++ show i
197 snRank (ImplementationN n args) = "2" ++ nameRank n ++ concatMap show args
198 snRank (ParentN n s) = "3" ++ nameRank n ++ show s
199 snRank (MethodN n) = "4" ++ nameRank n
200 snRank (CaseN _ n) = "5" ++ nameRank n
201 snRank (ImplementationCtorN n) = "7" ++ nameRank n
202 snRank (WithN i n) = "8" ++ nameRank n ++ show i
204isCon (TyDecl _ _) = True
205isCon _ = False
207build :: (Name, Def) -> Idris (Name, LDecl)
208build (n, d)
209 = do i <- getIState
210 case getPrim n i of
211 Just (ar, op) ->
212 let args = map (\x -> sMN x "op") [0..] in
213 return (n, (LFun [] n (take ar args)
214 (LOp op (map LV (take ar args)))))
215 _ -> do def <- mkLDecl n d
216 logCodeGen 3 $ "Compiled " ++ show n ++ " =\n\t" ++ show def
217 return (n, def)
218 where getPrim n i
219 | Just (ar, op) <- lookup n (idris_scprims i)
220 = Just (ar, op)
221 | Just ar <- lookup n (S.toList (idris_externs i))
222 = Just (ar, LExternal n)
223 getPrim n i = Nothing
225declArgs args inl n (LLam xs x) = declArgs (args ++ xs) inl n x
226declArgs args inl n x = LFun (if inl then [Inline] else []) n args x
228mkLDecl n (Function tm _)
229 = declArgs [] True n <$> irTerm n M.empty [] tm
231mkLDecl n (CaseOp ci _ _ _ pats cd)
232 = declArgs [] (case_inlinable ci || caseName n) n <$> irTree n args sc
233 where
234 (args, sc) = cases_runtime cd
236 -- Always attempt to inline functions arising from 'case' expressions
237 caseName (SN (CaseN _ _)) = True
238 caseName (SN (WithN _ _)) = True
239 caseName (NS n _) = caseName n
240 caseName _ = False
242mkLDecl n (TyDecl (DCon tag arity _) _) =
243 LConstructor n tag . length <$> fgetState (cg_usedpos . ist_callgraph n)
245mkLDecl n (TyDecl (TCon t a) _) = return $ LConstructor n (-1) a
246mkLDecl n _ = return $ (declArgs [] True n LNothing) -- postulate, never run
248data VarInfo = VI
249 { viMethod :: Maybe Name
250 }
251 deriving Show
253type Vars = M.Map Name VarInfo
255irTerm :: Name -> Vars -> [Name] -> Term -> Idris LExp
256irTerm top vs env tm@(App _ f a) = do
257 ist <- getIState
258 case unApply tm of
259 (P _ n _, args)
260 | n `elem` map fst (idris_metavars ist) \\ primDefs
261 -> return $ LError $ "ABORT: Attempt to evaluate hole " ++ show n
262 (P _ (UN m) _, args)
263 | m == txt "mkForeignPrim"
264 -> doForeign vs env (reverse (drop 4 args)) -- drop implicits
266 (P _ (UN u) _, [_, arg])
267 | u == txt "unsafePerformPrimIO"
268 -> irTerm top vs env arg
270 (P _ (UN u) _, _)
271 | u == txt "assert_unreachable"
272 -> return $ LError $ "ABORT: Reached an unreachable case in " ++ show top
274 (P _ (UN u) _, [_, msg])
275 | u == txt "idris_crash"
276 -> do msg' <- irTerm top vs env msg
277 return $ LOp LCrash [msg']
279 -- TMP HACK - until we get inlining.
280 (P _ (UN r) _, [_, _, _, _, _, arg])
281 | r == txt "replace"
282 -> irTerm top vs env arg
284 -- 'void' doesn't have any pattern clauses and only gets called on
285 -- erased things in higher order contexts (also a TMP HACK...)
286 (P _ (UN r) _, _)
287 | r == txt "void"
288 -> return LNothing
290 -- Laziness, the old way
291 (P _ (UN l) _, [_, arg])
292 | l == txt "lazy"
293 -> error "lazy has crept in somehow"
295 (P _ (UN l) _, [_, arg])
296 | l == txt "force"
297 -> LForce <$> irTerm top vs env arg
299 -- Laziness, the new way
300 (P _ (UN l) _, [_, _, arg])
301 | l == txt "Delay"
302 -> LLazyExp <$> irTerm top vs env arg
304 (P _ (UN l) _, [_, _, arg])
305 | l == txt "Force"
306 -> LForce <$> irTerm top vs env arg
308 (P _ (UN a) _, [_, _, _, arg])
309 | a == txt "assert_smaller"
310 -> irTerm top vs env arg
312 (P _ (UN a) _, [_, arg])
313 | a == txt "assert_total"
314 -> irTerm top vs env arg
316 (P _ (UN p) _, [_, arg])
317 | p == txt "par"
318 -> do arg' <- irTerm top vs env arg
319 return $ LOp LPar [LLazyExp arg']
321 (P _ (UN pf) _, [arg])
322 | pf == txt "prim_fork"
323 -> do arg' <- irTerm top vs env arg
324 return $ LOp LFork [LLazyExp arg']
326 (P _ (UN m) _, [_,size,t])
327 | m == txt "malloc"
328 -> irTerm top vs env t
330 (P _ (UN tm) _, [_,t])
331 | tm == txt "trace_malloc"
332 -> irTerm top vs env t -- TODO
334 -- This case is here until we get more general inlining. It's just
335 -- a really common case, and the laziness hurts...
336 (P _ (NS (UN be) [b,p]) _, [_,x,(App _ (App _ (App _ (P _ (UN d) _) _) _) t),
337 (App _ (App _ (App _ (P _ (UN d') _) _) _) e)])
338 | be == txt "ifThenElse"
339 , d == txt "Delay"
340 , d' == txt "Delay"
341 , b == txt "Bool"
342 , p == txt "Prelude"
343 -> do
344 x' <- irTerm top vs env x
345 t' <- irTerm top vs env t
346 e' <- irTerm top vs env e
347 return (LCase Shared x'
348 [LConCase 0 (sNS (sUN "False") ["Bool","Prelude"]) [] e'
349 ,LConCase 1 (sNS (sUN "True" ) ["Bool","Prelude"]) [] t'
350 ])
352 -- data constructor
353 (P (DCon t arity _) n _, args) -> do
354 detag <- fgetState (opt_detaggable . ist_optimisation n)
355 used <- map fst <$> fgetState (cg_usedpos . ist_callgraph n)
357 let isNewtype = length used == 1 && detag
358 let argsPruned = [a | (i,a) <- zip [0..] args, i `elem` used]
360 -- The following code removes fields from data constructors
361 -- and performs the newtype optimisation.
362 --
363 -- The general rule here is:
364 -- Everything we get as input is not touched by erasure,
365 -- so it conforms to the official arities and types
366 -- and we can reason about it like it's plain TT.
367 --
368 -- It's only the data that leaves this point that's erased
369 -- and possibly no longer typed as the original TT version.
370 --
371 -- Especially, underapplied constructors must yield functions
372 -- even if all the remaining arguments are erased
373 -- (the resulting function *will* be applied, to NULLs).
374 --
375 -- This will probably need rethinking when we get erasure from functions.
377 -- "padLams" will wrap our term in LLam-bdas and give us
378 -- the "list of future unerased args" coming from these lambdas.
379 --
380 -- We can do whatever we like with the list of unerased args,
381 -- hence it takes a lambda: \unerased_argname_list -> resulting_LExp.
382 let padLams = padLambdas used (length args) arity
384 case compare (length args) arity of
386 -- overapplied
387 GT -> ifail ("overapplied data constructor: " ++ show tm ++
388 "\nDEBUG INFO:\n" ++
389 "Arity: " ++ show arity ++ "\n" ++
390 "Arguments: " ++ show args ++ "\n" ++
391 "Pruned arguments: " ++ show argsPruned)
393 -- exactly saturated
394 EQ | isNewtype
395 -> irTerm top vs env (head argsPruned)
397 -- compile Nat-likes as bigints
398 | Just LikeZ <- isLikeNat ist n
399 -> irTerm top vs env $ Constant (BI 0)
401 -- compile Nat-likes as bigints
402 | Just LikeS <- isLikeNat ist n
403 -> irTerm top vs env $ mkApp
404 (P Ref (sUN "prim__addBigInt") Erased)
405 (Constant (BI 1) : argsPruned)
407 | otherwise -- not newtype, plain data ctor
408 -> buildApp (LV n) argsPruned
410 -- not saturated, underapplied
411 LT | isNewtype -- newtype
412 , length argsPruned == 1 -- and we already have the value
413 -> padLams . (\tm [] -> tm) -- the [] asserts there are no unerased args
414 <$> irTerm top vs env (head argsPruned)
416 | isNewtype -- newtype but the value is not among args yet
417 -> return . padLams $ \[vn] -> LApp False (LV n) [LV vn]
419 -- compile Nat-likes as bigints
420 | Just LikeS <- isLikeNat ist n
421 -> irTerm top vs env $
422 App Complete (P Ref (sUN "prim__addBigInt") Erased) (Constant $ BI 1)
424 -- not a newtype, just apply to a constructor
425 | otherwise
426 -> padLams . applyToNames <$> buildApp (LV n) argsPruned
428 -- type constructor
429 (P (TCon t a) n _, args) -> return LNothing
431 -- an external name applied to arguments
432 (P _ n _, args) | S.member (n, length args) (idris_externs ist) -> do
433 LOp (LExternal n) <$> mapM (irTerm top vs env) args
435 -- a name applied to arguments
436 (P _ n _, args) -> do
437 case lookup n (idris_scprims ist) of
438 -- if it's a primitive that is already saturated,
439 -- compile to the corresponding op here already to save work
440 Just (arity, op) | length args == arity
441 -> LOp op <$> mapM (irTerm top vs env) args
443 -- otherwise, just apply the name
444 _ -> applyName n ist args
446 -- turn de bruijn vars into regular named references and try again
447 (V i, args) -> irTerm top vs env $ mkApp (P Bound (env !! i) Erased) args
449 (f, args)
450 -> LApp False
451 <$> irTerm top vs env f
452 <*> mapM (irTerm top vs env) args
454 where
455 buildApp :: LExp -> [Term] -> Idris LExp
456 buildApp e [] = return e
457 buildApp e xs = LApp False e <$> mapM (irTerm top vs env) xs
459 applyToNames :: LExp -> [Name] -> LExp
460 applyToNames tm [] = tm
461 applyToNames tm ns = LApp False tm $ map LV ns
463 padLambdas :: [Int] -> Int -> Int -> ([Name] -> LExp) -> LExp
464 padLambdas used startIdx endSIdx mkTerm
465 = LLam allNames $ mkTerm nonerasedNames
466 where
467 allNames = [sMN i "sat" | i <- [startIdx .. endSIdx-1]]
468 nonerasedNames = [sMN i "sat" | i <- [startIdx .. endSIdx-1], i `elem` used]
470 applyName :: Name -> IState -> [Term] -> Idris LExp
471 applyName n ist args =
472 LApp False (LV n) <$> mapM (irTerm top vs env . erase) (zip [0..] args)
473 where
474 erase (i, x)
475 | i >= arity || i `elem` used = x
476 | otherwise = Erased
478 arity = case fst4 <$> lookupCtxtExact n (definitions . tt_ctxt $ ist) of
479 Just (CaseOp ci ty tys def tot cdefs) -> length tys
480 Just (TyDecl (DCon tag ar _) _) -> ar
481 Just (TyDecl Ref ty) -> length $ getArgTys ty
482 Just (Operator ty ar op) -> ar
483 Just def -> error $ "unknown arity: " ++ show (n, def)
484 Nothing -> 0 -- no definition, probably local name => can't erase anything
486 -- name for purposes of usage info lookup
487 uName
488 | Just n' <- viMethod =<< M.lookup n vs = n'
489 | otherwise = n
491 used = maybe [] (map fst . usedpos) $ lookupCtxtExact uName (idris_callgraph ist)
492 fst4 (x,_,_,_,_,_) = x
494irTerm top vs env (P _ n _) = return $ LV n
495irTerm top vs env (V i)
496 | i >= 0 && i < length env = return $ LV (env!!i)
497 | otherwise = ifail $ "bad de bruijn index: " ++ show i
499irTerm top vs env (Bind n (Lam _ _) sc) = LLam [n'] <$> irTerm top vs (n':env) sc
500 where
501 n' = uniqueName n env
503irTerm top vs env (Bind n (Let _ _ v) sc)
504 = LLet n <$> irTerm top vs env v <*> irTerm top vs (n : env) sc
506irTerm top vs env (Bind _ _ _) = return $ LNothing
508irTerm top vs env (Proj t (-1)) = do
509 t' <- irTerm top vs env t
510 return $ LOp (LMinus (ATInt ITBig))
511 [t', LConst (BI 1)]
513irTerm top vs env (Proj t i) = LProj <$> irTerm top vs env t <*> pure i
514irTerm top vs env (Constant TheWorld) = return LNothing
515irTerm top vs env (Constant c) = return (LConst c)
516irTerm top vs env (TType _) = return LNothing
517irTerm top vs env Erased = return LNothing
518irTerm top vs env Impossible = return LNothing
520data LikeNat = LikeZ | LikeS
522isLikeNat :: IState -> Name -> Maybe LikeNat
523isLikeNat ist cn
524 | Just cTy <- lookupTyExact cn $ tt_ctxt ist
525 , (P TCon{} tyN _, _) <- unApply $ getRetTy cTy
526 , Just (z, s) <- natLikeCtors tyN cTy
527 = if | cn == z -> Just LikeZ
528 | cn == s -> Just LikeS
529 | otherwise -> error $ "isLikeNat: constructor not found in its own family: " ++ show (cn, tyN)
531 | otherwise = Nothing
532 where
533 natLikeCtors :: Name -> Type -> Maybe (Name, Name)
534 natLikeCtors tyN cTy = case lookupCtxtExact tyN $ idris_datatypes ist of
535 Just TI{con_names = [z, s]}
536 | 0 <- getUsedCount z
537 , looksLikeS tyN s cTy
538 -> Just (z, s)
540 Just TI{con_names = [s, z]}
541 | 0 <- getUsedCount z
542 , looksLikeS tyN s cTy
543 -> Just (z, s)
545 _ -> Nothing
547 getUsedCount :: Name -> Int
548 getUsedCount n =
549 maybe 0 (length . usedpos)
550 $ lookupCtxtExact n
551 $ idris_callgraph ist
553 looksLikeS :: Name -> Name -> Type -> Bool
554 looksLikeS tyN cn cTy
555 | Just [(i, _)] <- fmap usedpos $ lookupCtxtExact cn $ idris_callgraph ist
556 , [recTy] <- [recTy | (j, (_n, recTy)) <- zip [0..] (getArgTys cTy), j == i]
557 , (P TCon{} recTyN _, _) <- unApply recTy
558 , recTyN == tyN
559 = True
561 | otherwise = False
563doForeign :: Vars -> [Name] -> [Term] -> Idris LExp
564doForeign vs env (ret : fname : world : args)
565 = do args' <- mapM splitArg args
566 let fname' = toFDesc fname
567 let ret' = toFDesc ret
568 return $ LForeign ret' fname' args'
569 where
570 splitArg tm | (_, [_,_,l,r]) <- unApply tm -- pair, two implicits
571 = do let l' = toFDesc l
572 r' <- irTerm (sMN 0 "__foreignCall") vs env r
573 return (l', r')
574 splitArg _ = ifail $ "Badly formed foreign function call: " ++
575 show (ret : fname : world : args)
578 toFDesc (Constant (Str str)) = FStr str
579 toFDesc tm
580 | (P _ n _, []) <- unApply tm = FCon (deNS n)
581 | (P _ n _, as) <- unApply tm = FApp (deNS n) (map toFDesc as)
582 toFDesc _ = FUnknown
584 deNS (NS n _) = n
585 deNS n = n
586doForeign vs env xs = ifail "Badly formed foreign function call"
588irTree :: Name -> [Name] -> SC -> Idris LExp
589irTree top args tree = do
590 logCodeGen 3 $ "Compiling " ++ show args ++ "\n" ++ show tree
591 LLam args <$> irSC top M.empty tree
593irSC :: Name -> Vars -> SC -> Idris LExp
594irSC top vs (STerm t) = irTerm top vs [] t
595irSC top vs (UnmatchedCase str) = return $ LError str
597irSC top vs (ProjCase tm alts) = do
598 tm' <- irTerm top vs [] tm
599 alts' <- mapM (irAlt top vs tm') alts
600 return $ LCase Shared tm' alts'
602-- Transform matching on Delay to applications of Force.
603irSC top vs (Case up n [ConCase (UN delay) i [_, _, n'] sc])
604 | delay == txt "Delay"
605 = do sc' <- irSC top vs sc -- mkForce n' n sc
606 return $ lsubst n' (LForce (LV n)) sc'
608-- There are two transformations in this case:
609--
610-- 1. Newtype-case elimination:
611-- case {e0} of
612-- wrap({e1}) -> P({e1}) ==> P({e0})
613--
614-- This is important because newtyped constructors are compiled away entirely
615-- and we need to do that everywhere.
616--
617-- 2. Unused-case elimination (only valid for singleton branches):
618-- case {e0} of ==> P
619-- C(x,y) -> P[... x,y not used ...]
620--
621-- This is important for runtime because sometimes we case on irrelevant data:
622--
623-- In the example above, {e0} will most probably have been erased
624-- so this vain projection would make the resulting program segfault
625-- because the code generator still emits a PROJECT(...) G-machine instruction.
626--
627-- Hence, we check whether the variables are used at all
628-- and erase the casesplit if they are not.
629--
630irSC top vs (Case up n [alt]) = do
631 replacement <- case alt of
632 ConCase cn a ns sc -> do
633 detag <- fgetState (opt_detaggable . ist_optimisation cn)
634 used <- map fst <$> fgetState (cg_usedpos . ist_callgraph cn)
635 if detag && length used == 1
636 then return . Just $ substSC (ns !! head used) n sc
637 else return Nothing
638 _ -> return Nothing
640 case replacement of
641 Just sc -> irSC top vs sc
642 _ -> do
643 alt' <- irAlt top vs (LV n) alt
644 return $ case namesBoundIn alt' `usedIn` subexpr alt' of
645 [] -> subexpr alt' -- strip the unused top-most case
646 _ -> LCase up (LV n) [alt']
647 where
648 namesBoundIn :: LAlt -> [Name]
649 namesBoundIn (LConCase cn i ns sc) = ns
650 namesBoundIn (LConstCase c sc) = []
651 namesBoundIn (LDefaultCase sc) = []
653 subexpr :: LAlt -> LExp
654 subexpr (LConCase _ _ _ e) = e
655 subexpr (LConstCase _ e) = e
656 subexpr (LDefaultCase e) = e
658-- FIXME: When we have a non-singleton case-tree of the form
659--
660-- case {e0} of
661-- C(x) => ...
662-- ... => ...
663--
664-- and C is detaggable (the only constructor of the family), we can be sure
665-- that the first branch will be always taken -- so we add special handling
666-- to remove the dead default branch.
667--
668-- If we don't do so and C is newtype-optimisable, we will miss this newtype
669-- transformation and the resulting code will probably segfault.
670--
671-- This work-around is not entirely optimal; the best approach would be
672-- to ensure that such case trees don't arise in the first place.
673--
674irSC top vs (Case up n alts@[ConCase cn a ns sc, DefaultCase sc']) = do
675 detag <- fgetState (opt_detaggable . ist_optimisation cn)
676 if detag
677 then irSC top vs (Case up n [ConCase cn a ns sc])
678 else do
679 likeNat <- isLikeNat <$> getIState <*> pure cn
680 case likeNat of
681 -- the annoying case: LikeS is translated into a default case
682 -- so we need to change the original DefaultCase to Z-case
683 -- and reorder it before this one
684 Just LikeS -> do
685 zCase <- LConstCase (BI 0) <$> irSC top vs sc'
686 sCase <- irAlt top vs (LV n) (ConCase cn a ns sc)
687 return $ LCase up (LV n) [zCase, sCase]
689 -- the usual case
690 _ -> LCase up (LV n) <$> mapM (irAlt top vs (LV n)) alts
692irSC top vs sc@(Case up n alts) = do
693 ist <- getIState
695 if | [ConCase cns as nss scs, ConCase cnz az nsz scz] <- alts
696 , Just LikeS <- isLikeNat ist cns
697 -> do
698 -- reorder to make the Z case come first
699 zCase <- LConstCase (BI 0) <$> irSC top vs scz
700 sCase <- irAlt top vs (LV n) (ConCase cns as nss scs)
701 return $ LCase up (LV n) [zCase, sCase]
703 | otherwise -> do
704 -- check that neither alternative needs the newtype optimisation,
705 -- see comment above
706 goneWrong <- or <$> mapM isDetaggable alts
707 when goneWrong
708 $ ifail ("irSC: non-trivial case-match on detaggable data: " ++ show sc)
710 -- everything okay
711 LCase up (LV n) <$> mapM (irAlt top vs (LV n)) alts
712 where
713 isDetaggable (ConCase cn _ _ _) = fgetState $ opt_detaggable . ist_optimisation cn
714 isDetaggable _ = return False
716irSC top vs ImpossibleCase = return LNothing
718irAlt :: Name -> Vars -> LExp -> CaseAlt -> Idris LAlt
720-- this leaves out all unused arguments of the constructor
721irAlt top vs tm (ConCase n t args sc) = do
722 likeNat <- isLikeNat <$> getIState <*> pure n
723 used <- map fst <$> fgetState (cg_usedpos . ist_callgraph n)
724 let usedArgs = [a | (i,a) <- zip [0..] args, i `elem` used]
726 case likeNat of
727 -- like S
728 Just LikeS -> do
729 sc' <- irSC top vs sc
730 case usedArgs of
731 [pv] -> return $ LDefaultCase $ LLet pv
732 ( LOp
733 (LMinus (ATInt ITBig))
734 [ tm
735 , LConst (BI 1)
736 ]
737 )
738 sc'
740 _ -> ifail $ "irAlt/LikeS: multiple used args: " ++ show usedArgs
742 -- like Z
743 Just LikeZ -> LConstCase (BI 0) <$> irSC top vs sc
745 -- not like Nat
746 Nothing -> LConCase (-1) n usedArgs <$> irSC top (methodVars `M.union` vs) sc
747 where
748 methodVars = case n of
749 SN (ImplementationCtorN interfaceName)
750 -> M.fromList [(v, VI
751 { viMethod = Just $ mkFieldName n i
752 }) | (v,i) <- zip args [0..]]
753 _
754 -> M.empty -- not an implementation constructor
756irAlt top vs _ (ConstCase x rhs)
757 | matchable x = LConstCase x <$> irSC top vs rhs
758 | matchableTy x = LDefaultCase <$> irSC top vs rhs
759 where
760 matchable (I _) = True
761 matchable (BI _) = True
762 matchable (Ch _) = True
763 matchable (Str _) = True
764 matchable (B8 _) = True
765 matchable (B16 _) = True
766 matchable (B32 _) = True
767 matchable (B64 _) = True
768 matchable _ = False
770 matchableTy (AType (ATInt ITNative)) = True
771 matchableTy (AType (ATInt ITBig)) = True
772 matchableTy (AType (ATInt ITChar)) = True
773 matchableTy StrType = True
775 matchableTy (AType (ATInt (ITFixed IT8))) = True
776 matchableTy (AType (ATInt (ITFixed IT16))) = True
777 matchableTy (AType (ATInt (ITFixed IT32))) = True
778 matchableTy (AType (ATInt (ITFixed IT64))) = True
780 matchableTy _ = False
782irAlt top vs tm (SucCase n rhs) = do
783 rhs' <- irSC top vs rhs
784 return $ LDefaultCase (LLet n (LOp (LMinus (ATInt ITBig))
785 [tm,
786 LConst (BI 1)]) rhs')
788irAlt top vs _ (ConstCase c rhs)
789 = ifail $ "Can't match on (" ++ show c ++ ")"
791irAlt top vs _ (DefaultCase rhs)
792 = LDefaultCase <$> irSC top vs rhs