hurl/docs/grammar.md

Grammar

Definitions

Short description:

• operator | denotes alternative,
• operator * denotes iteration (zero or more),
• operator + denotes iteration (one or more),

Syntax Grammar

General

hurl-file

entry*
lt*

entry(used by hurl-file)

request
response?

request(used by entry)

lt*
method sp value-string lt
header*
request-section*
body?

response(used by entry)

lt*
version sp status lt
header*
response-section*
body?

method(used by request)

[A-Z]+

version(used by response)

 HTTP/1.0
|HTTP/1.1
|HTTP/2
|HTTP

status(used by response)

[0-9]+

header(used by request, response)

lt*
key-value lt

body(used by request, response)

lt*
bytes lt

Sections

request-section(used by request)

 basic-auth-section
|query-string-params-section
|form-params-section
|multipart-form-data-section
|cookies-section
|options-section

response-section(used by response)

 captures-section
|asserts-section

query-string-params-section(used by request-section)

lt*
[QueryStringParams] lt
key-value*

form-params-section(used by request-section)

lt*
[FormParams] lt
key-value*

multipart-form-data-section(used by request-section)

lt*
[MultipartFormData] lt
multipart-form-data-param*

cookies-section(used by request-section)

lt*
[Cookies] lt
key-value*

captures-section(used by response-section)

lt*
[Captures] lt
capture*

asserts-section(used by response-section)

lt*
[Asserts] lt
assert*

basic-auth-section(used by request-section)

lt*
[BasicAuth] lt
key-value*

options-section(used by request-section)

lt*
[Options] lt
option*

key-value(used by header, query-string-params-section, form-params-section, cookies-section, basic-auth-section, multipart-form-data-param)

key-string : value-string

multipart-form-data-param(used by multipart-form-data-section)

file-param|key-value

file-param(used by multipart-form-data-param)

lt*
key-string : file-value lt

file-value(used by file-param)

file, filename ; (file-contenttype)?

file-contenttype(used by file-value)

[a-zA-Z0-9/+-]+

capture(used by captures-section)

lt*
key-string : query (sp filter)* lt

assert(used by asserts-section)

lt*
query (sp filter)* sp predicate lt

option(used by options-section)

lt*
(aws-sigv4-option|ca-certificate-option|client-certificate-option|client-key-option|compressed-option|connect-to-option|delay-option|follow-redirect-option|follow-redirect-trusted-option|http10-option|http11-option|http2-option|http3-option|insecure-option|ipv4-option|ipv6-option|max-redirs-option|netrc-option|netrc-file-option|netrc-optional-option|output-option|path-as-is-option|proxy-option|resolve-option|retry-option|retry-interval-option|skip-option|unix-socket-option|user-option|variable-option|verbose-option|very-verbose-option)

aws-sigv4-option(used by option)

aws-sigv4 : value-string lt

ca-certificate-option(used by option)

cacert : filename lt

client-certificate-option(used by option)

cert : filename-password lt

client-key-option(used by option)

key : value-string lt

compressed-option(used by option)

compressed : boolean-option lt

connect-to-option(used by option)

connect-to : value-string lt

delay-option(used by option)

delay : integer-option lt

follow-redirect-option(used by option)

location : boolean-option lt

follow-redirect-trusted-option(used by option)

location-trusted : boolean-option lt

http10-option(used by option)

http1.0 : boolean-option lt

http11-option(used by option)

http1.1 : boolean-option lt

http2-option(used by option)

http2 : boolean-option lt

http3-option(used by option)

http3 : boolean-option lt

insecure-option(used by option)

insecure : boolean-option lt

ipv4-option(used by option)

ipv4 : boolean-option lt

ipv6-option(used by option)

ipv6 : boolean-option lt

max-redirs-option(used by option)

max-redirs : integer-option lt

netrc-option(used by option)

netrc : boolean-option lt

netrc-file-option(used by option)

netrc-file : value-string lt

netrc-optional-option(used by option)

netrc-optional : boolean-option lt

output-option(used by option)

output : value-string lt

path-as-is-option(used by option)

path-as-is : boolean-option lt

proxy-option(used by option)

proxy : value-string lt

resolve-option(used by option)

resolve : value-string lt

retry-option(used by option)

retry : integer-option lt

retry-interval-option(used by option)

retry-interval : integer-option lt

skip-option(used by option)

skip : boolean-option lt

unix-socket-option(used by option)

unix-socket : value-string lt

user-option(used by option)

user : value-string lt

variable-option(used by option)

variable : variable-definition lt

verbose-option(used by option)

verbose : boolean-option lt

very-verbose-option(used by option)

very-verbose : boolean-option lt

variable-definition(used by variable-option)

variable-name = variable-value

boolean-option(used by compressed-option, follow-redirect-option, follow-redirect-trusted-option, http10-option, http11-option, http2-option, http3-option, insecure-option, ipv4-option, ipv6-option, netrc-option, netrc-optional-option, path-as-is-option, skip-option, verbose-option, very-verbose-option)

boolean|template

integer-option(used by delay-option, max-redirs-option, retry-option, retry-interval-option)

integer|template

variable-value(used by variable-definition)

 null
|boolean
|integer
|float
|key-string
|quoted-string

Query

query(used by capture, assert)

 status-query
|url-query
|header-query
|certificate-query
|cookie-query
|body-query
|xpath-query
|jsonpath-query
|regex-query
|variable-query
|duration-query
|bytes-query
|sha256-query
|md5-query

status-query(used by query)

status

url-query(used by query)

url

header-query(used by query)

header sp quoted-string

certificate-query(used by query)

certificate sp (Subject|Issuer|Start-Date|Expire-Date|Serial-Number)

cookie-query(used by query)

cookie sp quoted-string

body-query(used by query)

body

xpath-query(used by query)

xpath sp quoted-string

jsonpath-query(used by query)

jsonpath sp quoted-string

regex-query(used by query)

regex sp (quoted-string|regex)

variable-query(used by query)

variable sp quoted-string

duration-query(used by query)

duration

sha256-query(used by query)

sha256

md5-query(used by query)

md5

bytes-query(used by query)

bytes

Predicates

predicate(used by assert)

(not sp)? predicate-func

predicate-func(used by predicate)

 equal-predicate
|not-equal-predicate
|greater-predicate
|greater-or-equal-predicate
|less-predicate
|less-or-equal-predicate
|start-with-predicate
|end-with-predicate
|contain-predicate
|match-predicate
|exist-predicate
|is-empty-predicate
|include-predicate
|integer-predicate
|float-predicate
|boolean-predicate
|string-predicate
|collection-predicate
|date-predicate
|iso-date-predicate

equal-predicate(used by predicate-func)

== sp predicate-value

not-equal-predicate(used by predicate-func)

!= sp predicate-value

greater-predicate(used by predicate-func)

> sp (number|quoted-string)

greater-or-equal-predicate(used by predicate-func)

>= sp sp* (number|quoted-string)

less-predicate(used by predicate-func)

< sp (number|quoted-string)

less-or-equal-predicate(used by predicate-func)

<= sp (number|quoted-string)

start-with-predicate(used by predicate-func)

startsWith sp (quoted-string|oneline-hex|oneline-base64)

end-with-predicate(used by predicate-func)

endsWith sp (quoted-string|oneline-hex|oneline-base64)

contain-predicate(used by predicate-func)

contains sp quoted-string

match-predicate(used by predicate-func)

matches sp (quoted-string|regex)

exist-predicate(used by predicate-func)

exists

is-empty-predicate(used by predicate-func)

isEmpty

include-predicate(used by predicate-func)

includes sp predicate-value

integer-predicate(used by predicate-func)

isInteger

float-predicate(used by predicate-func)

isFloat

boolean-predicate(used by predicate-func)

isBoolean

string-predicate(used by predicate-func)

isString

collection-predicate(used by predicate-func)

isCollection

date-predicate(used by predicate-func)

isDate

iso-date-predicate(used by predicate-func)

isIsoDate

predicate-value(used by equal-predicate, not-equal-predicate, include-predicate)

 boolean
|multiline-string
|null
|number
|oneline-base64
|oneline-file
|oneline-hex
|quoted-string
|template

Bytes

bytes(used by body)

 json-value
|xml
|multiline-string
|oneline-string
|oneline-base64
|oneline-file
|oneline-hex

xml(used by bytes)

< To Be Defined >

oneline-base64(used by start-with-predicate, end-with-predicate, predicate-value, bytes)

base64, [A-Z0-9+-= \n]+ ;

oneline-file(used by predicate-value, bytes)

file, filename ;

oneline-hex(used by start-with-predicate, end-with-predicate, predicate-value, bytes)

hex, hexdigit* ;

Strings

quoted-string(used by variable-value, header-query, cookie-query, xpath-query, jsonpath-query, regex-query, variable-query, greater-predicate, greater-or-equal-predicate, less-predicate, less-or-equal-predicate, start-with-predicate, end-with-predicate, contain-predicate, match-predicate, predicate-value, jsonpath-filter, regex-filter, replace-filter, split-filter, xpath-filter)

" (quoted-string-content|template)* "

quoted-string-content(used by quoted-string)

(quoted-string-text|quoted-string-escaped-char)*

quoted-string-text(used by quoted-string-content)

~["\\]+

quoted-string-escaped-char(used by quoted-string-content)

\ ("|\|\b|\f|\n|\r|\t|\u unicode-char)

key-string(used by key-value, file-param, capture, variable-value)

(key-string-content|template)+

key-string-content(used by key-string)

(key-string-text|key-string-escaped-char)*

key-string-text(used by key-string-content)

(alphanum|_|-|.|[|]|@|$)+

key-string-escaped-char(used by key-string-content)

\ (#|:|\|\b|\f|\n|\r|\t|\u unicode-char)

value-string(used by request, key-value, aws-sigv4-option, client-key-option, connect-to-option, netrc-file-option, output-option, proxy-option, resolve-option, unix-socket-option, user-option)

(value-string-content|template)*

value-string-content(used by value-string)

(value-string-text|value-string-escaped-char)*

value-string-text(used by value-string-content)

~[#\n\\]+

value-string-escaped-char(used by value-string-content)

\ (#|\|\b|\f|\n|\r|\t|\u unicode-char)

oneline-string(used by bytes)

` (oneline-string-content|template)* `

oneline-string-content(used by oneline-string)

(oneline-string-text|oneline-string-escaped-char)*

oneline-string-text(used by oneline-string-content)

~[#\n\\] ~`

oneline-string-escaped-char(used by oneline-string-content)

\ (`|#|\|b|f|u unicode-char)

multiline-string(used by predicate-value, bytes)

``` multiline-string-type? lt
(multiline-string-content|template)* lt
```

multiline-string-type(used by multiline-string)

 base64
|hex
|json
|xml
|graphql

multiline-string-content(used by multiline-string)

(multiline-string-text|multiline-string-escaped-char)*

multiline-string-text(used by multiline-string-content)

~[\\]+ ~```

multiline-string-escaped-char(used by multiline-string-content)

\ (\|b|f|n|r|t|`|u unicode-char)

filename(used by file-value, ca-certificate-option, oneline-file)

(filename-content|template)*

filename-content(used by filename)

(filename-text|filename-escaped-char)*

filename-text(used by filename-content)

~[#;{} \n\\]+

filename-escaped-char(used by filename-content)

\ (\|b|f|n|r|t|#|;| |{|}|u unicode-char)

filename-password(used by client-certificate-option)

(filename-password-content|template)*

filename-password-content(used by filename-password)

(filename-password-text|filename-password-escaped-char)*

filename-password-text(used by filename-password-content)

~[#;{} \n\\]+

filename-password-escaped-char(used by filename-password-content)

\ (\|b|f|n|r|t|#|;| |{|}|:|u unicode-char)

unicode-char(used by quoted-string-escaped-char, key-string-escaped-char, value-string-escaped-char, oneline-string-escaped-char, multiline-string-escaped-char, filename-escaped-char, filename-password-escaped-char)

{ hexdigit+ }

JSON

json-value(used by bytes, json-key-value, json-array)

 template
|json-object
|json-array
|json-string
|json-number
|boolean
|null

json-object(used by json-value)

{ json-key-value (, json-key-value)* }

json-key-value(used by json-object)

json-string : json-value

json-array(used by json-value)

[ json-value (, json-value)* ]

json-string(used by json-value, json-key-value)

" (json-string-content|template)* "

json-string-content(used by json-string)

json-string-text|json-string-escaped-char

json-string-text(used by json-string-content)

~["\\]

json-string-escaped-char(used by json-string-content)

\ ("|\|b|f|n|r|t|u hexdigit hexdigit hexdigit hexdigit)

json-number(used by json-value)

integer fraction? exponent?

Template / Expression

template(used by boolean-option, integer-option, predicate-value, quoted-string, key-string, value-string, oneline-string, multiline-string, filename, filename-password, json-value, json-string)

{{ expr }}

expr(used by template)

variable-name (sp filter)*

variable-name(used by variable-definition, expr)

[A-Za-z] [A-Za-z_-0-9]*

Filter

filter(used by capture, assert, expr)

 count-filter
|days-after-now-filter
|days-before-now-filter
|decode-filter
|format-filter
|html-escape-filter
|html-unescape-filter
|jsonpath-filter
|nth-filter
|regex-filter
|replace-filter
|split-filter
|to-date-filter
|to-int-filter
|url-decode-filter
|url-encode-filter
|xpath-filter

count-filter(used by filter)

count

days-after-now-filter(used by filter)

daysAfterNow

days-before-now-filter(used by filter)

daysBeforeNow

decode-filter(used by filter)

decode

format-filter(used by filter)

format

html-escape-filter(used by filter)

htmlEscape

html-unescape-filter(used by filter)

htmlUnescape

jsonpath-filter(used by filter)

jsonpath sp quoted-string

nth-filter(used by filter)

nth sp integer

regex-filter(used by filter)

regex sp (quoted-string|regex)

replace-filter(used by filter)

replace sp (quoted-string|regex) sp quoted-string

split-filter(used by filter)

split sp quoted-string

to-date-filter(used by filter)

toDate

to-float-filter(used by filter)

toFloat

to-int-filter(used by filter)

toInt

url-decode-filter(used by filter)

urlDecode

url-encode-filter(used by filter)

urlEncode

xpath-filter(used by filter)

xpath sp quoted-string

Lexical Grammar

boolean(used by boolean-option, variable-value, predicate-value, json-value)

true|false

null(used by variable-value, predicate-value, json-value)

null

alphanum(used by key-string-text)

[A-Za-z0-9]

integer(used by integer-option, variable-value, json-number, nth-filter, float, number)

digit+

float(used by variable-value, number)

integer fraction

number(used by greater-predicate, greater-or-equal-predicate, less-predicate, less-or-equal-predicate, predicate-value)

integer|float

digit(used by integer, fraction, exponent)

[0-9]

hexdigit(used by oneline-hex, unicode-char, json-string-escaped-char)

[0-9A-Fa-f]

fraction(used by json-number, float)

. digit+

exponent(used by json-number)

(e|E) (+|-)? digit+

sp(used by request, response, capture, assert, header-query, certificate-query, cookie-query, xpath-query, jsonpath-query, regex-query, variable-query, predicate, equal-predicate, not-equal-predicate, greater-predicate, greater-or-equal-predicate, less-predicate, less-or-equal-predicate, start-with-predicate, end-with-predicate, contain-predicate, match-predicate, include-predicate, expr, jsonpath-filter, nth-filter, regex-filter, replace-filter, split-filter, xpath-filter, lt)

[ \t]

lt(used by hurl-file, request, response, header, body, query-string-params-section, form-params-section, multipart-form-data-section, cookies-section, captures-section, asserts-section, basic-auth-section, options-section, file-param, capture, assert, option, aws-sigv4-option, ca-certificate-option, client-certificate-option, client-key-option, compressed-option, connect-to-option, delay-option, follow-redirect-option, follow-redirect-trusted-option, http10-option, http11-option, http2-option, http3-option, insecure-option, ipv4-option, ipv6-option, max-redirs-option, netrc-option, netrc-file-option, netrc-optional-option, output-option, path-as-is-option, proxy-option, resolve-option, retry-option, retry-interval-option, skip-option, unix-socket-option, user-option, variable-option, verbose-option, very-verbose-option, multiline-string)

sp* comment? [\n]?

comment(used by lt)

# ~[\n]*

regex(used by regex-query, match-predicate, regex-filter, replace-filter)

/ regex-content /

regex-content(used by regex)

(regex-text|regex-escaped-char)*

regex-text(used by regex-content)

~[\n\/]+

regex-escaped-char(used by regex-content)

\ ~[\n]