git.iko.soy/elk
on a3a7b3e help sign in
elk/compiler/SourceSyntax/Expression.hs
127 lines 4.6 kB history raw
1{-# LANGUAGE DeriveDataTypeable #-}
2module SourceSyntax.Expression where
4import Data.Data
5import Data.List (intercalate)
6import qualified Text.Pandoc as Pandoc
7import SourceSyntax.PrettyPrint
8import Text.PrettyPrint as P
9import qualified SourceSyntax.Helpers as Help
10import qualified SourceSyntax.Location as Location
11import qualified SourceSyntax.Pattern as Pattern
12import qualified SourceSyntax.Type as Type
13import qualified SourceSyntax.Literal as Literal
15type LExpr tipe var = Location.Located (Expr tipe var)
16data Expr t v
17 = Literal Literal.Literal
18 | Var String
19 | Range (LExpr t v) (LExpr t v)
20 | ExplicitList [LExpr t v]
21 | Binop String (LExpr t v) (LExpr t v)
22 | Lambda Pattern.Pattern (LExpr t v)
23 | App (LExpr t v) (LExpr t v)
24 | MultiIf [(LExpr t v,LExpr t v)]
25 | Let [Def t v] (LExpr t v)
26 | Case (LExpr t v) [(Pattern.Pattern, LExpr t v)]
27 | Data String [LExpr t v]
28 | Access (LExpr t v) String
29 | Remove (LExpr t v) String
30 | Insert (LExpr t v) String (LExpr t v)
31 | Modify (LExpr t v) [(String, LExpr t v)]
32 | Record [(String, LExpr t v)]
33 | Markdown Pandoc.Pandoc
34 deriving (Eq, Show, Data, Typeable)
36data Def tipe var
37 = Def Pattern.Pattern (LExpr tipe var)
38 | TypeAnnotation String Type.Type
39 deriving (Eq, Show, Data, Typeable)
41tuple es = Data ("_Tuple" ++ show (length es)) es
43delist (Location.L _ _ (Data "::" [h,t])) = h : delist t
44delist _ = []
46dummyLet defs =
47 Location.none $ Let defs (Location.none . Literal $ Literal.IntNum 42)
49instance Pretty (Expr t v) where
50 pretty expr =
51 case expr of
52 Literal lit -> pretty lit
53 Var x -> parensIf (Help.isOp x) (P.text x)
54 Range e1 e2 -> P.brackets (pretty e1 <> P.text ".." <> pretty e2)
55 ExplicitList es -> P.brackets (commaCat (map pretty es))
56 Binop op e1 e2 -> P.sep [ prettyParens e1 <+> P.text op, prettyParens e2 ]
57 Lambda p e -> let (ps,body) = collectLambdas (Location.none $ Lambda p e)
58 in P.text "\\" <> P.sep ps <+> P.text "->" <+> pretty body
59 App _ _ -> P.hang func 2 (P.sep args)
60 where func:args = map prettyParens (collectApps (Location.none expr))
61 MultiIf branches -> P.text "if" $$ nest 3 (vcat $ map iff branches)
62 where
63 iff (b,e) = P.text "|" <+> P.hang (pretty b <+> P.text "->") 2 (pretty e)
64 Let defs e ->
65 P.sep [ P.hang (P.text "let") 4 (P.vcat (map pretty defs))
66 , P.text "in" <+> pretty e ]
67 Case e pats ->
68 P.hang pexpr 2 (P.vcat (map pretty' pats))
69 where
70 pexpr = P.sep [ P.text "case" <+> pretty e, P.text "of" ]
71 pretty' (p,e) = pretty p <+> P.text "->" <+> pretty e
72 Data "::" [hd,tl] -> pretty hd <+> P.text "::" <+> pretty tl
73 Data "[]" [] -> P.text "[]"
74 Data name es -> P.hang (P.text name) 2 (P.sep (map prettyParens es))
75 Access e x -> prettyParens e <> P.text "." <> P.text x
76 Remove e x -> P.braces (pretty e <+> P.text "-" <+> P.text x)
77 Insert (Location.L _ _ (Remove e y)) x v ->
78 P.braces (pretty e <+> P.text "-" <+> P.text y <+> P.text "|" <+> P.text x <+> P.text "=" <+> pretty v)
79 Insert e x v ->
80 P.braces (pretty e <+> P.text "|" <+> P.text x <+> P.text "=" <+> pretty v)
82 Modify e fs ->
83 P.braces $ P.hang (pretty e <+> P.text "|")
84 4
85 (P.sep . P.punctuate P.comma $ map field fs)
86 where
87 field (x,e) = P.text x <+> P.text "<-" <+> pretty e
89 Record fs ->
90 P.braces $ P.nest 2 (P.sep . P.punctuate P.comma $ map field fs)
91 where
92 field (x,e) = P.text x <+> P.text "=" <+> pretty e
94 Markdown _ -> P.text "[markdown| ... |]"
96instance Pretty (Def t v) where
97 pretty def =
98 case def of
99 TypeAnnotation name tipe ->
100 P.text name <+> P.text ":" <+> P.text (show tipe)
101 Def pattern expr ->
102 pretty pattern <+> P.text "=" <+> pretty expr
104collectApps lexpr@(Location.L _ _ expr) =
105 case expr of
106 App a b -> collectApps a ++ [b]
107 _ -> [lexpr]
109collectLambdas lexpr@(Location.L _ _ expr) =
110 case expr of
111 Lambda pattern body ->
112 let (ps, body') = collectLambdas body
113 in (pretty pattern : ps, body')
114 _ -> ([], lexpr)
116prettyParens (Location.L _ _ expr) = parensIf needed (pretty expr)
117 where
118 needed =
119 case expr of
120 Binop _ _ _ -> True
121 Lambda _ _ -> True
122 App _ _ -> True
123 MultiIf _ -> True
124 Let _ _ -> True
125 Case _ _ -> True
126 Data name (x:xs) -> name /= "::"
127 _ -> False