mirror of
https://github.com/hasura/graphql-engine.git
synced 2024-12-18 04:51:35 +03:00
b9ee669ee1
### Description This PR improves the `Collect` module by re-ordering the functions to make clear what is public API and what is internal implementation. Furthermore, it makes use of `traverseOf` and `traverseFields` to reduce duplication. To do so, it also introduces a few more lenses in the rest of the codebase, and uses this opportunity to harmonize some structures that were not following our naming convention. While the diff is massive, a lot of it is just code moving around; the file is now divided into separate sections: - entry points: IR types for which we want to run the collection - internal monadic structure - internal traversals: functions that do nothing but drill down further - actual transformations: the three cases where we do actually have work to do: selection sets on which we do want to insert join columns, extract remote relationships... those functions are left unchanged by this PR - internal helpers PR-URL: https://github.com/hasura/graphql-engine-mono/pull/3863 GitOrigin-RevId: f7cbecfae9eed9737b62acfa5848bfcf9d4651f6
83 lines
3.5 KiB
Haskell
83 lines
3.5 KiB
Haskell
{-# OPTIONS_HADDOCK ignore-exports #-}
|
|
|
|
-- | Responsible for translating and building an MSSQL execution plan for
|
|
-- delete mutations.
|
|
--
|
|
-- This module is used by "Hasura.Backends.MSSQL.Instances.Execute".
|
|
module Hasura.Backends.MSSQL.Execute.Delete
|
|
( executeDelete,
|
|
)
|
|
where
|
|
|
|
import Control.Monad.Validate qualified as V
|
|
import Database.MSSQL.Transaction qualified as Tx
|
|
import Hasura.Backends.MSSQL.Connection
|
|
import Hasura.Backends.MSSQL.Execute.MutationResponse
|
|
import Hasura.Backends.MSSQL.FromIr as TSQL
|
|
import Hasura.Backends.MSSQL.Plan
|
|
import Hasura.Backends.MSSQL.SQL.Error
|
|
import Hasura.Backends.MSSQL.ToQuery as TQ
|
|
import Hasura.Backends.MSSQL.Types.Internal as TSQL
|
|
import Hasura.Base.Error
|
|
import Hasura.EncJSON
|
|
import Hasura.GraphQL.Parser
|
|
import Hasura.Prelude
|
|
import Hasura.RQL.IR
|
|
import Hasura.RQL.Types
|
|
import Hasura.Session
|
|
|
|
-- | Executes a Delete IR AST and return results as JSON.
|
|
executeDelete ::
|
|
MonadError QErr m =>
|
|
UserInfo ->
|
|
StringifyNumbers ->
|
|
SourceConfig 'MSSQL ->
|
|
AnnDelG 'MSSQL Void (UnpreparedValue 'MSSQL) ->
|
|
m (ExceptT QErr IO EncJSON)
|
|
executeDelete userInfo stringifyNum sourceConfig deleteOperation = do
|
|
preparedDelete <- traverse (prepareValueQuery $ _uiSession userInfo) deleteOperation
|
|
pure $ mssqlRunReadWrite (_mscExecCtx sourceConfig) (buildDeleteTx preparedDelete stringifyNum)
|
|
|
|
-- | Converts a Delete IR AST to a transaction of three delete sql statements.
|
|
--
|
|
-- A GraphQL delete mutation does two things:
|
|
--
|
|
-- 1. Deletes rows in a table according to some predicate
|
|
-- 2. (Potentially) returns the deleted rows (including relationships) as JSON
|
|
--
|
|
-- In order to complete these 2 things we need 3 SQL statements:
|
|
--
|
|
-- 1. @SELECT INTO <temp_table> WHERE <false>@ - creates a temporary table
|
|
-- with the same schema as the original table in which we'll store the deleted rows
|
|
-- from the table we are deleting
|
|
-- 2. @DELETE FROM with OUTPUT@ - deletes the rows from the table and inserts the
|
|
-- deleted rows to the temporary table from (1)
|
|
-- 3. @SELECT@ - constructs the @returning@ query from the temporary table, including
|
|
-- relationships with other tables.
|
|
buildDeleteTx ::
|
|
AnnDel 'MSSQL ->
|
|
StringifyNumbers ->
|
|
Tx.TxET QErr IO EncJSON
|
|
buildDeleteTx deleteOperation stringifyNum = do
|
|
let withAlias = "with_alias"
|
|
createInsertedTempTableQuery =
|
|
toQueryFlat $
|
|
TQ.fromSelectIntoTempTable $
|
|
TSQL.toSelectIntoTempTable tempTableNameDeleted (_adTable deleteOperation) (_adAllCols deleteOperation) RemoveConstraints
|
|
-- Create a temp table
|
|
Tx.unitQueryE defaultMSSQLTxErrorHandler createInsertedTempTableQuery
|
|
let deleteQuery = TQ.fromDelete <$> TSQL.fromDelete deleteOperation
|
|
deleteQueryValidated <- toQueryFlat <$> V.runValidate (runFromIr deleteQuery) `onLeft` (throw500 . tshow)
|
|
-- Execute DELETE statement
|
|
Tx.unitQueryE mutationMSSQLTxErrorHandler deleteQueryValidated
|
|
mutationOutputSelect <- mkMutationOutputSelect stringifyNum withAlias $ _adOutput deleteOperation
|
|
let withSelect =
|
|
emptySelect
|
|
{ selectProjections = [StarProjection],
|
|
selectFrom = Just $ FromTempTable $ Aliased tempTableNameDeleted "deleted_alias"
|
|
}
|
|
finalMutationOutputSelect = mutationOutputSelect {selectWith = Just $ With $ pure $ Aliased withSelect withAlias}
|
|
mutationOutputSelectQuery = toQueryFlat $ TQ.fromSelect finalMutationOutputSelect
|
|
-- Execute SELECT query and fetch mutation response
|
|
encJFromText <$> Tx.singleRowQueryE defaultMSSQLTxErrorHandler mutationOutputSelectQuery
|