hurl/docs/grammar.md

Grammar

Definitions

Short description:

• operator | denotes alternative,
• operator * denotes iteration (zero or more),
• operator + denotes iteration (one or more),

Syntax Grammar

General

hurl-file

entry*
lt*

entry(used by hurl-file)

request
response?

request(used by entry)

lt*
method sp value-string lt
header*
request-section*
body?

response(used by entry)

lt*
version sp status lt
header*
response-section*
body?

method(used by request)

 GET
|HEAD
|POST
|PUT
|DELETE
|CONNECT
|OPTIONS
|TRACE
|PATCH

version(used by response)

 HTTP/1.0
|HTTP/1.1
|HTTP/2
|HTTP/*

status(used by response)

[0-9]+

header(used by request, response)

lt*
key-value lt

body(used by request, response)

lt*
bytes lt

Sections

request-section(used by request)

 query-string-params-section
|form-params-section
|multipart-form-data-section
|cookies-section
|options-section

response-section(used by response)

 captures-section
|asserts-section

query-string-params-section(used by request-section)

lt*
[QueryStringParams] lt
key-value*

form-params-section(used by request-section)

lt*
[FormParams] lt
key-value*

multipart-form-data-section(used by request-section)

lt*
[MultipartFormData] lt
multipart-form-data-param*

cookies-section(used by request-section)

lt*
[Cookies] lt
key-value*

captures-section(used by response-section)

lt*
[Captures] lt
capture*

asserts-section(used by response-section)

lt*
[Asserts] lt
assert*

options-section(used by request-section)

lt*
[Options] lt
option*

key-value(used by header, query-string-params-section, form-params-section, cookies-section, multipart-form-data-param)

key-string : value-string

multipart-form-data-param(used by multipart-form-data-section)

file-param|key-value

file-param(used by multipart-form-data-param)

lt*
key-string : file-value lt

file-value(used by file-param)

file, filename ; (file-contenttype)?

file-contenttype(used by file-value)

[a-zA-Z0-9/+-]+

capture(used by captures-section)

lt*
key-string : query lt

assert(used by asserts-section)

lt*
query sp predicate lt

option(used by options-section)

lt*
(ca-certificate-option|follow-redirect-option|insecure-option|max-redirs-option|variable-option|verbose-option|very-verbose-option)

ca-certificate-option(used by option)

cacert : filename lt

follow-redirect-option(used by option)

location : boolean lt

insecure-option(used by option)

insecure : boolean lt

max-redirs-option(used by option)

max-redirs : integer lt

variable-option(used by option)

variable : variable-definition lt

verbose-option(used by option)

verbose : boolean lt

very-verbose-option(used by option)

very-verbose : boolean lt

variable-definition(used by variable-option)

variable-name = variable-value

variable-value(used by variable-definition)

 null
|boolean
|integer
|float
|key-string
|quoted-string

Query

query(used by capture, assert)

main-query (sp subquery)?

main-query(used by query)

 status-query
|header-query
|cookie-query
|body-query
|xpath-query
|jsonpath-query
|regex-query
|variable-query
|duration-query
|bytes-query
|sha256-query
|md5-query

status-query(used by main-query)

status

header-query(used by main-query)

header sp quoted-string

cookie-query(used by main-query)

cookie sp quoted-string

body-query(used by main-query)

body

xpath-query(used by main-query)

xpath sp quoted-string

jsonpath-query(used by main-query)

jsonpath sp quoted-string

regex-query(used by main-query)

regex sp (quoted-string|regex)

variable-query(used by main-query)

variable sp quoted-string

duration-query(used by main-query)

duration

sha256-query(used by main-query)

sha256

md5-query(used by main-query)

md5

bytes-query(used by main-query)

bytes

subquery(used by query)

regex-subquery|count-subquery

regex-subquery(used by subquery)

regex sp (quoted-string|regex)

count-subquery(used by subquery)

count

Predicates

predicate(used by assert)

(not sp)? predicate-func

predicate-func(used by predicate)

 equal-predicate
|not-equal-predicate
|greater-predicate
|greater-or-equal-predicate
|less-predicate
|less-or-equal-predicate
|start-with-predicate
|end-with-predicate
|contain-predicate
|match-predicate
|exist-predicate
|include-predicate
|integer-predicate
|float-predicate
|boolean-predicate
|string-predicate
|collection-predicate

equal-predicate(used by predicate-func)

(equals|==) sp predicate-value

not-equal-predicate(used by predicate-func)

(notEquals|!=) sp predicate-value

greater-predicate(used by predicate-func)

(greaterThan|>) sp (integer|float|quoted-string)

greater-or-equal-predicate(used by predicate-func)

(greaterThanOrEquals|>=) sp sp* (integer|float|quoted-string)

less-predicate(used by predicate-func)

(lessThan|<) sp (integer|float|quoted-string)

less-or-equal-predicate(used by predicate-func)

(lessThanOrEquals|<=) sp (integer|float|quoted-string)

start-with-predicate(used by predicate-func)

startsWith sp (quoted-string|oneline-hex|oneline-base64)

end-with-predicate(used by predicate-func)

endsWith sp (quoted-string|oneline-hex|oneline-base64)

contain-predicate(used by predicate-func)

contains sp quoted-string

match-predicate(used by predicate-func)

matches sp (quoted-string|regex)

exist-predicate(used by predicate-func)

exists

include-predicate(used by predicate-func)

includes sp predicate-value

integer-predicate(used by predicate-func)

isInteger

float-predicate(used by predicate-func)

isFloat

boolean-predicate(used by predicate-func)

isBoolean

string-predicate(used by predicate-func)

isString

collection-predicate(used by predicate-func)

isCollection

predicate-value(used by equal-predicate, not-equal-predicate, include-predicate)

 null
|boolean
|integer
|float
|quoted-string
|oneline-hex
|oneline-base64
|oneline-file
|multiline-string
|template

Bytes

bytes(used by body)

 json-value
|xml
|multiline-string
|oneline-string
|oneline-base64
|oneline-file
|oneline-hex

xml(used by bytes)

< To Be Defined >

oneline-base64(used by start-with-predicate, end-with-predicate, predicate-value, bytes)

base64, [A-Z0-9+-= \n]+ ;

oneline-file(used by predicate-value, bytes)

file, filename ;

oneline-hex(used by start-with-predicate, end-with-predicate, predicate-value, bytes)

hex, hexdigit* ;

Strings

quoted-string(used by variable-value, header-query, cookie-query, xpath-query, jsonpath-query, regex-query, variable-query, regex-subquery, greater-predicate, greater-or-equal-predicate, less-predicate, less-or-equal-predicate, start-with-predicate, end-with-predicate, contain-predicate, match-predicate, predicate-value)

" (quoted-string-content|template)* "

quoted-string-content(used by quoted-string)

(quoted-string-text|quoted-string-escaped-char)*

quoted-string-text(used by quoted-string-content)

~["\\]+

quoted-string-escaped-char(used by quoted-string-content)

\ ("|\|\b|\f|\n|\r|\t|\u unicode-char)

key-string(used by key-value, file-param, capture, variable-value)

(key-string-content|template)+

key-string-content(used by key-string)

(key-string-text|key-string-escaped-char)*

key-string-text(used by key-string-content)

~[#:\n\\]+

key-string-escaped-char(used by key-string-content)

\ (#|:|\|\b|\f|\n|\r|\t|\u unicode-char)

value-string(used by request, key-value)

(value-string-content|template)*

value-string-content(used by value-string)

(value-string-text|value-string-escaped-char)*

value-string-text(used by value-string-content)

~[#\n\\]+

value-string-escaped-char(used by value-string-content)

\ (#|\|\b|\f|\n|\r|\t|\u unicode-char)

oneline-string(used by bytes)

``` (oneline-string-content|template)* ```

oneline-string-content(used by oneline-string)

(oneline-string-text|oneline-string-escaped-char)*

oneline-string-text(used by oneline-string-content)

~[#\n\\] ~```

oneline-string-escaped-char(used by oneline-string-content)

\ (#|\|b|f|u unicode-char)

multiline-string(used by predicate-value, bytes)

``` multiline-string-type? lt
(multiline-string-content|template)* lt
```

multiline-string-type(used by multiline-string)

 base64
|hex
|json
|xml
|graphql

multiline-string-content(used by multiline-string)

(multiline-string-text|multiline-string-escaped-char)*

multiline-string-text(used by multiline-string-content)

~[\\]+ ~```

multiline-string-escaped-char(used by multiline-string-content)

\ (\|b|f|n|r|t|`|u unicode-char)

filename(used by file-value, ca-certificate-option, oneline-file)

(filename-content|template)*

filename-content(used by filename)

(filename-text|filename-escaped-char)*

filename-text(used by filename-content)

~[#; \n\\]+

filename-escaped-char(used by filename-content)

\ (;|#|[ ])

unicode-char(used by quoted-string-escaped-char, key-string-escaped-char, value-string-escaped-char, oneline-string-escaped-char, multiline-string-escaped-char)

{ hexdigit+ }

JSON

json-value(used by bytes, json-key-value, json-array)

 template
|json-object
|json-array
|json-string
|json-number
|boolean
|null

json-object(used by json-value)

{ json-key-value (, json-key-value)* }

json-key-value(used by json-object)

json-string : json-value

json-array(used by json-value)

[ json-value (, json-value)* ]

json-string(used by json-value, json-key-value)

" (json-string-content|template)* "

json-string-content(used by json-string)

json-string-text|json-string-escaped-char

json-string-text(used by json-string-content)

~["\\]

json-string-escaped-char(used by json-string-content)

\ ("|\|b|f|n|r|t|u hexdigit hexdigit hexdigit hexdigit)

json-number(used by json-value)

integer fraction? exponent?

Template / Expression

template(used by predicate-value, quoted-string, key-string, value-string, oneline-string, multiline-string, filename, json-value, json-string)

{{ expr }}

expr(used by template)

variable-name

variable-name(used by variable-definition, expr)

[A-Za-z] [A-Za-z_-0-9]*

Lexical Grammar

boolean(used by follow-redirect-option, insecure-option, verbose-option, very-verbose-option, variable-value, predicate-value, json-value)

true|false

null(used by variable-value, predicate-value, json-value)

null

integer(used by max-redirs-option, variable-value, greater-predicate, greater-or-equal-predicate, less-predicate, less-or-equal-predicate, predicate-value, json-number, float)

digit+

float(used by variable-value, greater-predicate, greater-or-equal-predicate, less-predicate, less-or-equal-predicate, predicate-value)

integer fraction

digit(used by integer, fraction, exponent)

[0-9]

hexdigit(used by oneline-hex, unicode-char, json-string-escaped-char)

[0-9A-Fa-f]

fraction(used by json-number, float)

. digit+

exponent(used by json-number)

(e|E) (+|-)? digit+

sp(used by request, response, assert, query, header-query, cookie-query, xpath-query, jsonpath-query, regex-query, variable-query, regex-subquery, predicate, equal-predicate, not-equal-predicate, greater-predicate, greater-or-equal-predicate, less-predicate, less-or-equal-predicate, start-with-predicate, end-with-predicate, contain-predicate, match-predicate, include-predicate, lt)

[ \t]

lt(used by hurl-file, request, response, header, body, query-string-params-section, form-params-section, multipart-form-data-section, cookies-section, captures-section, asserts-section, options-section, file-param, capture, assert, option, ca-certificate-option, follow-redirect-option, insecure-option, max-redirs-option, variable-option, verbose-option, very-verbose-option, multiline-string)

sp* comment? [\n]?

comment(used by lt)

# ~[\n]*

regex(used by regex-query, regex-subquery, match-predicate)

/ regex-content /

regex-content(used by regex)

(regex-text|regex-escaped-char)*

regex-text(used by regex-content)

~[\n\/]+

regex-escaped-char(used by regex-content)

\ ~[\n]