git.iko.soy/elk
on ef280ed help sign in
elk/src/Compile.hs
69 lines 2.1 kB history raw
1module Compile (compile) where
3import qualified Data.Map as Map
5import qualified AST.Module as Module
6import qualified AST.Module.Name as ModuleName
7import qualified Canonicalize
8import Elm.Utils ((|>))
9import qualified Elm.Package as Package
10import qualified Nitpick.PatternMatches as Nitpick
11import qualified Nitpick.TopLevelTypes as Nitpick
12import qualified Optimize
13import qualified Parse.Helpers as Parse
14import qualified Parse.Parse as Parse
15import qualified Reporting.Error as Error
16import qualified Reporting.Result as Result
17import qualified Reporting.Warning as Warning
18import qualified Type.Inference as TI
21compile
22 :: Package.Name
23 -> Bool
24 -> [ModuleName.Canonical]
25 -> Module.Interfaces
26 -> String
27 -> Result.Result Warning.Warning Error.Error Module.Optimized
29compile packageName isRoot canonicalImports interfaces source =
30 do
31 -- Parse the source code
32 validModule <-
33 Result.mapError Error.Syntax $
34 Parse.program packageName isRoot (getOpTable interfaces) source
36 -- Canonicalize all variables, pinning down where they came from.
37 canonicalModule <-
38 Canonicalize.module' canonicalImports interfaces validModule
40 -- Run type inference on the program.
41 types <-
42 Result.from Error.Type $
43 TI.infer interfaces canonicalModule
45 -- One last round of checks
46 Result.mapError Error.Type $
47 Nitpick.topLevelTypes types (Module.body validModule)
49 tagDict <-
50 Result.mapError Error.Pattern $
51 Nitpick.patternMatches interfaces canonicalModule
53 -- Add the real list of types
54 let body =
55 (Module.body canonicalModule) { Module.types = types }
57 -- Do some basic optimizations
58 let optModule =
59 Optimize.optimize tagDict (canonicalModule { Module.body = body })
61 return optModule
64getOpTable :: Module.Interfaces -> Parse.OpTable
65getOpTable interfaces =
66 Map.elems interfaces
67 |> concatMap Module.iFixities
68 |> map (\(assoc,lvl,op) -> (op,(lvl,assoc)))
69 |> Map.fromList