::
::::  /hoon/command/work/mar
  ::
/-    *work
!:
::::
  ::
|_  mad=command
++  grab
  |%  ++  noun  command
      ++  json
    =>  [jo ..command]
    =<  (corl need (cu |=(a=command a) coma))
    |%
    ++  as
      :: |*(a=fist (cu sa (ar a)))  ::  XX  types
      |*  a=fist 
      %-  cu  :_  (ar a)
      ~(gas in *(set ,_(need *a)))
    ++  id  (ci (slat %uv) so)
    ++  ship  (su fed:ag)
    ++  coma  (of new/task old/(ot id/id dif/uppd ~) sort/(ar id) ~)
    ++  task
      %^    ot
          :-  %task
          %-  ot  :~
            id/id           date-created/di
            version/ni      date-modified/di
            owner/ship      status/(ci (soft status) so)
            tags/(as so)    date-due/(mu di)
            done/(mu di)    title/so
            description/so  discussion/(ar (ot date/di ship/ship body/so ~))
          ==
        audience/(as (ot ship/ship span/so ~))
      ~
    ++  uppd
      %-  of  :~
        own/(of announce/ul claim/ul ~)
        add/(of comment/so ~)
        :-  %set
        %-  of  :~
          date-due/(mu di)
          title/so
          description/so
          tags/(as so)
          done/bo
          audience/(as (ot ship/ship span/so ~))
        ==
      ==
    --
  --
++  grow
  |%
  ++  elem  ;pre: {(zing `wall`(turn (wash 0^120 >mad<) |=(a=tape ['\0a' a])))}
  --
--
:: {new: {
::   id:'0vaof.6df9u.2agc3.d0dp1',
::   date-created:1440011611215,
::   version:1,
::   date-modified:1440011611215,
::   owner:'fyr',
::   status:'gave',
::   tags:['tag'],
::   date-due:null,
::   done:XX
::   title:'Test task',
::   description:'The converter owrks right?',
::   discussion:[{date:1440011611215,ship:'sondel',body:'hi'}]
:: } }