git.iko.soy/elk
on 117100e help sign in
elk/compiler/src/Compile.hs
127 lines 3.0 kB history raw
1{-# OPTIONS_GHC -Wall -fno-warn-unused-do-bind #-}
2module Compile
3 ( DocsFlag(..)
4 , compile
5 , Artifacts(..)
6 )
7 where
10import qualified Data.ByteString as BS
11import qualified Data.Map as Map
13import qualified AST.Source as Src
14import qualified AST.Valid as Valid
15import qualified AST.Canonical as Can
16import qualified AST.Optimized as Opt
17import qualified AST.Module.Name as ModuleName
18import qualified Canonicalize.Module as Canonicalize
19import qualified Elm.Docs as Docs
20import qualified Elm.Interface as I
21import qualified Elm.Name as N
22import qualified Elm.Package as Pkg
23import qualified Nitpick.PatternMatches as PatternMatches
24import qualified Optimize.Module as Optimize
25import qualified Parse.Parse as Parse
26import qualified Reporting.Error as Error
27import qualified Reporting.Render.Type.Localizer as L
28import qualified Reporting.Result as Result
29import qualified Reporting.Warning as Warning
30import qualified Type.Constrain.Module as Type
31import qualified Type.Solve as Type
33import System.IO.Unsafe (unsafePerformIO)
37-- COMPILE
40type Result i a =
41 Result.Result i [Warning.Warning] Error.Error a
44type ImportDict =
45 Map.Map N.Name ModuleName.Canonical
48data Artifacts =
49 Artifacts
50 { _elmi :: I.Interface
51 , _elmo :: Opt.Graph
52 , _docs :: Maybe Docs.Module
53 }
56compile :: DocsFlag -> Pkg.Name -> ImportDict -> I.Interfaces -> BS.ByteString -> Result i Artifacts
57compile flag pkg importDict interfaces source =
58 do
59 valid <- Result.mapError Error.Syntax $
60 Parse.program pkg source
62 canonical <- Result.mapError Error.Canonicalize $
63 Canonicalize.canonicalize pkg importDict interfaces valid
65 annotations <-
66 runTypeInference (Valid._imports valid) canonical
68 () <-
69 exhaustivenessCheck canonical
71 graph <- Result.mapError Error.Main $
72 Optimize.optimize annotations canonical
74 documentation <-
75 genarateDocs flag canonical
77 Result.ok $
78 Artifacts
79 { _elmi = I.fromModule annotations canonical
80 , _elmo = graph
81 , _docs = documentation
82 }
86-- TYPE INFERENCE
89runTypeInference :: [Src.Import] -> Can.Module -> Result i (Map.Map N.Name Can.Annotation)
90runTypeInference imports canonical =
91 case unsafePerformIO (Type.run =<< Type.constrain canonical) of
92 Left errors ->
93 Result.throw (Error.Type (L.fromImports imports) errors)
95 Right annotations ->
96 Result.ok annotations
100-- EXHAUSTIVENESS CHECK
103exhaustivenessCheck :: Can.Module -> Result i ()
104exhaustivenessCheck canonical =
105 case PatternMatches.check canonical of
106 Left errors ->
107 Result.throw (Error.Pattern errors)
109 Right () ->
110 Result.ok ()
114-- DOCUMENTATION
117data DocsFlag = YesDocs | NoDocs
120genarateDocs :: DocsFlag -> Can.Module -> Result.Result i w Error.Error (Maybe Docs.Module)
121genarateDocs flag modul =
122 case flag of
123 NoDocs ->
124 Result.ok Nothing
126 YesDocs ->
127 Just <$> Docs.fromModule modul