git.iko.soy/elk
on 42f3721 help sign in
elk/compiler/src/Parse/Module.hs
297 lines 7.1 kB history raw
1{-# OPTIONS_GHC -Wall #-}
2{-# LANGUAGE OverloadedStrings #-}
3module Parse.Module
4 ( module_
5 , chompImports
6 , freshLine
7 , exposing
8 )
9 where
12import qualified Data.Name as Name
14import qualified AST.Source as Src
15import qualified Elm.Compiler.Imports as Imports
16import qualified Elm.Package as Pkg
17import Parse.Primitives (Parser, oneOf)
18import qualified Parse.Primitives as P
19import qualified Parse.Primitives.Keyword as Keyword
20import qualified Parse.Primitives.Symbol as Symbol
21import qualified Parse.Primitives.Variable as Var
22import qualified Parse.Primitives.Whitespace as W
23import qualified Reporting.Annotation as A
24import qualified Reporting.Error.Syntax as E
25import qualified Reporting.Region as R
29-- MODULE
32module_ :: Pkg.Name -> Parser decls -> Parser (Src.Module decls)
33module_ pkgName chompDecls =
34 do freshLine
35 header <- oneOf [ Just <$> chompHeader, return Nothing ]
36 imports <- Imports.addDefaults pkgName <$> chompImports []
37 decls <- chompDecls
38 return (Src.Module header imports decls)
41chompHeader :: Parser Src.Header
42chompHeader =
43 do start <- P.getPosition
44 P.pushContext start E.Module
45 (name, effects) <- chompNameAndEffects
46 P.hint E.Exposing $ Keyword.exposing_
47 P.spaces
48 exports <- P.addLocation exposing
49 P.popContext ()
50 docs <- chompDocComment
51 return (Src.Header name effects exports docs)
55-- MODULE NAME
56--
57-- module MyThing
58-- port module MyThing
59-- effect module MyThing where { command = MyCmd }
60--
61chompNameAndEffects :: Parser (Name.Name, Src.Effects)
62chompNameAndEffects =
63 oneOf
64 [
65 do Keyword.module_
66 P.spaces
67 name <- Var.moduleName
68 P.spaces
69 return ( name, Src.NoEffects )
70 ,
71 do start <- P.getPosition
72 Keyword.port_
73 P.spaces
74 Keyword.module_
75 end <- P.getPosition
76 P.spaces
77 name <- Var.moduleName
78 P.spaces
79 return ( name, Src.Ports (R.Region start end) )
80 ,
81 do start <- P.getPosition
82 Keyword.effect_
83 P.spaces
84 Keyword.module_
85 end <- P.getPosition
86 P.spaces
87 name <- Var.moduleName
88 P.spaces
89 manager <- chompManager
90 return ( name, Src.Manager (R.Region start end) manager )
91 ]
95-- MANAGER
96--
97-- where { command = MyCmd }
98-- where { subscription = MySub }
99-- where { command = MyCmd, subscription = MySub }
100--
101chompManager :: Parser Src.Manager
102chompManager =
103 do Keyword.where_
104 P.spaces
105 Symbol.leftCurly
106 P.spaces
107 oneOf
108 [ do cmd <- chompCommand
109 P.spaces
110 oneOf
111 [ do Symbol.rightCurly
112 P.spaces
113 return (Src.Cmd cmd)
114 , do Symbol.comma
115 P.spaces
116 sub <- chompSubscription
117 P.spaces
118 Symbol.rightCurly
119 P.spaces
120 return (Src.Fx cmd sub)
121 ]
122 , do sub <- chompSubscription
123 P.spaces
124 oneOf
125 [ do Symbol.rightCurly
126 P.spaces
127 return (Src.Sub sub)
128 , do Symbol.comma
129 P.spaces
130 cmd <- chompCommand
131 P.spaces
132 Symbol.rightCurly
133 P.spaces
134 return (Src.Fx cmd sub)
135 ]
136 ]
139chompCommand :: Parser (A.Located Name.Name)
140chompCommand =
141 do Keyword.command_
142 P.spaces
143 Symbol.equals
144 P.spaces
145 P.addLocation Var.upper
148chompSubscription :: Parser (A.Located Name.Name)
149chompSubscription =
150 do Keyword.subscription_
151 P.spaces
152 Symbol.equals
153 P.spaces
154 P.addLocation Var.upper
158-- DOC COMMENTS
161chompDocComment :: Parser Src.Docs
162chompDocComment =
163 do endOfExposing <- P.getPosition
164 freshLine
165 nextStart <- P.getPosition
166 oneOf
167 [ do doc <- W.docComment
168 docEnd <- P.getPosition
169 freshLine
170 return (Src.YesDocs (R.Region nextStart docEnd) doc)
171 , return (Src.NoDocs (R.Region endOfExposing nextStart))
172 ]
176-- IMPORTS
179chompImports :: [Src.Import] -> Parser [Src.Import]
180chompImports imports =
181 oneOf
182 [ do start <- P.getPosition
183 Keyword.import_
184 P.pushContext start E.Import
185 P.spaces
186 name <- P.addLocation Var.moduleName
187 pos <- W.whitespace
188 oneOf
189 [ do P.checkFreshLine pos
190 P.popContext ()
191 chompImports $
192 Src.Import name Nothing (Src.Explicit []) : imports
193 , do P.checkSpace pos
194 oneOf
195 [ chompAs name imports
196 , chompExposing name Nothing imports
197 ]
198 ]
199 , return (reverse imports)
200 ]
203chompAs :: A.Located Name.Name -> [Src.Import] -> Parser [Src.Import]
204chompAs name imports =
205 do Keyword.as_
206 P.spaces
207 alias <- Var.upper
208 pos <- W.whitespace
209 oneOf
210 [ do P.checkFreshLine pos
211 P.popContext ()
212 chompImports $
213 Src.Import name (Just alias) (Src.Explicit []) : imports
214 , do P.checkSpace pos
215 chompExposing name (Just alias) imports
216 ]
219chompExposing :: A.Located Name.Name -> Maybe Name.Name -> [Src.Import] -> Parser [Src.Import]
220chompExposing name maybeAlias imports =
221 do Keyword.exposing_
222 P.spaces
223 exposed <- exposing
224 freshLine
225 P.popContext ()
226 chompImports $
227 Src.Import name maybeAlias exposed : imports
231-- LISTING
234exposing :: Parser Src.Exposing
235exposing =
236 P.hint E.Listing $
237 do Symbol.leftParen
238 P.spaces
239 oneOf
240 [ do Symbol.doubleDot
241 P.spaces
242 Symbol.rightParen
243 return Src.Open
244 , do entry <- P.addLocation chompEntry
245 P.spaces
246 exposingHelp [entry]
247 ]
250exposingHelp :: [A.Located Src.Exposed] -> Parser Src.Exposing
251exposingHelp revEntries =
252 oneOf
253 [ do Symbol.comma
254 P.spaces
255 entry <- P.addLocation chompEntry
256 P.spaces
257 exposingHelp (entry:revEntries)
258 , do Symbol.rightParen
259 return (Src.Explicit (reverse revEntries))
260 ]
263chompEntry :: Parser Src.Exposed
264chompEntry =
265 oneOf
266 [ Src.Lower <$> Var.lower
267 , do Symbol.leftParen
268 op <- Symbol.binop
269 Symbol.rightParen
270 return (Src.Operator op)
271 , do name <- Var.upper
272 P.spaces
273 Src.Upper name <$> privacy
274 ]
277privacy :: Parser Src.Privacy
278privacy =
279 oneOf
280 [ do Symbol.leftParen
281 P.spaces
282 Symbol.doubleDot
283 P.spaces
284 Symbol.rightParen
285 return Src.Public
286 , return Src.Private
287 ]
291-- FRESH LINES
294freshLine :: Parser ()
295freshLine =
296 P.checkFreshLine =<< W.whitespace