mirror of
https://github.com/kanaka/mal.git
synced 2024-08-18 02:00:40 +03:00
033892777a
See issue #587. * Merge eval-ast and eval into a single conditional. * Expand macros during the apply phase, removing lots of duplicate tests, and increasing the overall consistency by allowing the macro to be computed instead of referenced by name (`((defmacro! cond (...)))` is currently illegal for example). * Print "EVAL: $ast" at the top of EVAL if DEBUG-EVAL exists in the MAL environment. * Remove macroexpand and quasiquoteexpand special forms. * Use pattern-matching style in process/step*.txt. Unresolved issues: c.2: unable to reproduce with gcc 11.12.0. elm: the directory is unchanged. groovy: sometimes fail, but not on each rebuild. nasm: fails some new soft tests, but the issue is unreproducible when running the interpreter manually. objpascal: unreproducible with fpc 3.2.2. ocaml: unreproducible with 4.11.1. perl6: unreproducible with rakudo 2021.09. Unrelated changes: Reduce diff betweens steps. Prevent defmacro! from mutating functions: c forth logo miniMAL vb. dart: fix recent errors and warnings ocaml: remove metadata from symbols. Improve the logo implementation. Encapsulate all representation in types.lg and env.lg, unwrap numbers. Replace some manual iterations with logo control structures. Reduce the diff between steps. Use native iteration in env_get and env_map Rewrite the reader with less temporary strings. Reduce the number of temporary lists (for example, reverse iteration with butlast requires O(n^2) allocations). It seems possible to remove a few exceptions: GC settings (Dockerfile), NO_SELF_HOSTING (IMPLS.yml) and step5_EXCLUDES (Makefile.impls) .
81 lines
2.4 KiB
EmacsLisp
81 lines
2.4 KiB
EmacsLisp
(require 'mal/types)
|
|
(require 'mal/reader)
|
|
(require 'mal/printer)
|
|
|
|
(defvar repl-env (make-hash-table :test 'eq))
|
|
(puthash '+ (lambda (a b) (mal-number (+ (mal-value a) (mal-value b)))) repl-env)
|
|
(puthash '- (lambda (a b) (mal-number (- (mal-value a) (mal-value b)))) repl-env)
|
|
(puthash '* (lambda (a b) (mal-number (* (mal-value a) (mal-value b)))) repl-env)
|
|
(puthash '/ (lambda (a b) (mal-number (/ (mal-value a) (mal-value b)))) repl-env)
|
|
|
|
(defun READ (input)
|
|
(read-str input))
|
|
|
|
(defun EVAL (ast env)
|
|
;; (println "EVAL: %s\n" (PRINT ast))
|
|
(cl-case (mal-type ast)
|
|
(list
|
|
(let ((a (mal-value ast)))
|
|
(if a
|
|
(let* ((fn (EVAL (car a) env))
|
|
(args (mapcar (lambda (x) (EVAL x env)) (cdr a))))
|
|
(apply fn args))
|
|
ast)))
|
|
(symbol
|
|
(let ((definition (gethash (mal-value ast) env)))
|
|
(or definition (error "Definition not found"))))
|
|
(vector
|
|
(mal-vector (vconcat (mapcar (lambda (item) (EVAL item env))
|
|
(mal-value ast)))))
|
|
(map
|
|
(let ((map (copy-hash-table (mal-value ast))))
|
|
(maphash (lambda (key val)
|
|
(puthash key (EVAL val env) map))
|
|
map)
|
|
(mal-map map)))
|
|
(t
|
|
;; return as is
|
|
ast)))
|
|
|
|
(defun PRINT (input)
|
|
(pr-str input t))
|
|
|
|
(defun rep (input)
|
|
(PRINT (EVAL (READ input) repl-env)))
|
|
|
|
(defun readln (prompt)
|
|
;; C-d throws an error
|
|
(ignore-errors (read-from-minibuffer prompt)))
|
|
|
|
(defun println (format-string &rest args)
|
|
(if (not args)
|
|
(princ format-string)
|
|
(princ (apply 'format format-string args)))
|
|
(terpri))
|
|
|
|
(defun main ()
|
|
(let (eof)
|
|
(while (not eof)
|
|
(let ((input (readln "user> ")))
|
|
(if input
|
|
(condition-case err
|
|
(println (rep input))
|
|
(end-of-token-stream
|
|
;; empty input, carry on
|
|
)
|
|
(unterminated-sequence
|
|
(princ (format "Expected '%c', got EOF\n"
|
|
(cl-case (cadr err)
|
|
(string ?\")
|
|
(list ?\))
|
|
(vector ?\])
|
|
(map ?})))))
|
|
(error ; catch-all
|
|
(println (error-message-string err))
|
|
(backtrace)))
|
|
(setq eof t)
|
|
;; print final newline
|
|
(terpri))))))
|
|
|
|
(main)
|