mirror of
https://github.com/hasura/graphql-engine.git
synced 2024-12-17 20:41:49 +03:00
11a454c2d6
This commit applies ormolu to the whole Haskell code base by running `make format`. For in-flight branches, simply merging changes from `main` will result in merge conflicts. To avoid this, update your branch using the following instructions. Replace `<format-commit>` by the hash of *this* commit. $ git checkout my-feature-branch $ git merge <format-commit>^ # and resolve conflicts normally $ make format $ git commit -a -m "reformat with ormolu" $ git merge -s ours post-ormolu https://github.com/hasura/graphql-engine-mono/pull/2404 GitOrigin-RevId: 75049f5c12f430c615eafb4c6b8e83e371e01c8e
66 lines
2.3 KiB
Haskell
66 lines
2.3 KiB
Haskell
module Hasura.Server.Middleware where
|
|
|
|
import Control.Applicative
|
|
import Data.ByteString qualified as B
|
|
import Data.CaseInsensitive qualified as CI
|
|
import Data.Text.Encoding qualified as TE
|
|
import Hasura.Prelude
|
|
import Hasura.Server.Cors
|
|
import Hasura.Server.Utils
|
|
import Network.HTTP.Types qualified as H
|
|
import Network.Wai
|
|
|
|
corsMiddleware :: CorsPolicy -> Middleware
|
|
corsMiddleware policy app req sendResp = do
|
|
let origin = getRequestHeader "Origin" $ requestHeaders req
|
|
maybe (app req sendResp) handleCors origin
|
|
where
|
|
handleCors origin = case cpConfig policy of
|
|
CCDisabled _ -> app req sendResp
|
|
CCAllowAll -> sendCors origin
|
|
CCAllowedOrigins ds
|
|
-- if the origin is in our cors domains, send cors headers
|
|
| bsToTxt origin `elem` dmFqdns ds -> sendCors origin
|
|
-- if current origin is part of wildcard domain list, send cors
|
|
| inWildcardList ds (bsToTxt origin) -> sendCors origin
|
|
-- otherwise don't send cors headers
|
|
| otherwise -> app req sendResp
|
|
|
|
sendCors :: B.ByteString -> IO ResponseReceived
|
|
sendCors origin =
|
|
case requestMethod req of
|
|
"OPTIONS" -> sendResp $ respondPreFlight origin
|
|
_ -> app req $ sendResp . injectCorsHeaders origin
|
|
|
|
respondPreFlight :: B.ByteString -> Response
|
|
respondPreFlight origin =
|
|
setHeaders (mkPreFlightHeaders requestedHeaders) $
|
|
injectCorsHeaders origin emptyResponse
|
|
|
|
emptyResponse = responseLBS H.status204 [] ""
|
|
requestedHeaders =
|
|
fromMaybe "" $
|
|
getRequestHeader "Access-Control-Request-Headers" $
|
|
requestHeaders req
|
|
|
|
injectCorsHeaders :: B.ByteString -> Response -> Response
|
|
injectCorsHeaders origin = setHeaders (mkCorsHeaders origin)
|
|
|
|
mkPreFlightHeaders allowReqHdrs =
|
|
[ ("Access-Control-Max-Age", "1728000"),
|
|
("Access-Control-Allow-Headers", allowReqHdrs),
|
|
("Content-Length", "0"),
|
|
("Content-Type", "text/plain charset=UTF-8")
|
|
]
|
|
|
|
mkCorsHeaders origin =
|
|
[ ("Access-Control-Allow-Origin", origin),
|
|
("Access-Control-Allow-Credentials", "true"),
|
|
( "Access-Control-Allow-Methods",
|
|
B.intercalate "," $ TE.encodeUtf8 <$> cpMethods policy
|
|
)
|
|
]
|
|
|
|
setHeaders hdrs = mapResponseHeaders (\h -> mkRespHdrs hdrs ++ h)
|
|
mkRespHdrs = map (\(k, v) -> (CI.mk k, v))
|