mirror of
https://github.com/LadybirdBrowser/ladybird.git
synced 2024-09-21 10:19:03 +03:00
22562b4b17
We were previously using TRY_COMPILE_TARGET_TYPE to bypass the compiler check at the beginning of the CMake build, since we don't have LibC available and therefore can't link at that point. However, this breaks a lot of assumptions in try_compile when it comes to library checks. While this was the main idea behind our usage of the flag, it also has some really nasty side effects when software wants to find out what library a symbol is in. Instead, just manually tell CMake that our compiler works as intended and keep the target type setting at its default.
48 lines
2.2 KiB
Plaintext
48 lines
2.2 KiB
Plaintext
list(APPEND CMAKE_MODULE_PATH "@SERENITY_SOURCE_DIR@/Toolchain/CMake")
|
|
|
|
set(CMAKE_SYSTEM_NAME SerenityOS)
|
|
set(CMAKE_SYSTEM_PROCESSOR "@SERENITY_ARCH@")
|
|
|
|
set(SERENITYOS 1)
|
|
set(triple @SERENITY_ARCH@-pc-serenity)
|
|
set(TOOLCHAIN_ROOT @SERENITY_SOURCE_DIR@/Toolchain/Local/clang/)
|
|
set(TOOLCHAIN_PATH ${TOOLCHAIN_ROOT}/bin)
|
|
|
|
# where to read from/write to
|
|
set(CMAKE_SYSROOT @SERENITY_BUILD_DIR@/Root)
|
|
set(CMAKE_STAGING_PREFIX @SERENITY_BUILD_DIR@/Root/usr/local)
|
|
set(CMAKE_INSTALL_PREFIX /usr/local)
|
|
set(CMAKE_INSTALL_DATAROOTDIR share)
|
|
|
|
set(CMAKE_C_COMPILER ${TOOLCHAIN_PATH}/clang)
|
|
set(CMAKE_C_COMPILER_TARGET ${triple})
|
|
set(CMAKE_CXX_COMPILER ${TOOLCHAIN_PATH}/clang++)
|
|
set(CMAKE_CXX_COMPILER_TARGET ${triple})
|
|
set(CMAKE_ASM_COMPILER ${TOOLCHAIN_PATH}/clang)
|
|
set(CMAKE_ASM_COMPILER_TARGET ${triple})
|
|
set(CMAKE_LINKER ${TOOLCHAIN_PATH}/ld.lld)
|
|
set(CMAKE_RANLIB ${TOOLCHAIN_PATH}/llvm-ranlib)
|
|
set(CMAKE_STRIP ${TOOLCHAIN_PATH}/llvm-strip)
|
|
set(CMAKE_AR ${TOOLCHAIN_PATH}/llvm-ar)
|
|
set(SERENITY_CXXFILT ${TOOLCHAIN_PATH}/llvm-cxxfilt)
|
|
# FIXME: Persuade LLVM maintainers to add `--update-section` to llvm-objcopy, as it's required for the kernel symbol map.
|
|
set(CMAKE_OBJCOPY ${TOOLCHAIN_PATH}/gnu-objcopy)
|
|
|
|
set(CMAKE_EXE_LINKER_FLAGS_INIT "-Wl,--hash-style=gnu,-z,relro,-z,now,-z,noexecstack,-z,max-page-size=0x1000,-z,separate-code")
|
|
|
|
# FIXME: We could eliminate this setting by building LibC and support asm files (crti.o, crtn.o)
|
|
# in a separate build stage before the main build to ensure that LibC is available
|
|
# for the try_compile check for the main build.
|
|
# Note that `set(CMAKE_TRY_COMPILE_TARGET_TYPE STATIC_LIBRARY)` is not a suitable replacement,
|
|
# since applications might try and use `try_compile()` to detect which library a symbol is in,
|
|
# which doesn't work when using static linking.
|
|
# Instead, just tell CMake directly that the compiler works fine, so that it doesn't have to run
|
|
# a compile check before the build.
|
|
set(CMAKE_C_COMPILER_WORKS TRUE)
|
|
set(CMAKE_CXX_COMPILER_WORKS TRUE)
|
|
|
|
set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
|
|
set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
|
|
set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
|
|
set(CMAKE_FIND_ROOT_PATH_MODE_PACKAGE BOTH)
|