Merge pull request #6051 from urbit/po/add-region-to-s3-settings

Groups/Garden: Add s3 region to s3 settings

pkg/landscape/app/s3-store.hoon

@@ -9,12 +9,14 @@
 +$  card  card:agent:gall
 +$  versioned-state
   $%  state-zero
+      state-one
   ==
 ::
-+$  state-zero  [%0 =credentials =configuration]
++$  state-zero  [%0 =credentials:zero:past =configuration:zero:past]
++$  state-one   [%1 =credentials =configuration]
 --
 ::
-=|  state-zero
+=|  state-one
 =*  state  -
 ::
 %-  agent:dbug
@@ -28,8 +30,28 @@
 ++  on-init   on-init:def
 ++  on-save   !>(state)
 ++  on-load
-  |=  old-vase=vase
-  [~ this(state !<(state-zero old-vase))]
+  |=  =vase
+  =/  old  !<(versioned-state vase)
+  |^
+  ?-  -.old
+    %1  `this(state old)
+    %0  `this(state (state-0-to-1 old))
+  ==
+  ++  state-0-to-1
+    |=  zer=state-zero
+    ^-  state-one
+    :*  %1
+        credentials.zer
+        (configuration-0-to-1 configuration.zer)
+    ==
+  ++  configuration-0-to-1
+    |=  conf=configuration:zero:past
+    ^-  ^configuration
+    :*  buckets.conf
+        current-bucket.conf
+        ''
+    ==
+  --
 ::
 ++  on-poke
   ~/  %s3-poke
@@ -56,6 +78,9 @@
     ::
         %set-secret-access-key
       state(secret-access-key.credentials secret-access-key.act)
+    ::
+        %set-region
+      state(region.configuration region.act)
     ::
         %set-current-bucket
       %_  state

pkg/landscape/gen/s3-store/set-region.hoon

@@ -0,0 +1,10 @@
+::  s3-store|set-current-bucket: set current bucket for S3
+::
+/-  *s3
+:-  %say
+|=  $:  [now=@da eny=@uvJ =beak]
+        [[region=@t ~] ~]
+    ==
+:-  %s3-action
+^-  action
+[%set-region region]

pkg/landscape/lib/s3-json.hoon

@@ -10,6 +10,7 @@
     :~  [%set-endpoint so:dejs]
         [%set-access-key-id so:dejs]
         [%set-secret-access-key so:dejs]
+        [%set-region so:dejs]
         [%add-bucket so:dejs]
         [%remove-bucket so:dejs]
         [%set-current-bucket so:dejs]
@@ -25,6 +26,7 @@
   :~  ?-  -.upd
           %set-current-bucket  [%'setCurrentBucket' s+bucket.upd]
           %add-bucket          [%'addBucket' s+bucket.upd]
+          %set-region          [%'setRegion' s+region.upd]
           %remove-bucket       [%'removeBucket' s+bucket.upd]
           %set-endpoint        [%'setEndpoint' s+endpoint.upd]
           %set-access-key-id   [%'setAccessKeyId' s+access-key-id.upd]
@@ -44,6 +46,7 @@
         %-  pairs:enjs
         :~  [%buckets a+(turn ~(tap in buckets.configuration.upd) |=(a=@t s+a))]
             [%'currentBucket' s+current-bucket.configuration.upd]
+            [%'region' s+region.configuration.upd]
         ==
       ==
   ==

pkg/landscape/sur/s3-0.hoon

@@ -0,0 +1,27 @@
+|%
++$  credentials
+  $:  endpoint=@t
+      access-key-id=@t
+      secret-access-key=@t
+  ==
+::
++$  configuration
+  $:  buckets=(set @t)
+      current-bucket=@t
+  ==
+::
++$  action
+  $%  [%set-endpoint endpoint=@t]
+      [%set-access-key-id access-key-id=@t]
+      [%set-secret-access-key secret-access-key=@t]
+      [%add-bucket bucket=@t]
+      [%remove-bucket bucket=@t]
+      [%set-current-bucket bucket=@t]
+  ==
+::
++$  update
+  $%  [%credentials =credentials]
+      [%configuration =configuration]
+      action
+  ==
+--

pkg/landscape/sur/s3.hoon

@@ -1,4 +1,9 @@
+/-  zer=s3-0
 |%
+++  past
+  |%
+  ++  zero  zer
+  --
 +$  credentials
   $:  endpoint=@t
       access-key-id=@t
@@ -8,6 +13,7 @@
 +$  configuration
   $:  buckets=(set @t)
       current-bucket=@t
+      region=@t
   ==
 ::
 +$  action
@@ -17,6 +23,7 @@
       [%add-bucket bucket=@t]
       [%remove-bucket bucket=@t]
       [%set-current-bucket bucket=@t]
+      [%set-region region=@t]
   ==
 ::
 +$  update