mirror of
https://github.com/kanaka/mal.git
synced 2024-08-18 02:00:40 +03:00
See issue #587. * Merge eval-ast and eval into a single conditional. * Expand macros during the apply phase, removing lots of duplicate tests, and increasing the overall consistency by allowing the macro to be computed instead of referenced by name (`((defmacro! cond (...)))` is currently illegal for example). * Print "EVAL: $ast" at the top of EVAL if DEBUG-EVAL exists in the MAL environment. * Remove macroexpand and quasiquoteexpand special forms. * Use pattern-matching style in process/step*.txt. Unresolved issues: c.2: unable to reproduce with gcc 11.12.0. elm: the directory is unchanged. groovy: sometimes fail, but not on each rebuild. nasm: fails some new soft tests, but the issue is unreproducible when running the interpreter manually. objpascal: unreproducible with fpc 3.2.2. ocaml: unreproducible with 4.11.1. perl6: unreproducible with rakudo 2021.09. Unrelated changes: Reduce diff betweens steps. Prevent defmacro! from mutating functions: c forth logo miniMAL vb. dart: fix recent errors and warnings ocaml: remove metadata from symbols. Improve the logo implementation. Encapsulate all representation in types.lg and env.lg, unwrap numbers. Replace some manual iterations with logo control structures. Reduce the diff between steps. Use native iteration in env_get and env_map Rewrite the reader with less temporary strings. Reduce the number of temporary lists (for example, reverse iteration with butlast requires O(n^2) allocations). It seems possible to remove a few exceptions: GC settings (Dockerfile), NO_SELF_HOSTING (IMPLS.yml) and step5_EXCLUDES (Makefile.impls) .
198 lines
5.5 KiB
Groovy
198 lines
5.5 KiB
Groovy
import reader
|
|
import printer
|
|
import types
|
|
import types.MalException
|
|
import types.MalSymbol
|
|
import types.MalFunc
|
|
import env.Env
|
|
import core
|
|
|
|
// READ
|
|
READ = { str ->
|
|
reader.read_str str
|
|
}
|
|
|
|
// EVAL
|
|
starts_with = { lst, sym ->
|
|
lst.size() == 2 && lst[0].class == MalSymbol && lst[0].value == sym
|
|
}
|
|
qq_loop = { elt, acc ->
|
|
if (types.list_Q(elt) && starts_with(elt, "splice-unquote")) {
|
|
return [new MalSymbol("concat"), elt[1], acc]
|
|
} else {
|
|
return [new MalSymbol("cons"), quasiquote(elt), acc]
|
|
}
|
|
}
|
|
qq_foldr = { xs ->
|
|
def acc = []
|
|
for (int i=xs.size()-1; 0<=i; i-=1) {
|
|
acc = qq_loop(xs[i], acc)
|
|
}
|
|
return acc
|
|
}
|
|
quasiquote = { ast ->
|
|
switch (ast) {
|
|
case List:
|
|
if (types.vector_Q(ast)) {
|
|
return [new MalSymbol("vec"), qq_foldr(ast)]
|
|
} else if (starts_with(ast, "unquote")) {
|
|
return ast[1]
|
|
} else {
|
|
return qq_foldr(ast)
|
|
}
|
|
case MalSymbol: return [new MalSymbol("quote"), ast]
|
|
case Map: return [new MalSymbol("quote"), ast]
|
|
default: return ast
|
|
}
|
|
}
|
|
|
|
EVAL = { ast, env ->
|
|
while (true) {
|
|
def dbgevalenv = env.find("DEBUG-EVAL");
|
|
if (dbgevalenv != null) {
|
|
def dbgeval = env.get("DEBUG-EVAL");
|
|
if (dbgeval != null && dbgeval != false) {
|
|
println("EVAL: ${printer.pr_str(ast,true)}")
|
|
}
|
|
}
|
|
|
|
switch (ast) {
|
|
case MalSymbol: return env.get(ast.value);
|
|
case List: if (types.vector_Q(ast)) {
|
|
return types.vector(ast.collect { EVAL(it, env) })
|
|
}
|
|
break;
|
|
case Map: def new_hm = [:]
|
|
ast.each { k,v ->
|
|
new_hm[k] = EVAL(v, env)
|
|
}
|
|
return new_hm
|
|
default: return ast
|
|
}
|
|
|
|
if (ast.size() == 0) return ast
|
|
|
|
switch (ast[0]) {
|
|
case { it instanceof MalSymbol && it.value == "def!" }:
|
|
return env.set(ast[1], EVAL(ast[2], env))
|
|
case { it instanceof MalSymbol && it.value == "let*" }:
|
|
def let_env = new Env(env)
|
|
for (int i=0; i < ast[1].size(); i += 2) {
|
|
let_env.set(ast[1][i], EVAL(ast[1][i+1], let_env))
|
|
}
|
|
env = let_env
|
|
ast = ast[2]
|
|
break // TCO
|
|
case { it instanceof MalSymbol && it.value == "quote" }:
|
|
return ast[1]
|
|
case { it instanceof MalSymbol && it.value == "quasiquote" }:
|
|
ast = quasiquote(ast[1])
|
|
break // TCO
|
|
case { it instanceof MalSymbol && it.value == "defmacro!" }:
|
|
def f = EVAL(ast[2], env)
|
|
f = f.clone()
|
|
f.ismacro = true
|
|
return env.set(ast[1], f)
|
|
case { it instanceof MalSymbol && it.value == "try*" }:
|
|
try {
|
|
return EVAL(ast[1], env)
|
|
} catch(exc) {
|
|
if (ast.size() > 2 &&
|
|
ast[2][0] instanceof MalSymbol &&
|
|
ast[2][0].value == "catch*") {
|
|
def e = null
|
|
if (exc instanceof MalException) {
|
|
e = exc.obj
|
|
} else {
|
|
e = exc.message
|
|
}
|
|
return EVAL(ast[2][2], new Env(env, [ast[2][1]], [e]))
|
|
} else {
|
|
throw exc
|
|
}
|
|
}
|
|
case { it instanceof MalSymbol && it.value == "do" }:
|
|
ast.size() > 2 ? ast[1..-2].collect { EVAL(it, env) } : null
|
|
ast = ast[-1]
|
|
break // TCO
|
|
case { it instanceof MalSymbol && it.value == "if" }:
|
|
def cond = EVAL(ast[1], env)
|
|
if (cond == false || cond == null) {
|
|
if (ast.size > 3) {
|
|
ast = ast[3]
|
|
break // TCO
|
|
} else {
|
|
return null
|
|
}
|
|
} else {
|
|
ast = ast[2]
|
|
break // TCO
|
|
}
|
|
case { it instanceof MalSymbol && it.value == "fn*" }:
|
|
return new MalFunc(EVAL, ast[2], env, ast[1])
|
|
default:
|
|
def f = EVAL(ast[0], env)
|
|
def args = ast.drop(1)
|
|
if (f instanceof MalFunc && f.ismacro) {
|
|
ast = f(args)
|
|
break // TCO
|
|
}
|
|
args = args.collect { EVAL(it, env) }
|
|
if (f instanceof MalFunc) {
|
|
env = new Env(f.env, f.params, args)
|
|
ast = f.ast
|
|
break // TCO
|
|
} else {
|
|
return f(args)
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
// PRINT
|
|
PRINT = { exp ->
|
|
printer.pr_str exp, true
|
|
}
|
|
|
|
// REPL
|
|
repl_env = new Env();
|
|
REP = { str ->
|
|
PRINT(EVAL(READ(str), repl_env))
|
|
}
|
|
|
|
// core.EXT: defined using Groovy
|
|
core.ns.each { k,v ->
|
|
repl_env.set(new MalSymbol(k), v)
|
|
}
|
|
repl_env.set(new MalSymbol("eval"), { a -> EVAL(a[0], repl_env)})
|
|
repl_env.set(new MalSymbol("*ARGV*"), this.args as List)
|
|
|
|
// core.mal: defined using mal itself
|
|
REP("(def! not (fn* (a) (if a false true)))")
|
|
REP("(def! load-file (fn* (f) (eval (read-string (str \"(do \" (slurp f) \"\nnil)\")))))")
|
|
REP("(defmacro! cond (fn* (& xs) (if (> (count xs) 0) (list 'if (first xs) (if (> (count xs) 1) (nth xs 1) (throw \"odd number of forms to cond\")) (cons 'cond (rest (rest xs)))))))");
|
|
|
|
|
|
if (this.args.size() > 0) {
|
|
repl_env.set(new MalSymbol("*ARGV*"), this.args.drop(1) as List)
|
|
REP("(load-file \"${this.args[0]}\")")
|
|
System.exit(0)
|
|
}
|
|
|
|
while (true) {
|
|
line = System.console().readLine 'user> '
|
|
if (line == null) {
|
|
break;
|
|
}
|
|
try {
|
|
println REP(line)
|
|
} catch(MalException ex) {
|
|
println "Error: ${printer.pr_str(ex.obj, true)}"
|
|
} catch(StackOverflowError ex) {
|
|
println "Error: ${ex}"
|
|
} catch(ex) {
|
|
println "Error: $ex"
|
|
ex.printStackTrace()
|
|
}
|
|
}
|