git.iko.soy/ghcide
on 8bce2dd help sign in
ghcide/src/Development/IDE/Types/Diagnostics.hs
114 lines 3.6 kB history raw
1-- Copyright (c) 2019 Digital Asset (Switzerland) GmbH and/or its affiliates. All rights reserved.
2-- SPDX-License-Identifier: Apache-2.0
4{-# LANGUAGE OverloadedStrings #-}
6module Development.IDE.Types.Diagnostics (
7 LSP.Diagnostic(..),
8 FileDiagnostic,
9 LSP.DiagnosticSeverity(..),
10 DiagnosticStore,
11 List(..),
12 ideErrorText,
13 showDiagnostics,
14 showDiagnosticsColored,
15 ) where
17import Data.Maybe as Maybe
18import qualified Data.Text as T
19import Data.Text.Prettyprint.Doc
20import qualified Language.Haskell.LSP.Types as LSP
21import Language.Haskell.LSP.Types as LSP (
22 DiagnosticSeverity(..)
23 , Diagnostic(..)
24 , List(..)
25 )
26import Language.Haskell.LSP.Diagnostics
27import Data.Text.Prettyprint.Doc.Render.Text
28import qualified Data.Text.Prettyprint.Doc.Render.Terminal as Terminal
29import Data.Text.Prettyprint.Doc.Render.Terminal (Color(..), color)
31import Development.IDE.Types.Location
34ideErrorText :: NormalizedFilePath -> T.Text -> FileDiagnostic
35ideErrorText fp msg = (fp, LSP.Diagnostic {
36 _range = noRange,
37 _severity = Just LSP.DsError,
38 _code = Nothing,
39 _source = Just "compiler",
40 _message = msg,
41 _relatedInformation = Nothing
42 })
45-- | Human readable diagnostics for a specific file.
46--
47-- This type packages a pretty printed, human readable error message
48-- along with the related source location so that we can display the error
49-- on either the console or in the IDE at the right source location.
50--
51type FileDiagnostic = (NormalizedFilePath, Diagnostic)
53prettyRange :: Range -> Doc Terminal.AnsiStyle
54prettyRange Range{..} = f _start <> "-" <> f _end
55 where f Position{..} = pretty (_line+1) <> colon <> pretty _character
57stringParagraphs :: T.Text -> Doc a
58stringParagraphs = vcat . map (fillSep . map pretty . T.words) . T.lines
60showDiagnostics :: [FileDiagnostic] -> T.Text
61showDiagnostics = srenderPlain . prettyDiagnostics
63showDiagnosticsColored :: [FileDiagnostic] -> T.Text
64showDiagnosticsColored = srenderColored . prettyDiagnostics
67prettyDiagnostics :: [FileDiagnostic] -> Doc Terminal.AnsiStyle
68prettyDiagnostics = vcat . map prettyDiagnostic
70prettyDiagnostic :: FileDiagnostic -> Doc Terminal.AnsiStyle
71prettyDiagnostic (fp, LSP.Diagnostic{..}) =
72 vcat
73 [ slabel_ "File: " $ pretty (fromNormalizedFilePath fp)
74 , slabel_ "Range: " $ prettyRange _range
75 , slabel_ "Source: " $ pretty _source
76 , slabel_ "Severity:" $ pretty $ show sev
77 , slabel_ "Message: "
78 $ case sev of
79 LSP.DsError -> annotate $ color Red
80 LSP.DsWarning -> annotate $ color Yellow
81 LSP.DsInfo -> annotate $ color Blue
82 LSP.DsHint -> annotate $ color Magenta
83 $ stringParagraphs _message
84 , slabel_ "Code:" $ pretty _code
85 ]
86 where
87 sev = fromMaybe LSP.DsError _severity
90-- | Label a document.
91slabel_ :: String -> Doc a -> Doc a
92slabel_ t d = nest 2 $ sep [pretty t, d]
94-- | The layout options used for the SDK assistant.
95cliLayout ::
96 Int
97 -- ^ Rendering width of the pretty printer.
98 -> LayoutOptions
99cliLayout renderWidth = LayoutOptions
100 { layoutPageWidth = AvailablePerLine renderWidth 0.9
101 }
103-- | Render without any syntax annotations
104srenderPlain :: Doc ann -> T.Text
105srenderPlain = renderStrict . layoutSmart (cliLayout defaultTermWidth)
107-- | Render a 'Document' as an ANSII colored string.
108srenderColored :: Doc Terminal.AnsiStyle -> T.Text
109srenderColored =
110 Terminal.renderStrict .
111 layoutSmart defaultLayoutOptions { layoutPageWidth = AvailablePerLine 100 1.0 }
113defaultTermWidth :: Int
114defaultTermWidth = 80