git.iko.soy/helix
on 0e42e4e help sign in
helix/runtime/queries/julia/textobjects.scm
46 lines 1.3 kB history raw
1(function_definition (_)? @function.inside) @function.around
3(short_function_definition (_)? @function.inside) @function.around
5(macro_definition (_)? @function.inside) @function.around
7(struct_definition (_)? @class.inside) @class.around
9(abstract_definition (_)? @class.inside) @class.around
11(primitive_definition (_)? @class.inside) @class.around
13(parameter_list
14 ; Match all children of parameter_list *except* keyword_parameters
15 ([(identifier)
16 (slurp_parameter)
17 (optional_parameter)
18 (typed_parameter)
19 (tuple_expression)
20 (interpolation_expression)
21 (call_expression)]
22 @parameter.inside . ","? @parameter.around) @parameter.around)
24(keyword_parameters
25 ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
27(argument_list
28 ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
30(type_parameter_list
31 ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
33(line_comment) @comment.inside
35(line_comment)+ @comment.around
37(block_comment) @comment.inside
39(block_comment)+ @comment.around
41(_expression (macro_identifier
42 (identifier) @_name
43 (#match? @_name "^(test|test_throws|test_logs|inferred|test_deprecated|test_warn|test_nowarn|test_broken|test_skip)$")
44 )
45 .
46 (macro_argument_list) @test.inside) @test.around