mirror of
https://github.com/ilyakooo0/helix.git
synced 2024-08-17 03:50:21 +03:00
add tree-sitter-erlang (#1657)
This commit is contained in:
parent
8a7aec6414
commit
3a83a764e3
3
.gitmodules
vendored
3
.gitmodules
vendored
@ -226,3 +226,6 @@
|
||||
path = helix-syntax/languages/tree-sitter-rescript
|
||||
url = https://github.com/jaredramirez/tree-sitter-rescript
|
||||
shallow = true
|
||||
[submodule "helix-syntax/languages/tree-sitter-erlang"]
|
||||
path = helix-syntax/languages/tree-sitter-erlang
|
||||
url = https://github.com/the-mikedavis/tree-sitter-erlang
|
||||
|
@ -11,6 +11,7 @@
|
||||
| dockerfile | ✓ | | | `docker-langserver` |
|
||||
| elixir | ✓ | | | `elixir-ls` |
|
||||
| elm | ✓ | | | `elm-language-server` |
|
||||
| erlang | ✓ | | | |
|
||||
| fish | ✓ | ✓ | ✓ | |
|
||||
| git-commit | ✓ | | | |
|
||||
| git-config | ✓ | | | |
|
||||
|
1
helix-syntax/languages/tree-sitter-erlang
Submodule
1
helix-syntax/languages/tree-sitter-erlang
Submodule
@ -0,0 +1 @@
|
||||
Subproject commit 86985bde399c5f40b00bc75f7ab70a6c69a5f9c3
|
@ -732,3 +732,12 @@ auto-format = true
|
||||
comment-token = "//"
|
||||
language-server = { command = "rescript-language-server", args = ["--stdio"] }
|
||||
indent = { tab-width = 2, unit = " " }
|
||||
|
||||
[[language]]
|
||||
name = "erlang"
|
||||
scope = "source.erlang"
|
||||
injection-regex = "^erl$"
|
||||
file-types = ["erl", "hrl", "app", "rebar.config"]
|
||||
roots = ["rebar.config"]
|
||||
comment-token = "%%"
|
||||
indent = { tab-width = 4, unit = " " }
|
||||
|
118
runtime/queries/erlang/highlights.scm
Normal file
118
runtime/queries/erlang/highlights.scm
Normal file
@ -0,0 +1,118 @@
|
||||
; Attributes
|
||||
; module declaration
|
||||
(attribute
|
||||
name: (atom) @keyword
|
||||
(arguments (atom) @module)
|
||||
(#eq? @keyword "module"))
|
||||
|
||||
(attribute
|
||||
name: (atom) @keyword
|
||||
(arguments
|
||||
.
|
||||
(atom) @module)
|
||||
(#eq? @keyword "import"))
|
||||
|
||||
(attribute
|
||||
name: (atom) @keyword
|
||||
(arguments
|
||||
.
|
||||
(atom) @type
|
||||
[
|
||||
(tuple (atom) @variable.other.member)
|
||||
(tuple
|
||||
(binary_operator
|
||||
left: (atom) @variable.other.member
|
||||
operator: "="))
|
||||
(tuple
|
||||
(binary_operator
|
||||
left:
|
||||
(binary_operator
|
||||
left: (atom) @variable.other.member
|
||||
operator: "=")
|
||||
operator: "::"))
|
||||
])
|
||||
(#eq? @keyword "record"))
|
||||
|
||||
(attribute
|
||||
name: (atom) @keyword
|
||||
(arguments
|
||||
.
|
||||
[
|
||||
(atom) @keyword.directive
|
||||
(variable) @keyword.directive
|
||||
(call
|
||||
function:
|
||||
[(variable) (atom)] @keyword.directive)
|
||||
])
|
||||
(#eq? @keyword "define"))
|
||||
|
||||
(attribute
|
||||
name: (atom) @keyword
|
||||
module: (atom) @module
|
||||
(#eq? @keyword "spec"))
|
||||
|
||||
; Functions
|
||||
(function name: (atom) @function)
|
||||
(call module: (atom) @module)
|
||||
(call function: (atom) @function)
|
||||
(stab_clause name: (atom) @function)
|
||||
(function_capture module: (atom) @module)
|
||||
(function_capture function: (atom) @function)
|
||||
|
||||
; Records
|
||||
(record_content
|
||||
(binary_operator
|
||||
left: (atom) @variable.other.member
|
||||
operator: "="))
|
||||
|
||||
(record field: (atom) @variable.other.member)
|
||||
(record name: (atom) @type)
|
||||
|
||||
; Keywords
|
||||
((attribute name: (atom) @keyword)
|
||||
(#match?
|
||||
@keyword
|
||||
"^(define|export|export_type|include|include_lib|ifdef|ifndef|if|elif|else|endif|vsn|on_load|behaviour|record|file|type|opaque|spec)$"))
|
||||
|
||||
["case" "fun" "if" "of" "when" "end" "receive" "try" "catch" "after"] @keyword
|
||||
|
||||
; Operators
|
||||
(binary_operator
|
||||
left: (atom) @function
|
||||
operator: "/"
|
||||
right: (integer) @constant.numeric.integer)
|
||||
|
||||
(binary_operator operator: _ @operator)
|
||||
(unary_operator operator: _ @operator)
|
||||
["/" ":" "#" "->"] @operator
|
||||
|
||||
; Comments
|
||||
((variable) @comment.discard
|
||||
(#match? @comment.discard "^_"))
|
||||
|
||||
(tripledot) @comment.discard
|
||||
|
||||
(comment) @comment
|
||||
|
||||
; Macros
|
||||
(macro
|
||||
"?"+ @keyword.directive
|
||||
name: (_) @keyword.directive)
|
||||
|
||||
; Basic types
|
||||
(variable) @variable
|
||||
[
|
||||
(atom)
|
||||
(quoted_atom)
|
||||
] @string.special.symbol
|
||||
(string) @string
|
||||
(character) @constant.character
|
||||
|
||||
(integer) @constant.numeric.integer
|
||||
(float) @constant.numeric.float
|
||||
|
||||
; Punctuation
|
||||
["," "." "-" ";"] @punctuation.delimiter
|
||||
["(" ")" "{" "}" "[" "]" "<<" ">>"] @punctuation.bracket
|
||||
|
||||
; (ERROR) @error
|
2
runtime/queries/erlang/injections.scm
Normal file
2
runtime/queries/erlang/injections.scm
Normal file
@ -0,0 +1,2 @@
|
||||
((comment) @injection.content
|
||||
(#set! injection.language "comment"))
|
Loading…
Reference in New Issue
Block a user