git.iko.soy/hakyll
on 2ef7fee help sign in
hakyll/src/Hakyll/Core/Provider/Metadata.hs
134 lines 4.8 kB history raw
1--------------------------------------------------------------------------------
2-- | Internal module to parse metadata
3module Hakyll.Core.Provider.Metadata
4 ( loadMetadata
5 , metadata
6 , page
8 -- This parser can be reused in some places
9 , metadataKey
10 ) where
13--------------------------------------------------------------------------------
14import Control.Applicative
15import Control.Arrow (second)
16import qualified Data.ByteString.Char8 as BC
17import Data.List (intercalate)
18import qualified Data.Map as M
19import System.IO as IO
20import Text.Parsec ((<?>))
21import qualified Text.Parsec as P
22import Text.Parsec.String (Parser)
25--------------------------------------------------------------------------------
26import Hakyll.Core.Identifier
27import Hakyll.Core.Metadata
28import Hakyll.Core.Provider.Internal
29import Hakyll.Core.Util.Parser
30import Hakyll.Core.Util.String
33--------------------------------------------------------------------------------
34loadMetadata :: Provider -> Identifier -> IO (Metadata, Maybe String)
35loadMetadata p identifier = do
36 hasHeader <- probablyHasMetadataHeader fp
37 (md, body) <- if hasHeader
38 then second Just <$> loadMetadataHeader fp
39 else return (M.empty, Nothing)
41 emd <- case mi of
42 Nothing -> return M.empty
43 Just mi' -> loadMetadataFile $ resourceFilePath p mi'
45 return (M.union md emd, body)
46 where
47 fp = resourceFilePath p identifier
48 mi = M.lookup identifier (providerFiles p) >>= resourceInfoMetadata
51--------------------------------------------------------------------------------
52loadMetadataHeader :: FilePath -> IO (Metadata, String)
53loadMetadataHeader fp = do
54 contents <- readFile fp
55 case P.parse page fp contents of
56 Left err -> error (show err)
57 Right (md, b) -> return (M.fromList md, b)
60--------------------------------------------------------------------------------
61loadMetadataFile :: FilePath -> IO Metadata
62loadMetadataFile fp = do
63 contents <- readFile fp
64 case P.parse metadata fp contents of
65 Left err -> error (show err)
66 Right md -> return $ M.fromList md
69--------------------------------------------------------------------------------
70-- | Check if a file "probably" has a metadata header. The main goal of this is
71-- to exclude binary files (which are unlikely to start with "---").
72probablyHasMetadataHeader :: FilePath -> IO Bool
73probablyHasMetadataHeader fp = do
74 handle <- IO.openFile fp IO.ReadMode
75 bs <- BC.hGet handle 1024
76 IO.hClose handle
77 return $ isMetadataHeader bs
78 where
79 isMetadataHeader bs =
80 let pre = BC.takeWhile (\x -> x /= '\n' && x /= '\r') bs
81 in BC.length pre >= 3 && BC.all (== '-') pre
84--------------------------------------------------------------------------------
85-- | Space or tab, no newline
86inlineSpace :: Parser Char
87inlineSpace = P.oneOf ['\t', ' '] <?> "space"
90--------------------------------------------------------------------------------
91-- | Parse Windows newlines as well (i.e. "\n" or "\r\n")
92newline :: Parser String
93newline = P.string "\n" <|> P.string "\r\n"
96--------------------------------------------------------------------------------
97-- | Parse a single metadata field
98metadataField :: Parser (String, String)
99metadataField = do
100 key <- metadataKey
101 _ <- P.char ':'
102 P.skipMany1 inlineSpace <?> "space followed by metadata for: " ++ key
103 value <- P.manyTill P.anyChar newline
104 trailing' <- P.many trailing
105 return (key, trim $ intercalate " " $ value : trailing')
106 where
107 trailing = P.many1 inlineSpace *> P.manyTill P.anyChar newline
110--------------------------------------------------------------------------------
111-- | Parse a metadata block
112metadata :: Parser [(String, String)]
113metadata = P.many metadataField
116--------------------------------------------------------------------------------
117-- | Parse a metadata block, including delimiters and trailing newlines
118metadataBlock :: Parser [(String, String)]
119metadataBlock = do
120 open <- P.many1 (P.char '-') <* P.many inlineSpace <* newline
121 metadata' <- metadata
122 _ <- P.choice $ map (P.string . replicate (length open)) ['-', '.']
123 P.skipMany inlineSpace
124 P.skipMany1 newline
125 return metadata'
128--------------------------------------------------------------------------------
129-- | Parse a page consisting of a metadata header and a body
130page :: Parser ([(String, String)], String)
131page = do
132 metadata' <- P.option [] metadataBlock
133 body <- P.many P.anyChar
134 return (metadata', body)