mirror of
https://github.com/cursorless-dev/cursorless.git
synced 2024-10-04 04:47:29 +03:00
0bf9021962
Fixes #2316
## Checklist
- [x] I have added
[tests](https://www.cursorless.org/docs/contributing/test-case-recorder/)
- [/] I have updated the
[docs](https://github.com/cursorless-dev/cursorless/tree/main/docs) and
[cheatsheet](https://github.com/cursorless-dev/cursorless/tree/main/cursorless-talon/src/cheatsheet)
- [x] I have not broken the cheatsheet
- [x] Add `@disqualifyDelimiter` for all languages
- [x] Add plural form of surrounding pair
[scopes.py](5e9a2e9555/cursorless-talon/src/modifiers/scopes.py (L48)
)
- [x] Run talon tests
- [x] add multiline quad tests for plaintext?
---------
Co-authored-by: pre-commit-ci-lite[bot] <117423508+pre-commit-ci-lite[bot]@users.noreply.github.com>
Co-authored-by: Pokey Rule <755842+pokey@users.noreply.github.com>
84 lines
1.6 KiB
Scheme
84 lines
1.6 KiB
Scheme
;; https://github.com/tree-sitter-grammars/tree-sitter-yaml/blob/master/src/grammar.json
|
|
|
|
;; ;;!! foo: bar
|
|
;; ;;! ^^^ ^^^
|
|
(_
|
|
key: (_) @collectionKey @value.leading.endOf
|
|
value: (_) @value @collectionKey.trailing.startOf
|
|
) @_.domain
|
|
|
|
;;!! foo: bar
|
|
;;! ^^^^^^^^
|
|
(block_mapping
|
|
(block_mapping_pair)? @collectionItem.leading.endOf
|
|
.
|
|
(block_mapping_pair) @collectionItem
|
|
.
|
|
(block_mapping_pair)? @collectionItem.trailing.startOf
|
|
) @map
|
|
|
|
;;!! - 0
|
|
;;! ^
|
|
;;! ---
|
|
(
|
|
(block_sequence
|
|
(block_sequence_item)? @collectionItem.leading.endOf
|
|
.
|
|
(block_sequence_item
|
|
"-" @collectionItem.prefix
|
|
(_) @collectionItem
|
|
) @collectionItem.domain
|
|
.
|
|
(block_sequence_item)? @collectionItem.trailing.startOf
|
|
(#trim-end! @collectionItem)
|
|
(#insertion-delimiter! @collectionItem "\n")
|
|
) @list
|
|
(#trim-end! @list)
|
|
)
|
|
|
|
;;!! [0]
|
|
;;! ^
|
|
(flow_sequence
|
|
(flow_node)? @collectionItem.leading.endOf
|
|
.
|
|
(flow_node) @collectionItem
|
|
.
|
|
(flow_node)? @collectionItem.trailing.startOf
|
|
(#insertion-delimiter! @collectionItem ", ")
|
|
) @list
|
|
|
|
;;!! { foo: bar }
|
|
;;! ^^^^^^^^
|
|
(flow_mapping
|
|
(flow_pair)? @collectionItem.leading.endOf
|
|
.
|
|
(flow_pair) @collectionItem
|
|
.
|
|
(flow_pair)? @collectionItem.trailing.startOf
|
|
(#insertion-delimiter! @collectionItem ", ")
|
|
) @map
|
|
|
|
[
|
|
(block_mapping)
|
|
(block_sequence)
|
|
(flow_sequence)
|
|
(flow_mapping)
|
|
] @collectionItem.iteration @collectionKey.iteration @value.iteration
|
|
|
|
;;!! foo: bar
|
|
;;! ^^^
|
|
;;!! | block scalar
|
|
;;! ^^^^^^^^^^^^^
|
|
[
|
|
(string_scalar)
|
|
(block_scalar)
|
|
] @string @textFragment
|
|
|
|
;;!! # comment
|
|
;;! ^^^^^^^^^
|
|
(comment) @comment @textFragment
|
|
|
|
(block_scalar
|
|
">" @disqualifyDelimiter
|
|
)
|