git.iko.soy/Idris-dev
on f88a377 help sign in
Idris-dev/libs/effects/Effect/Random.idr
47 lines 1.6 kB history raw
1module Effect.Random
3import Effects
4import Data.Vect
6data Random : Effect where
7 getRandom : sig Random Integer Integer
8 setSeed : Integer -> sig Random () Integer
10instance Handler Random m where
11 handle seed getRandom k
12 = let seed' = assert_total ((1664525 * seed + 1013904223) `prim__sremBigInt` (pow 2 32)) in
13 k seed' seed'
14 handle seed (setSeed n) k = k () n
16RND : EFFECT
17RND = MkEff Integer Random
19||| Generates a random Integer in a given range
20rndInt : Integer -> Integer -> Eff Integer [RND]
21rndInt lower upper = do v <- call $ getRandom
22 return ((v `prim__sremBigInt` (upper - lower)) + lower)
24||| Generate a random number in Fin (S `k`)
25|||
26||| Note that rndFin k takes values 0, 1, ..., k.
27rndFin : (k : Nat) -> Eff (Fin (S k)) [RND]
28rndFin k = do let v = assert_total $ !(call getRandom) `prim__sremBigInt` (cast (S k))
29 return (toFin v)
30 where toFin : Integer -> Fin (S k)
31 toFin x = case integerToFin x (S k) of
32 Just v => v
33 Nothing => toFin (assert_smaller x (x - cast (S k)))
35||| Select a random element from a vector
36rndSelect' : Vect (S k) a -> Eff a [RND]
37rndSelect' {k} xs = return (Vect.index !(rndFin k) xs)
39||| Select a random element from a list, or Nothing if the list is empty
40rndSelect : List a -> Eff (Maybe a) [RND]
41rndSelect [] = return Nothing
42rndSelect (x::xs) = return (Just !(rndSelect' (x::(fromList xs))))
44||| Sets the random seed
45srand : Integer -> Eff () [RND]
46srand n = call $ setSeed n