mirror of
https://github.com/carp-lang/Carp.git
synced 2024-09-11 05:25:28 +03:00
e1943b29a9
* refactor: major environment mgmt refactor This big refactor primarily changes two things in terms of behavior: 1. Stores a SymPath on concretely named (non-generic) struct types; before we stored a string. 2. The SymPath mentioned in (1.) designates where the struct is stored in the current environment chain. Modules now carry a local type environment in addition to their local value environments. Any types defined in the module are added to this environment rather than the global type environment. To resolve a type such as `Foo.Bar` we now do the following: - Search the *global value environment* for the Foo module. - Get the type environment stored in the Foo module. - Search for Bar in the Foo module's type environment. Additionally, this commit eliminates the Lookup module entirely and refactors the Env module to handle all aspects of environment management in hopefully a more reusable fashion. I also took the opportunity to refactor primitiveDeftype in Primitives and qualifySym in Qualify, both of which were hefty functions that I found difficult to grok and needed refactoring anyway as a result of lookup changes (lookups now return an Either instead of a Maybe). Subsequent commits will clean up and clarify this work further. This does include one minor regression. Namely, an implementation of `hash` in core/Color that was maximally generic now needs type casting. * refactor: clean up recent Env changes This commit removes some redundant functions, unifies some logic, and renames some routines across the Env module in efforts to make it cleaner. Call sites have been updated accordingly. * chore: format code with ormolu * fix: update lookup tests Changes references to renamed functions in the Env module. * refactor: style + additional improvements from eriksvedang@ - Rename arrayTy -> arrayTyA in ArrayTemplates.hs to disambiguate. - Add maybeId util function. - Remove commented code. - Refactor a few functions for readability. * fix: fix type inference regression Recent commits introduced one minor regression whereby an instance of type inference in core/Color.carp no longer worked and required explicit type annotation. The problem ultimately had to do with qualification: - Prior to the recent changes, type inference worked because the call in question was qualified to Color.Id.get-tag, fixing the type. - Failing to copy over a local envs Use modules to function envs resulted in finding more than just Color.Id.get-tag for this instance. We now copy use modules over to function envs generated during qualification to ensure we resolve to Use'd definitions before more general cases. Similarly, I made a small change to primitiveUse to support contextual use calls (e.g. the `(use Id)` in Color.carp, which really means `(use Color.Id)`) * chore: Update some clarificatory comments * chore: fix inline comment
68 lines
2.5 KiB
Haskell
68 lines
2.5 KiB
Haskell
module AssignTypes where
|
|
|
|
import Data.List (nub)
|
|
import qualified Map
|
|
import Obj
|
|
import TypeError
|
|
import Types
|
|
|
|
{-# ANN assignTypes "HLint: ignore Eta reduce" #-}
|
|
|
|
-- | Walk the whole expression tree and replace all occurences of VarTy with their corresponding actual type.
|
|
assignTypes :: TypeMappings -> XObj -> Either TypeError XObj
|
|
assignTypes mappings root = visit root
|
|
where
|
|
visit xobj =
|
|
case xobjObj xobj of
|
|
(Lst _) -> visitList xobj
|
|
(Arr _) -> visitArray xobj
|
|
(StaticArr _) -> visitStaticArray xobj
|
|
_ -> assignType xobj
|
|
visitList :: XObj -> Either TypeError XObj
|
|
visitList (XObj (Lst xobjs) i t) =
|
|
do
|
|
visited <- mapM (assignTypes mappings) xobjs
|
|
let xobj' = XObj (Lst visited) i t
|
|
assignType xobj'
|
|
visitList _ = error "The function 'visitList' only accepts XObjs with lists in them."
|
|
visitArray :: XObj -> Either TypeError XObj
|
|
visitArray (XObj (Arr xobjs) i t) =
|
|
do
|
|
visited <- mapM (assignTypes mappings) xobjs
|
|
let xobj' = XObj (Arr visited) i t
|
|
assignType xobj'
|
|
visitArray _ = error "The function 'visitArray' only accepts XObjs with arrays in them."
|
|
visitStaticArray :: XObj -> Either TypeError XObj
|
|
visitStaticArray (XObj (StaticArr xobjs) i t) =
|
|
do
|
|
visited <- mapM (assignTypes mappings) xobjs
|
|
let xobj' = XObj (StaticArr visited) i t
|
|
assignType xobj'
|
|
visitStaticArray _ = error "The function 'visitStaticArray' only accepts XObjs with arrays in them."
|
|
assignType :: XObj -> Either TypeError XObj
|
|
assignType xobj = case xobjTy xobj of
|
|
Just startingType ->
|
|
let finalType = replaceTyVars mappings startingType
|
|
in if isArrayTypeOK finalType
|
|
then Right (xobj {xobjTy = Just finalType})
|
|
else Left (ArraysCannotContainRefs xobj)
|
|
Nothing -> pure xobj
|
|
|
|
isArrayTypeOK :: Ty -> Bool
|
|
isArrayTypeOK (StructTy (ConcreteNameTy (SymPath [] "Array")) [RefTy _ _]) = False -- An array containing refs!
|
|
isArrayTypeOK _ = True
|
|
|
|
-- | Change auto generated type names (i.e. 't0') to letters (i.e. 'a', 'b', 'c', etc...)
|
|
-- | TODO: Only change variables that are machine generated.
|
|
beautifyTypeVariables :: XObj -> Either TypeError XObj
|
|
beautifyTypeVariables root =
|
|
let Just t = xobjTy root
|
|
tys = nub (typeVariablesInOrderOfAppearance t)
|
|
mappings =
|
|
Map.fromList
|
|
( zip
|
|
(map (\(VarTy name) -> name) tys)
|
|
(map (VarTy . (: [])) ['a' ..])
|
|
)
|
|
in assignTypes mappings root
|