mirror of
https://github.com/hasura/graphql-engine.git
synced 2024-12-18 04:51:35 +03:00
dec8579db8
### Description Each Backend executes queries against the database in a slightly different stack: Postgres uses its own `TXeT`, MSSQL uses a variant of it, BigQuery is simply in `ExceptT QErr IO`... To accommodate those variations, we had originally introduced an `ExecutionMonad b` type family in `BackendExecute`, allowing each backend to describe its own stack. It was then up to that backend's `BackendTransport` instance to implement running said stack, and converting the result back into our main app monad. However, this was not without complications: `TraceT` is one of them: as it usually needs to be on the top of the stack, converting from one stack to the other implies the use `interpTraceT`, which is quite monstrous. Furthermore, as part of the Entitlement Services work, we're trying to move to a "Services" architecture in which the entire engine runs in one base monad, that delegates features and dependencies to monad constraints; and as a result we'd like to minimize the number of different monad stacks we have to maintain and translate from and to in the codebase. To improve things, this PR changes `ExecutionMonad b` from an _absolute_ stack to a _relative_ one: i.e.: what needs to be stacked on top of our base monad for the execution. In `Transport`, we then only need to pop the top of the stack, and voila. This greatly simplifies the implementation of the backends, as there's no longer any need to do any stack transformation: MySQL's implementation becomes a `runIdentityT`! This also removes most mentions of `TraceT` from the execution code since it's no longer required: we can rely on the base monad's existing `MonadTrace` constraint. To continue encapsulating monadic actions in `DBStepInfo` and avoid threading a bunch of `forall` all over the place, this PR introduces a small local helper: `OnBaseMonad`. One only downside of all this is that this requires adding `MonadBaseControl IO m` constraint all over the place: previously, we would run directly on `IO` and lift, and would therefore not need to bring that constraint all the way. PR-URL: https://github.com/hasura/graphql-engine-mono/pull/7789 GitOrigin-RevId: e9b2e431c5c47fa9851abf87545c0415ff6d1a12
138 lines
4.9 KiB
Haskell
138 lines
4.9 KiB
Haskell
{-# OPTIONS_GHC -fno-warn-orphans #-}
|
|
|
|
module Hasura.Backends.MySQL.Instances.Execute () where
|
|
|
|
import Data.Aeson as J
|
|
import Data.Bifunctor
|
|
import Data.Coerce
|
|
import Data.Environment qualified as Env
|
|
import Data.HashMap.Strict.InsOrd qualified as OMap
|
|
import Data.Text qualified as T
|
|
import Data.Text.Encoding qualified as T
|
|
import Data.Tree
|
|
import Database.MySQL.Base (fetchFields, query, storeResult)
|
|
import Hasura.Backends.MySQL.Connection
|
|
import Hasura.Backends.MySQL.DataLoader.Execute (OutputValue (..), RecordSet (..))
|
|
import Hasura.Backends.MySQL.DataLoader.Execute qualified as DataLoader
|
|
import Hasura.Backends.MySQL.DataLoader.Plan qualified as DataLoader
|
|
import Hasura.Backends.MySQL.Plan
|
|
import Hasura.Backends.MySQL.ToQuery as ToQuery
|
|
import Hasura.Backends.MySQL.Types qualified as MySQL
|
|
import Hasura.Base.Error
|
|
import Hasura.EncJSON
|
|
import Hasura.GraphQL.Execute.Backend
|
|
import Hasura.GraphQL.Namespace
|
|
import Hasura.Prelude hiding (first, second)
|
|
import Hasura.RQL.IR
|
|
import Hasura.RQL.Types.Backend
|
|
import Hasura.RQL.Types.Common
|
|
import Hasura.SQL.AnyBackend qualified as AB
|
|
import Hasura.SQL.Backend
|
|
import Hasura.Session
|
|
import Language.GraphQL.Draft.Syntax qualified as G
|
|
import Network.HTTP.Types qualified as HTTP
|
|
|
|
instance BackendExecute 'MySQL where
|
|
type PreparedQuery 'MySQL = Text
|
|
type MultiplexedQuery 'MySQL = Void
|
|
type ExecutionMonad 'MySQL = IdentityT
|
|
|
|
mkDBQueryPlan = mysqlDBQueryPlan
|
|
mkDBMutationPlan = error "mkDBMutationPlan: MySQL backend does not support this operation yet."
|
|
mkLiveQuerySubscriptionPlan _ _ _ _ _ _ = error "mkLiveQuerySubscriptionPlan: MySQL backend does not support this operation yet."
|
|
mkDBStreamingSubscriptionPlan _ _ _ _ _ = error "mkDBStreamingSubscriptionPlan: MySQL backend does not support this operation yet."
|
|
mkDBQueryExplain = mysqlDBQueryExplain
|
|
mkSubscriptionExplain _ = error "mkSubscriptionExplain: MySQL backend does not support this operation yet."
|
|
mkDBRemoteRelationshipPlan = error "mkDBRemoteRelationshipPlan: MySQL does not support this operation yet."
|
|
|
|
mysqlDBQueryPlan ::
|
|
forall m.
|
|
( MonadError QErr m
|
|
) =>
|
|
UserInfo ->
|
|
Env.Environment ->
|
|
SourceName ->
|
|
SourceConfig 'MySQL ->
|
|
QueryDB 'MySQL Void (UnpreparedValue 'MySQL) ->
|
|
[HTTP.Header] ->
|
|
Maybe G.Name ->
|
|
m (DBStepInfo 'MySQL)
|
|
mysqlDBQueryPlan userInfo _env sourceName sourceConfig qrf _ _ = do
|
|
(headAndTail, actionsForest) <- queryToActionForest userInfo qrf
|
|
pure
|
|
( DBStepInfo
|
|
@'MySQL
|
|
sourceName
|
|
sourceConfig
|
|
(Just (T.pack (drawForest (fmap (fmap show) actionsForest))))
|
|
( OnBaseMonad do
|
|
result <-
|
|
DataLoader.runExecute
|
|
sourceConfig
|
|
headAndTail
|
|
(DataLoader.execute actionsForest)
|
|
either
|
|
(throw500WithDetail "MySQL DataLoader Error" . toJSON . show)
|
|
(pure . encJFromRecordSet)
|
|
result
|
|
)
|
|
()
|
|
)
|
|
|
|
--------------------------------------------------------------------------------
|
|
-- Encoding for Hasura's GraphQL JSON representation
|
|
|
|
mysqlDBQueryExplain ::
|
|
MonadError QErr m =>
|
|
RootFieldAlias ->
|
|
UserInfo ->
|
|
SourceName ->
|
|
SourceConfig 'MySQL ->
|
|
QueryDB 'MySQL Void (UnpreparedValue 'MySQL) ->
|
|
[HTTP.Header] ->
|
|
Maybe G.Name ->
|
|
m (AB.AnyBackend DBStepInfo)
|
|
mysqlDBQueryExplain fieldName userInfo sourceName sourceConfig qrf _ _ = do
|
|
select :: MySQL.Select <- planQuery (_uiSession userInfo) qrf
|
|
let sqlQuery = selectSQLTextForQuery select
|
|
sqlQueryText = (T.decodeUtf8 . unQuery . toQueryPretty) (ToQuery.fromSelect select)
|
|
explainResult = OnBaseMonad $
|
|
withMySQLPool
|
|
(MySQL.scConnectionPool sourceConfig)
|
|
\conn -> do
|
|
query conn ("EXPLAIN FORMAT=JSON " <> (unQuery sqlQuery))
|
|
result <- storeResult conn
|
|
fields <- fetchFields result
|
|
rows <- fetchAllRows result
|
|
let texts = concat $ parseTextRows fields rows
|
|
pure $ encJFromJValue $ ExplainPlan fieldName (Just sqlQueryText) (Just texts)
|
|
pure $
|
|
AB.mkAnyBackend $
|
|
DBStepInfo @'MySQL sourceName sourceConfig Nothing explainResult ()
|
|
|
|
selectSQLTextForQuery :: MySQL.Select -> ToQuery.Query
|
|
selectSQLTextForQuery select = toQueryFlat $ ToQuery.fromSelect select
|
|
|
|
encJFromRecordSet :: RecordSet -> EncJSON
|
|
encJFromRecordSet RecordSet {rows} =
|
|
encJFromList
|
|
( map
|
|
( encJFromAssocList
|
|
. map (first coerce . second encJFromOutputValue)
|
|
. OMap.toList
|
|
)
|
|
(toList rows)
|
|
)
|
|
|
|
encJFromOutputValue :: DataLoader.OutputValue -> EncJSON
|
|
encJFromOutputValue =
|
|
\case
|
|
ArrayOutputValue array -> encJFromList (map encJFromOutputValue (toList array))
|
|
RecordOutputValue m ->
|
|
encJFromAssocList
|
|
. map (first coerce . second encJFromOutputValue)
|
|
. OMap.toList
|
|
$ m
|
|
ScalarOutputValue value -> encJFromJValue value
|
|
NullOutputValue {} -> encJFromJValue J.Null
|