mirror of
https://github.com/kanaka/mal.git
synced 2024-09-19 01:28:26 +03:00
dd7a4f55f3
Fixes made to: ada, c, chuck, clojure, coffee, common-lisp, cpp, crystal, d, dart, elm, erlang, es6, factor, fsharp, gnu-smalltalk, groovy, guile, haxe, hy, js, livescript, matlab, miniMAL, nasm, nim, objc, objpascal, ocaml, perl, perl6, php, plsql, ps, python, r, rpython, ruby, scheme, swift3, tcl, ts, vb, vimscript, wasm, yorick. Catchless try* test is an optional test. Not all implementations support catchless try* but a number were fixed so they at least don't crash on catchless try*.
56 lines
1.4 KiB
CoffeeScript
56 lines
1.4 KiB
CoffeeScript
readline = require "./node_readline.coffee"
|
|
types = require "./types.coffee"
|
|
reader = require "./reader.coffee"
|
|
printer = require "./printer.coffee"
|
|
|
|
# read
|
|
READ = (str) -> reader.read_str str
|
|
|
|
# eval
|
|
eval_ast = (ast, env) ->
|
|
if types._symbol_Q(ast) then env[ast.name]
|
|
else if types._list_Q(ast) then ast.map((a) -> EVAL(a, env))
|
|
else if types._vector_Q(ast)
|
|
types._vector(ast.map((a) -> EVAL(a, env))...)
|
|
else if types._hash_map_Q(ast)
|
|
new_hm = {}
|
|
new_hm[k] = EVAL(ast[k],env) for k,v of ast
|
|
new_hm
|
|
else ast
|
|
|
|
EVAL = (ast, env) ->
|
|
#console.log "EVAL:", printer._pr_str ast
|
|
if !types._list_Q ast then return eval_ast ast, env
|
|
if ast.length == 0 then return ast
|
|
|
|
# apply list
|
|
[f, args...] = eval_ast ast, env
|
|
f(args...)
|
|
|
|
|
|
# print
|
|
PRINT = (exp) -> printer._pr_str exp, true
|
|
|
|
# repl
|
|
repl_env = {}
|
|
rep = (str) -> PRINT(EVAL(READ(str), repl_env))
|
|
|
|
repl_env["+"] = (a,b) -> a+b
|
|
repl_env["-"] = (a,b) -> a-b
|
|
repl_env["*"] = (a,b) -> a*b
|
|
repl_env["/"] = (a,b) -> a/b
|
|
|
|
# repl loop
|
|
while (line = readline.readline("user> ")) != null
|
|
continue if line == ""
|
|
try
|
|
console.log rep line
|
|
catch exc
|
|
continue if exc instanceof reader.BlankException
|
|
if exc.stack? and exc.stack.length > 2000
|
|
console.log exc.stack.slice(0,1000) + "\n ..." + exc.stack.slice(-1000)
|
|
else if exc.stack? then console.log exc.stack
|
|
else console.log exc
|
|
|
|
# vim: ts=2:sw=2
|