mirror of
https://github.com/digital-asset/daml.git
synced 2024-09-20 09:17:43 +03:00
d2e2c21684
New year, new copyright, new expected unknown issues with various files that won't be covered by the script and/or will be but shouldn't change. I'll do the details on Jan 1, but would appreciate this being preapproved so I can actually get it merged by then. CHANGELOG_BEGIN CHANGELOG_END
53 lines
1.7 KiB
HCL
53 lines
1.7 KiB
HCL
# Copyright (c) 2022 Digital Asset (Switzerland) GmbH and/or its affiliates. All rights reserved.
|
|
# SPDX-License-Identifier: Apache-2.0
|
|
|
|
resource "google_compute_backend_bucket" "default" {
|
|
project = var.project
|
|
name = "${var.name}-backend"
|
|
bucket_name = google_storage_bucket.default.name
|
|
enable_cdn = true
|
|
}
|
|
|
|
resource "google_compute_global_address" "default" {
|
|
project = var.project
|
|
name = "${var.name}-address"
|
|
ip_version = "IPV4"
|
|
}
|
|
|
|
resource "google_compute_url_map" "default" {
|
|
project = var.project
|
|
name = var.name
|
|
default_service = google_compute_backend_bucket.default.self_link
|
|
}
|
|
|
|
resource "google_compute_target_http_proxy" "default" {
|
|
project = var.project
|
|
name = "${var.name}-http-proxy"
|
|
url_map = google_compute_url_map.default.self_link
|
|
}
|
|
|
|
resource "google_compute_global_forwarding_rule" "http" {
|
|
project = var.project
|
|
name = "${var.name}-http"
|
|
target = google_compute_target_http_proxy.default.self_link
|
|
ip_address = google_compute_global_address.default.address
|
|
port_range = "80"
|
|
depends_on = [google_compute_global_address.default]
|
|
}
|
|
|
|
resource "google_compute_target_https_proxy" "default" {
|
|
project = var.project
|
|
name = "${var.name}-https-proxy"
|
|
url_map = google_compute_url_map.default.self_link
|
|
ssl_certificates = [var.ssl_certificate]
|
|
}
|
|
|
|
resource "google_compute_global_forwarding_rule" "https" {
|
|
project = var.project
|
|
name = "${var.name}-https"
|
|
target = google_compute_target_https_proxy.default.self_link
|
|
ip_address = google_compute_global_address.default.address
|
|
port_range = "443"
|
|
depends_on = [google_compute_global_address.default]
|
|
}
|