Outputs traces to stdout in addition to exporting via otlp. Stdout contains one JSON object per line, with a single span resource in each output line. This will make it quite a bit easier for me to get a quick look at what is going on in the engine during local development.
The first commit makes the change using the existing opentelemetry crate versions. The second commit upgrades the opentelemetry dependencies. I thought I would include that just because I went to the trouble of figuring out how to do that upgrade.
The JSON output is noisy, but can be formatted nicely with some shell functions. For example in nushell I use these functions to process the opentelemetry data coming via docker-compose or arion-compose log output:
```nu
# Get log output from arion/docker-compose services with JSON parsing. If an
# argument is given filters to logs from the given service
def logs [
service?: string@docker_compose_services
--file (-f): string = "./arion-compose.nix" # Use FILE instead of the default ./arion-compose.nix
] {
let args = [$service] | compact
let input = if ($file | path exists) {
arion --file $file logs ...$args
} else {
docker-compose logs ...$args
}
$input
| lines
| parse -r '^(?<service>\S+)\s*\|\s*(?<log>.*)$'
| where {|it| is_json $it.log}
| update log {|it| $it.log | from json }
| flatten
}
# Gets log output from a given docker-compose service, and extracts and formats
# relevant opentelemetry data
def otel [
service: string@docker_compose_services
--file (-f): string = "./arion-compose.nix" # Use FILE instead of the default ./arion-compose.nix
] {
logs $service -f $file | get resourceSpans | each {|it| $it.scopeSpans.0.spans.0 | select name attributes status }
}
# Helper to provide autocompletion for inputs to the logs command
def docker_compose_services [] {
let compose_file = if ("arion-compose.nix" | path exists) {
arion cat | from json
} else if ("docker-compose.yaml" | path exists) {
open docker-compose.yaml
} else {
return []
}
$compose_file | get services | columns
}
# Helper for the logs command
def is_json [input: string] {
($input | from json | describe) =~ '^(record|table|list)'
}
```
V3_GIT_ORIGIN_REV_ID: 38fd62f321a363a52b03d661b66d4dd49ac922de
