mirror of
https://github.com/hasura/graphql-engine.git
synced 2024-12-18 04:51:35 +03:00
8a77386fcf
### Description This PR adds the required IR for DB to DB joins, based on @paf31 and @0x777 's `feature/db-to-db` branch. To do so, it also refactors the IR to introduce a new type parameter, `r`, which is used to recursively constructs the `v` parameter of remote QueryDBs. When collecting remote joins, we replace `r` with `Const Void`, indicating at the type level that there cannot be any leftover remote join. Furthermore, this PR refactors IR.Select for readability, moves some code from IR.Root to IR.Select to avoid having to deal with circular dependencies, and makes it compile by adding `error` in all new cases in the execution pipeline. The diff doesn't make it clear, but most of Select.hs is actually unchanged. Declarations have just been reordered by topic, in the following order: - type declarations - instance declarations - type aliases - constructor functions - traverse functions https://github.com/hasura/graphql-engine-mono/pull/1580 Co-authored-by: Phil Freeman <630306+paf31@users.noreply.github.com> GitOrigin-RevId: bbdcb4119cec8bb3fc32f1294f91b8dea0728721
68 lines
2.1 KiB
Haskell
68 lines
2.1 KiB
Haskell
module Hasura.RQL.IR.Update where
|
|
|
|
import Hasura.Prelude
|
|
|
|
import Data.Kind (Type)
|
|
|
|
import Hasura.RQL.IR.BoolExp
|
|
import Hasura.RQL.IR.Returning
|
|
import Hasura.RQL.Types.Backend
|
|
import Hasura.RQL.Types.Column
|
|
import Hasura.SQL.Backend
|
|
|
|
|
|
data AnnUpdG (b :: BackendType) (r :: BackendType -> Type) v
|
|
= AnnUpd
|
|
{ uqp1Table :: !(TableName b)
|
|
, uqp1OpExps :: ![(Column b, UpdOpExpG v)]
|
|
, uqp1Where :: !(AnnBoolExp b v, AnnBoolExp b v)
|
|
, uqp1Check :: !(AnnBoolExp b v)
|
|
-- we don't prepare the arguments for returning
|
|
-- however the session variable can still be
|
|
-- converted as desired
|
|
, uqp1Output :: !(MutationOutputG b r v)
|
|
, uqp1AllCols :: ![ColumnInfo b]
|
|
}
|
|
|
|
type AnnUpd b = AnnUpdG b (Const Void) (SQLExpression b)
|
|
|
|
data UpdOpExpG v
|
|
= UpdSet !v
|
|
| UpdInc !v
|
|
| UpdAppend !v
|
|
| UpdPrepend !v
|
|
| UpdDeleteKey !v
|
|
| UpdDeleteElem !v
|
|
| UpdDeleteAtPath ![v]
|
|
deriving (Functor, Foldable, Traversable, Generic, Data)
|
|
|
|
|
|
-- NOTE: This function can be improved, because we use
|
|
-- the literal values defined below in the 'updateOperators'
|
|
-- function in 'Hasura.GraphQL.Schema.Mutation'. It would
|
|
-- be nice if we could avoid duplicating the string literal
|
|
-- values
|
|
updateOperatorText :: UpdOpExpG a -> Text
|
|
updateOperatorText (UpdSet _) = "_set"
|
|
updateOperatorText (UpdInc _) = "_inc"
|
|
updateOperatorText (UpdAppend _) = "_append"
|
|
updateOperatorText (UpdPrepend _) = "_prepend"
|
|
updateOperatorText (UpdDeleteKey _) = "_delete_key"
|
|
updateOperatorText (UpdDeleteElem _) = "_delete_elem"
|
|
updateOperatorText (UpdDeleteAtPath _) = "_delete_at_path"
|
|
|
|
traverseAnnUpd
|
|
:: (Applicative f, Backend backend)
|
|
=> (a -> f b)
|
|
-> AnnUpdG backend r a
|
|
-> f (AnnUpdG backend r b)
|
|
traverseAnnUpd f annUpd =
|
|
AnnUpd tn
|
|
<$> traverse (traverse $ traverse f) opExps
|
|
<*> ((,) <$> traverseAnnBoolExp f whr <*> traverseAnnBoolExp f fltr)
|
|
<*> traverseAnnBoolExp f chk
|
|
<*> traverseMutationOutput f mutOutput
|
|
<*> pure allCols
|
|
where
|
|
AnnUpd tn opExps (whr, fltr) chk mutOutput allCols = annUpd
|