git.iko.soy/elk
on 04df608 help sign in
elk/compiler/Transform/SafeNames.hs
76 lines 2.6 kB history raw
1{-# OPTIONS_GHC -Wall #-}
2module Transform.SafeNames (metadataModule) where
4import Control.Arrow (first, (***))
5import Data.List (intercalate)
7import qualified Data.Set as Set
9import qualified Parse.Helpers as PHelp
10import SourceSyntax.Expression
11import qualified SourceSyntax.Helpers as SHelp
12import SourceSyntax.Location
13import SourceSyntax.Module
14import SourceSyntax.Pattern
16var :: String -> String
17var = intercalate "." . map (dereserve . deprime) . SHelp.splitDots
18 where
19 deprime = map (\c -> if c == '\'' then '$' else c)
20 dereserve x = case Set.member x PHelp.jsReserveds of
21 False -> x
22 True -> "$" ++ x
24pattern :: Pattern -> Pattern
25pattern pat =
26 case pat of
27 PVar x -> PVar (var x)
28 PLiteral _ -> pat
29 PRecord fs -> PRecord (map var fs)
30 PAnything -> pat
31 PAlias x p -> PAlias (var x) (pattern p)
32 PData name ps -> PData name (map pattern ps)
34expression :: LExpr -> LExpr
35expression (L loc expr) =
36 let f = expression in
37 L loc $
38 case expr of
39 Literal _ -> expr
40 Var x -> Var (var x)
41 Range e1 e2 -> Range (f e1) (f e2)
42 ExplicitList es -> ExplicitList (map f es)
43 Binop op e1 e2 -> Binop op (f e1) (f e2)
44 Lambda p e -> Lambda (pattern p) (f e)
45 App e1 e2 -> App (f e1) (f e2)
46 MultiIf ps -> MultiIf (map (f *** f) ps)
47 Let defs body -> Let (map definition defs) (f body)
48 Case e cases -> Case (f e) $ map (pattern *** f) cases
49 Data name es -> Data name (map f es)
50 Access e x -> Access (f e) (var x)
51 Remove e x -> Remove (f e) (var x)
52 Insert e x v -> Insert (f e) (var x) (f v)
53 Modify r fs -> Modify (f r) (map (var *** f) fs)
54 Record fs -> Record (map (var *** f) fs)
55 Markdown uid md es -> Markdown uid md (map f es)
56 PortIn name st -> PortIn name st
57 PortOut name st signal -> PortOut name st (f signal)
59definition :: Def -> Def
60definition (Definition p e t) =
61 Definition (pattern p) (expression e) t
63metadataModule :: MetadataModule -> MetadataModule
64metadataModule modul =
65 modul
66 { names = map var (names modul)
67 , exports = map var (exports modul)
68 , imports = map (first var) (imports modul)
69 , program = expression (program modul)
70 , aliases =
71 let makeSafe (name,tvars,tipe) = (var name, tvars, tipe)
72 in map makeSafe (aliases modul)
73 , datatypes =
74 let makeSafe (name,tvars,ctors) = (var name, tvars, map (first var) ctors)
75 in map makeSafe (datatypes modul)
76 }