git.iko.soy/elk
on 306a7ee help sign in
elk/src/Transform/Declaration.hs
135 lines 4.5 kB history raw
1{-# OPTIONS_GHC -Wall #-}
2module Transform.Declaration (combineAnnotations, toExpr) where
4import Control.Applicative ((<$>))
6import qualified AST.Annotation as A
7import qualified AST.Declaration as D
8import qualified AST.Expression.General as E
9import qualified AST.Expression.Source as Source
10import qualified AST.Expression.Valid as Valid
11import qualified AST.Expression.Canonical as Canonical
12import qualified AST.Module as Module
13import qualified AST.Pattern as P
14import qualified AST.Type as T
15import qualified AST.Variable as Var
17import qualified Transform.Expression as Expr
18import qualified Transform.Definition as Def
21combineAnnotations :: [D.SourceDecl] -> Either String [D.ValidDecl]
22combineAnnotations =
23 go
24 where
25 errorMessage kind name =
26 "Syntax Error: The type annotation for " ++ kind ++ " '" ++
27 name ++ "' must be directly above its definition."
29 exprCombineAnnotations =
30 Expr.crawlLet Def.combineAnnotations
32 go decls =
33 case decls of
34 -- simple cases, pass them through with no changes
35 [] ->
36 return []
38 D.Datatype name tvars ctors : rest ->
39 (:) (D.Datatype name tvars ctors) <$> go rest
41 D.TypeAlias name tvars alias : rest ->
42 (:) (D.TypeAlias name tvars alias) <$> go rest
44 D.Fixity assoc prec op : rest ->
45 (:) (D.Fixity assoc prec op) <$> go rest
47 D.Port name tipe : rest ->
48 (:) (D.Port name tipe) <$> go rest
50 -- combine definitions
51 D.Definition def : defRest ->
52 case def of
53 Source.Definition pat expr ->
54 do expr' <- exprCombineAnnotations expr
55 let def' = Valid.Definition pat expr' Nothing
56 (:) (D.Definition def') <$> go defRest
58 Source.TypeAnnotation name tipe ->
59 case defRest of
60 D.Definition (Source.Definition pat@(P.Var name') expr) : rest
61 | name == name' ->
62 do expr' <- exprCombineAnnotations expr
63 let def' = Valid.Definition pat expr' (Just tipe)
64 (:) (D.Definition def') <$> go rest
66 _ -> Left (errorMessage "value" name)
69toExpr :: Module.Name -> [D.CanonicalDecl] -> [Canonical.Def]
70toExpr moduleName =
71 concatMap (toDefs moduleName)
74toDefs :: Module.Name -> D.CanonicalDecl -> [Canonical.Def]
75toDefs moduleName decl =
76 let typeVar = Var.Canonical (Var.Module moduleName) in
77 case decl of
78 D.Definition def ->
79 [def]
81 D.Datatype name tvars constructors ->
82 concatMap toDefs' constructors
83 where
84 toDefs' (ctor, tipes) =
85 let vars = take (length tipes) arguments
86 tbody = T.App (T.Type (typeVar name)) (map T.Var tvars)
87 body = A.none . E.Data ctor $ map (A.none . E.localVar) vars
88 in
89 [ definition ctor (buildFunction body vars) (foldr T.Lambda tbody tipes) ]
91 D.TypeAlias name tvars tipe@(T.Record fields ext) ->
92 [ definition name (buildFunction record vars) (foldr T.Lambda result args) ]
93 where
94 result =
95 T.Aliased (typeVar name) (zip tvars (map T.Var tvars)) tipe
97 args =
98 map snd fields ++ maybe [] (:[]) ext
100 var = A.none . E.localVar
101 vars = take (length args) arguments
103 efields = zip (map fst fields) (map var vars)
104 record =
105 case ext of
106 Nothing -> A.none $ E.Record efields
107 Just _ ->
108 foldl (\r (f,v) -> A.none $ E.Insert r f v) (var $ last vars) efields
110 -- Type aliases must be added to an extended equality dictionary,
111 -- but they do not require any basic constraints.
112 D.TypeAlias _ _ _ ->
113 []
115 D.Port name tipe ->
116 [ definition name (A.none $ E.Port name tipe) (T.portTypeToType tipe) ]
118 -- no constraints are needed for fixity declarations
119 D.Fixity _ _ _ ->
120 []
123arguments :: [String]
124arguments =
125 map (:[]) ['a'..'z'] ++ map (\n -> "_" ++ show (n :: Int)) [1..]
128buildFunction :: Canonical.Expr -> [String] -> Canonical.Expr
129buildFunction body@(A.A s _) vars =
130 foldr (\p e -> A.A s (E.Lambda p e)) body (map P.Var vars)
133definition :: String -> Canonical.Expr -> T.CanonicalType -> Canonical.Def
134definition name expr tipe =
135 Canonical.Definition (P.Var name) expr (Just tipe)