mirror of
https://github.com/kanaka/mal.git
synced 2024-10-27 14:52:16 +03:00
033892777a
See issue #587. * Merge eval-ast and eval into a single conditional. * Expand macros during the apply phase, removing lots of duplicate tests, and increasing the overall consistency by allowing the macro to be computed instead of referenced by name (`((defmacro! cond (...)))` is currently illegal for example). * Print "EVAL: $ast" at the top of EVAL if DEBUG-EVAL exists in the MAL environment. * Remove macroexpand and quasiquoteexpand special forms. * Use pattern-matching style in process/step*.txt. Unresolved issues: c.2: unable to reproduce with gcc 11.12.0. elm: the directory is unchanged. groovy: sometimes fail, but not on each rebuild. nasm: fails some new soft tests, but the issue is unreproducible when running the interpreter manually. objpascal: unreproducible with fpc 3.2.2. ocaml: unreproducible with 4.11.1. perl6: unreproducible with rakudo 2021.09. Unrelated changes: Reduce diff betweens steps. Prevent defmacro! from mutating functions: c forth logo miniMAL vb. dart: fix recent errors and warnings ocaml: remove metadata from symbols. Improve the logo implementation. Encapsulate all representation in types.lg and env.lg, unwrap numbers. Replace some manual iterations with logo control structures. Reduce the diff between steps. Use native iteration in env_get and env_map Rewrite the reader with less temporary strings. Reduce the number of temporary lists (for example, reverse iteration with butlast requires O(n^2) allocations). It seems possible to remove a few exceptions: GC settings (Dockerfile), NO_SELF_HOSTING (IMPLS.yml) and step5_EXCLUDES (Makefile.impls) .
176 lines
4.2 KiB
Forth
176 lines
4.2 KiB
Forth
require reader.fs
|
|
require printer.fs
|
|
require env.fs
|
|
|
|
: args-as-native { argv argc -- entry*argc... }
|
|
argc 0 ?do
|
|
argv i cells + @ as-native
|
|
loop ;
|
|
|
|
0 MalEnv. constant repl-env
|
|
s" +" MalSymbol. :noname args-as-native + MalInt. ; MalNativeFn. repl-env env/set
|
|
s" -" MalSymbol. :noname args-as-native - MalInt. ; MalNativeFn. repl-env env/set
|
|
s" *" MalSymbol. :noname args-as-native * MalInt. ; MalNativeFn. repl-env env/set
|
|
s" /" MalSymbol. :noname args-as-native / MalInt. ; MalNativeFn. repl-env env/set
|
|
|
|
: read read-str ;
|
|
s" DEBUG-EVAL" MalSymbol. constant debug-eval-sym
|
|
: eval ( env obj )
|
|
over debug-eval-sym swap env/get-addr ?dup-if
|
|
@ dup mal-false <> swap mal-nil <> and if
|
|
." EVAL: " dup pr-str safe-type cr
|
|
endif
|
|
endif
|
|
mal-eval ;
|
|
: print
|
|
\ ." Type: " dup mal-type @ type-name safe-type cr
|
|
pr-str ;
|
|
|
|
MalDefault extend mal-eval nip ;; drop \ By default, evalutate to yourself
|
|
|
|
MalKeyword
|
|
extend eval-invoke { env list kw -- val }
|
|
0 kw env list MalList/start @ cell+ @ eval get
|
|
?dup 0= if
|
|
\ compute not-found value
|
|
list MalList/count @ 1 > if
|
|
env list MalList/start @ 2 cells + @ eval
|
|
else
|
|
mal-nil
|
|
endif
|
|
endif ;;
|
|
drop
|
|
|
|
\ eval all but the first item of list
|
|
: eval-rest { env list -- argv argc }
|
|
list MalList/start @ cell+ { expr-start }
|
|
list MalList/count @ 1- { argc }
|
|
argc cells allocate throw { target }
|
|
argc 0 ?do
|
|
env expr-start i cells + @ eval
|
|
target i cells + !
|
|
loop
|
|
target argc ;
|
|
|
|
MalNativeFn
|
|
extend eval-invoke ( env list this -- list )
|
|
MalNativeFn/xt @ { xt }
|
|
eval-rest ( argv argc )
|
|
xt execute ( return-val ) ;;
|
|
drop
|
|
|
|
SpecialOp
|
|
extend eval-invoke ( env list this -- list )
|
|
SpecialOp/xt @ execute ;;
|
|
drop
|
|
|
|
: install-special ( symbol xt )
|
|
SpecialOp. repl-env env/set ;
|
|
|
|
: defspecial
|
|
parse-allot-name MalSymbol.
|
|
['] install-special
|
|
:noname
|
|
;
|
|
|
|
defspecial quote ( env list -- form )
|
|
nip MalList/start @ cell+ @ ;;
|
|
|
|
defspecial def! { env list -- val }
|
|
list MalList/start @ cell+ { arg0 }
|
|
arg0 @ ( key )
|
|
env arg0 cell+ @ eval dup { val } ( key val )
|
|
env env/set val ;;
|
|
|
|
defspecial let* { old-env list -- val }
|
|
old-env MalEnv. { env }
|
|
list MalList/start @ cell+ dup { arg0 }
|
|
@ to-list
|
|
dup MalList/start @ { bindings-start } ( list )
|
|
MalList/count @ 0 +do
|
|
bindings-start i cells + dup @ swap cell+ @ ( sym expr )
|
|
env swap eval
|
|
env env/set
|
|
2 +loop
|
|
env arg0 cell+ @ eval
|
|
\ TODO: dec refcount of env
|
|
;;
|
|
|
|
MalSymbol
|
|
extend mal-eval { env sym -- val }
|
|
sym env env/get-addr
|
|
dup 0= if
|
|
drop
|
|
0 0 s" ' not found" sym pr-str s" '" ...throw-str
|
|
else
|
|
@
|
|
endif ;;
|
|
drop
|
|
|
|
: eval-ast { env list -- list }
|
|
here
|
|
list MalList/start @ { expr-start }
|
|
list MalList/count @ 0 ?do
|
|
env expr-start i cells + @ eval ,
|
|
loop
|
|
here>MalList ;
|
|
|
|
MalList
|
|
extend mal-eval { env list -- val }
|
|
list MalList/count @ 0= if
|
|
list
|
|
else
|
|
env list MalList/start @ @ eval
|
|
env list rot eval-invoke
|
|
endif ;;
|
|
drop
|
|
|
|
MalVector
|
|
extend mal-eval ( env vector -- vector )
|
|
MalVector/list @ eval-ast
|
|
MalVector new swap over MalVector/list ! ;;
|
|
drop
|
|
|
|
MalMap
|
|
extend mal-eval ( env map -- map )
|
|
MalMap/list @ eval-ast
|
|
MalMap new swap over MalMap/list ! ;;
|
|
drop
|
|
|
|
: rep ( str-addr str-len -- str-addr str-len )
|
|
read
|
|
repl-env swap eval
|
|
print ;
|
|
|
|
create buff 128 allot
|
|
77777777777 constant stack-leak-detect
|
|
|
|
: read-lines
|
|
begin
|
|
." user> "
|
|
stack-leak-detect
|
|
buff 128 stdin read-line throw
|
|
while ( num-bytes-read )
|
|
dup 0 <> if
|
|
buff swap ( str-addr str-len )
|
|
['] rep
|
|
\ execute ['] nop \ uncomment to see stack traces
|
|
catch ?dup 0= if
|
|
safe-type cr
|
|
stack-leak-detect <> if ." --stack leak--" cr endif
|
|
else { errno }
|
|
begin stack-leak-detect = until
|
|
errno 1 <> if
|
|
s" forth-errno" MalKeyword. errno MalInt. MalMap/Empty assoc
|
|
to exception-object
|
|
endif
|
|
." Uncaught exception: "
|
|
exception-object pr-str safe-type cr
|
|
endif
|
|
endif
|
|
repeat ;
|
|
|
|
read-lines
|
|
cr
|
|
bye
|