git.iko.soy/elk
on f41abda help sign in
elk/src/Parse/Module.hs
296 lines 7.0 kB history raw
1{-# OPTIONS_GHC -Wall #-}
2{-# LANGUAGE OverloadedStrings #-}
3module Parse.Module
4 ( module_
5 , chompImports
6 , freshLine
7 )
8 where
11import qualified Data.ByteString as B
12import Data.Text (Text)
14import qualified AST.Source as Src
15import qualified Elm.Name as N
16import Parse.Primitives (Parser, oneOf)
17import qualified Parse.Primitives as P
18import qualified Parse.Primitives.Keyword as Keyword
19import qualified Parse.Primitives.Symbol as Symbol
20import qualified Parse.Primitives.Variable as Var
21import qualified Parse.Primitives.Whitespace as W
22import qualified Reporting.Annotation as A
23import qualified Reporting.Error.Syntax as E
24import qualified Reporting.Region as R
28-- MODULE
31module_ :: Parser decls -> Parser (Src.Module decls)
32module_ chompDecls =
33 do freshLine
34 header <- oneOf [ Just <$> chompHeader, return Nothing ]
35 imports <- chompImports []
36 decls <- chompDecls
37 return (Src.Module header imports decls)
40chompHeader :: Parser Src.Header
41chompHeader =
42 do start <- P.getPosition
43 P.pushContext start E.Module
44 (name, effects) <- chompNameAndEffects
45 P.hint E.Exposing $ Keyword.exposing_
46 P.spaces
47 exports <- exposing
48 P.popContext ()
49 docs <- maybeDocComment
50 return (Src.Header name effects exports docs)
54-- MODULE NAME
55--
56-- module MyThing
57-- port module MyThing
58-- effect module MyThing where { command = MyCmd }
59--
60chompNameAndEffects :: Parser (N.Name, Src.Effects)
61chompNameAndEffects =
62 oneOf
63 [
64 do Keyword.module_
65 P.spaces
66 name <- Var.moduleName
67 P.spaces
68 return ( name, Src.NoEffects )
69 ,
70 do start <- P.getPosition
71 Keyword.port_
72 P.spaces
73 Keyword.module_
74 end <- P.getPosition
75 P.spaces
76 name <- Var.moduleName
77 P.spaces
78 return ( name, Src.Ports (R.Region start end) )
79 ,
80 do start <- P.getPosition
81 Keyword.effect_
82 P.spaces
83 Keyword.module_
84 end <- P.getPosition
85 P.spaces
86 name <- Var.moduleName
87 P.spaces
88 manager <- chompManager
89 return ( name, Src.Manager (R.Region start end) manager )
90 ]
94-- MANAGER
95--
96-- where { command = MyCmd }
97-- where { subscription = MySub }
98-- where { command = MyCmd, subscription = MySub }
99--
100chompManager :: Parser Src.Manager
101chompManager =
102 do Keyword.where_
103 P.spaces
104 Symbol.leftCurly
105 P.spaces
106 oneOf
107 [ do cmd <- chompCommand
108 P.spaces
109 oneOf
110 [ do Symbol.rightCurly
111 P.spaces
112 return (Src.Cmd cmd)
113 , do Symbol.comma
114 P.spaces
115 sub <- chompSubscription
116 P.spaces
117 Symbol.rightCurly
118 P.spaces
119 return (Src.Fx cmd sub)
120 ]
121 , do sub <- chompSubscription
122 P.spaces
123 oneOf
124 [ do Symbol.rightCurly
125 P.spaces
126 return (Src.Sub sub)
127 , do Symbol.comma
128 P.spaces
129 cmd <- chompCommand
130 P.spaces
131 Symbol.rightCurly
132 P.spaces
133 return (Src.Fx cmd sub)
134 ]
135 ]
138chompCommand :: Parser (A.Located Text)
139chompCommand =
140 do Keyword.command_
141 P.spaces
142 Symbol.equals
143 P.spaces
144 P.addLocation Var.upper
147chompSubscription :: Parser (A.Located Text)
148chompSubscription =
149 do Keyword.subscription_
150 P.spaces
151 Symbol.equals
152 P.spaces
153 P.addLocation Var.upper
157-- DOC COMMENTS
160maybeDocComment :: Parser (A.Located (Maybe B.ByteString))
161maybeDocComment =
162 do oldEnd <- P.getPosition
163 freshLine
164 newStart <- P.getPosition
165 oneOf
166 [ do doc <- W.docComment
167 end <- P.getPosition
168 freshLine
169 return (A.at newStart end (Just doc))
170 , return (A.at oldEnd newStart Nothing)
171 ]
175-- IMPORTS
178chompImports :: [Src.Import] -> Parser [Src.Import]
179chompImports imports =
180 oneOf
181 [ do start <- P.getPosition
182 Keyword.import_
183 P.pushContext start E.Import
184 P.spaces
185 name <- P.addLocation Var.moduleName
186 pos <- W.whitespace
187 oneOf
188 [ do P.checkFreshLine pos
189 P.popContext ()
190 chompImports $
191 Src.Import name Nothing (Src.Explicit []) : imports
192 , do P.checkSpace pos
193 oneOf
194 [ chompAs name imports
195 , chompExposing name Nothing imports
196 ]
197 ]
198 , return (reverse imports)
199 ]
202chompAs :: A.Located Text -> [Src.Import] -> Parser [Src.Import]
203chompAs name imports =
204 do Keyword.as_
205 P.spaces
206 alias <- Var.upper
207 pos <- W.whitespace
208 oneOf
209 [ do P.checkFreshLine pos
210 P.popContext ()
211 chompImports $
212 Src.Import name (Just alias) (Src.Explicit []) : imports
213 , do P.checkSpace pos
214 chompExposing name (Just alias) imports
215 ]
218chompExposing :: A.Located Text -> Maybe Text -> [Src.Import] -> Parser [Src.Import]
219chompExposing name maybeAlias imports =
220 do Keyword.exposing_
221 P.spaces
222 exposed <- exposing
223 freshLine
224 P.popContext ()
225 chompImports $
226 Src.Import name maybeAlias exposed : imports
230-- LISTING
233exposing :: Parser Src.Exposing
234exposing =
235 P.hint E.Listing $
236 do Symbol.leftParen
237 P.spaces
238 oneOf
239 [ do Symbol.doubleDot
240 P.spaces
241 Symbol.rightParen
242 return Src.Open
243 , do entry <- P.addLocation chompEntry
244 P.spaces
245 exposingHelp [entry]
246 ]
249exposingHelp :: [A.Located Src.Exposed] -> Parser Src.Exposing
250exposingHelp revEntries =
251 oneOf
252 [ do Symbol.comma
253 P.spaces
254 entry <- P.addLocation chompEntry
255 P.spaces
256 exposingHelp (entry:revEntries)
257 , do Symbol.rightParen
258 return (Src.Explicit (reverse revEntries))
259 ]
262chompEntry :: Parser Src.Exposed
263chompEntry =
264 oneOf
265 [ Src.Lower <$> Var.lower
266 , do Symbol.leftParen
267 op <- Symbol.binop
268 Symbol.rightParen
269 return (Src.Lower op)
270 , do name <- Var.upper
271 P.spaces
272 Src.Upper name <$> privacy
273 ]
276privacy :: Parser Src.Privacy
277privacy =
278 oneOf
279 [ do Symbol.leftParen
280 P.spaces
281 Symbol.doubleDot
282 P.spaces
283 Symbol.rightParen
284 return Src.Public
285 , return Src.Private
286 ]
290-- FRESH LINES
293freshLine :: Parser ()
294freshLine =
295 P.checkFreshLine =<< W.whitespace